批量_选择列表框_保存\读取配置

h1601zl

.版本 2

.子程序 批量_选择列表框_保存配置, 整数型, 公开, 保存窗口上所有组合框的内容!与"批量_选择列表框_读取配置()"命令一起用的!  返回被操作的选择列表框数量!
.参数 组件的父窗口, 窗口, , 直接填写顶级窗口就行了,如:_启动窗口
.参数 配置文件名, 文本型, 可空, 可空:默认保存在根目录\data目录下,名为setsoft.ini
.参数 不保存的控件名称, 文本型, 可空, 不需要自动保存数据的控件名称,以|分开;
.局部变量 局_寻找句柄, 整数型
.局部变量 局_计次, 整数型
.局部变量 局_组件, 选择列表框
.局部变量 局_临时文本, 文本型
.局部变量 局_组件数量, 整数型
.局部变量 局_列表框计次, 整数型

.如果真 (配置文件名 ＝ “”)
    配置文件名 ＝ 取默认目录 ()
.如果真结束
局_寻找句柄 ＝ 寻找组件 (组件的父窗口, , “选择列表框”, , )
局_组件数量 ＝ 取找到组件数目 (局_寻找句柄)
.计次循环首 (局_组件数量, 局_计次)
    局_临时文本 ＝ “”
    局_组件 ＝ 取所找到组件 (局_寻找句柄, 局_计次 － 1)
    .如果真 (内部_对比 (不保存的控件名称, 取组件名称 (局_组件)))
        .计次循环首 (局_组件.取项目数 (), 局_列表框计次)
            局_临时文本 ＝ 局_临时文本 ＋ 局_组件.取项目文本 (局_列表框计次 － 1) ＋ “<|>” ＋ 到文本 (局_组件.取项目数值 (局_列表框计次 － 1)) ＋ “<||>” ＋ 到文本 (局_组件.是否被选中 (局_列表框计次 － 1)) ＋ “<|||>”
        .计次循环尾 ()
        局_临时文本 ＝ 局_临时文本 ＋ “<||||>” ＋ 到文本 (局_组件.现行选中项)
        局_临时文本 ＝ 子文本替换 (局_临时文本, #引号, “#引号”, , , 真)
        写配置项 (配置文件名, “选择列表框”, 取组件名称 (局_组件), 局_临时文本)
    .如果真结束

.计次循环尾 ()
清除组件寻找句柄 (局_寻找句柄)
返回 (局_组件数量)

.子程序 批量_选择列表框_读取配置, 整数型, 公开, 与"批量_选择列表框_保存配置()"命令一起用的!  返回被操作的选择列表框数量!
.参数 组件的父窗口, 窗口, , 直接填写顶级窗口就行了,如:_启动窗口
.参数 配置文件名, 文本型, 可空, 可空:默认保存在根目录\data目录下,名为setsoft.ini
.局部变量 局_寻找句柄, 整数型
.局部变量 局_计次, 整数型
.局部变量 局_组件, 选择列表框
.局部变量 局_临时文本, 文本型
.局部变量 局_组件数量, 整数型
.局部变量 局_列表框计次, 整数型
.局部变量 局_临时数组, 文本型, , "0"
.局部变量 所处位置, 整数型

.如果真 (配置文件名 ＝ “”)
    配置文件名 ＝ 取默认目录 ()
.如果真结束
局_寻找句柄 ＝ 寻找组件 (组件的父窗口, , “选择列表框”, , )
局_组件数量 ＝ 取找到组件数目 (局_寻找句柄)
.计次循环首 (局_组件数量, 局_计次)
    局_组件 ＝ 取所找到组件 (局_寻找句柄, 局_计次 － 1)
    局_临时文本 ＝ 读配置项 (配置文件名, “选择列表框”, 取组件名称 (局_组件), “”)
    局_临时文本 ＝ 子文本替换 (局_临时文本, “#引号”, #引号, , , 真)
    .如果真 (局_临时文本 ＝ “”)
        到循环尾 ()
    .如果真结束
    局_组件.清空 ()
    局_临时数组 ＝ 分割文本 (局_临时文本, “<|||>”, )
    .计次循环首 (取数组成员数 (局_临时数组) － 1, 局_列表框计次)
        所处位置 ＝ 局_组件.加入项目 (文本_取左边 (局_临时数组 [局_列表框计次], “<|>”, , ), 到数值 (文本_取中间 (局_临时数组 [局_列表框计次], “<|>”, “<||>”, , , , )))
        局_组件.选中项目 (所处位置, 选择 (文本_取右边 (局_临时数组 [局_列表框计次], “<||>”, , ) ＝ “真”, 真, 假))
    .计次循环尾 ()
    .如果真 (取数组成员数 (局_临时数组) ＞ 0)
        局_组件.现行选中项 ＝ 到数值 (文本_取右边 (局_临时数组 [取数组成员数 (局_临时数组)], “<||||>”, , ))

    .如果真结束
    清除数组 (局_临时数组)
.计次循环尾 ()
清除组件寻找句柄 (局_寻找句柄)
返回 (局_组件数量)

外卖小哥

学习学习

duisir

6666666666666666666666666

邪七

这个必须支持了！

邪七

支持一下！

doudou1234

#在这里快速回复#..。。。。。...。。。。。。。。。。。。。。。。。。。。。。。。

zzy5012

6666666666666

一直在沉默

6666666666666666666666666666666666666666666666666