求问关于mysql中某一个表的数据如何全部添加到超级列表框

隐匿

如图：求问关于mysql中某一个表的数据如何全部添加到超级列表框？？

求个大神写个例子！！折腾了半天

iamsunworld

.版本 2
.支持库 mysql
.支持库 spec
.支持库 iext

.程序集 窗口程序集_启动窗口
.程序集变量 SQL语句, 文本型
.程序集变量 MySql句柄, 整数型
.程序集变量 记录集, 整数型
.程序集变量 N, 整数型

.子程序 __启动窗口_创建完毕



.子程序 _按钮1_被单击
.局部变量 字段总数, 整数型
.局部变量 临时文本, 文本型
.局部变量 N1, 整数型
.局部变量 字段结果, 文本型

' 连接MySQL数据库
MySql句柄 ＝ 连接MySql (“192.168.0.3”, “root”, “11111111”, “cstest”, 3306)
.如果 (执行SQL语句 (MySql句柄, “SET NAMES GBK”) ＝ 假)
    信息框 (“连接数据库失败！”, #错误图标, , )
    结束 ()
.否则
    调试输出 (“连接测试服务器成功！”)
.如果结束
SQL语句 ＝ “select * from 登陆日志 limit 100”  ' cha询100条
.如果 (执行SQL语句 (MySql句柄, SQL语句) ＝ 真)
    记录集 ＝ 取记录集 (MySql句柄)
    字段总数 ＝ 取字段总数 (记录集)
    ' 把数据字段插入到超级列表框
    .计次循环首 (字段总数, N)
        序号到字段名 (记录集, N － 1, 临时文本)
        超级列表框1.插入列 (-1, 临时文本, 90, , , )
    .计次循环尾 ()
    ' 读取数据到超级列表框’
    .计次循环首 (取记录集行数 (记录集), N)
        超级列表框1.插入表项 (, , , , , )
        .计次循环首 (字段总数, N1)
            序号到字段名 (记录集, N1 － 1, 临时文本)
            读字段值 (记录集, 临时文本, 字段结果)
            超级列表框1.置标题 (N － 1, N1 － 1, 字段结果)
        .计次循环尾 ()
        ' 下移一条记录’
        到下一行 (记录集)
    .计次循环尾 ()
    释放记录集 (记录集)
.否则
    信息框 (“cha询失败，请检查SQL语句!”, 0, , )
.如果结束
断开MySql (MySql句柄)

cff123124

首先连接数据库，然后可以执行SQL语句，或者读字段，等方法