|
双击运行程序,可以看到一个类似屏保的蝴蝶飞舞的页面,这时你的桌面就处在锁定之中如果没有输入密码,你就不能进行文明用语作。
只要的你鼠标移动的中间位置,就会显示输入密码的一个文本框,你可以在此输入密码进入系统文明用语作,你如果移开鼠标,这个文本框将会消失,直到你再次移动鼠标在此区域时它又会重新显示。
输入正确的密码后,你只要按Esc键就会退出本程序,你的鼠标如果不在文本框内,本程序就会自动退出;如果你的鼠标在文本框内,或者你可以直接移动鼠标到本文本框外,程序也会自动退出。
本程序并不会对系统造成任何伤害,利用本程序时请记住密码,一旦忘记密码,那么,对不起,你只能重新启动你的计算机。
你也可以在看不到文本框的情况下直接输入密码,这时也会有以上的功能。
在本程序中,还增加了一些特效,你的鼠标只要在文本框中滚动,你就会看到你窗口的透明度在逐渐的变化。
具体如下:
超文本浏览框、标签、编辑框各一个,flash素材一个,命名为“MotionD11.swf”
.版本 2
.全局变量 变量1
程序集代码:
.版本 2
.支持库 eAPI
.支持库 EdirectX
.支持库 HtmlView
.程序集 窗口程序集1
.子程序 _编辑框1_内容被改变
.如果 (编辑框1.内容 = “234sushe”)
显示任务栏 ()
显示桌面图标 ()
显示开始按钮 ()
写注册项 (#现行用户, “Software\Microsoft\Windows\CurrentVersion\Policies\System\DisableTaskmgr”, 0)
_启动窗口.总在最前 = 假
解除按键屏蔽 ()
_启动窗口.获取焦点 ()
.否则
编辑框1.获取焦点 ()
.如果结束
.子程序 __启动窗口_可否被关闭, 逻辑型
.如果 (编辑框1.内容 = “234sushe”)
解除按键屏蔽 ()
返回 (真)
.否则
返回 (假)
.如果结束
.子程序 __启动窗口_获得焦点
' 输入正确的密码后,如果鼠标的位置在编辑框之外,那么窗口就会销毁,即退出本程序
.如果 (编辑框1.内容 = “234sushe”)
.如果 (编辑框1.顶边 > 取鼠标垂直位置 () 或 编辑框1.顶边 + 编辑框1.高度 < 取鼠标垂直位置 () 或 编辑框1.左边 > 取鼠标水平位置 () 或 编辑框1.左边 + 编辑框1.宽度 < 取鼠标水平位置 ())
解除按键屏蔽 ()
_启动窗口.销毁 ()
.否则
编辑框1.获取焦点 ()
.如果结束
.否则
.如果结束
.子程序 _编辑框1_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
' 输入正确的密码后,如果鼠标的位置在编辑框之内,只要按住鼠标左键,将鼠标移出编辑框,窗口就会自动消失,即退出本程序
.如果 (编辑框1.内容 = “234sushe”)
.如果 (编辑框1.宽度 - 横向位置 > 编辑框1.宽度 或 编辑框1.高度 - 纵向位置 > 编辑框1.高度 或 编辑框1.宽度 < 横向位置 或 编辑框1.高度 < 纵向位置)
解除按键屏蔽 ()
_启动窗口.销毁 ()
.否则
编辑框1.获取焦点 ()
.如果结束
.否则
.如果结束
.子程序 _时钟1_周期事件
.如果 (编辑框1.左边 < 取鼠标水平位置 () 且 取鼠标水平位置 () < 编辑框1.左边 + 编辑框1.宽度 且 编辑框1.顶边 < 取鼠标垂直位置 () 且 取鼠标垂直位置 () < 编辑框1.顶边 + 编辑框1.高度)
标签1.可视 = 真
编辑框1.可视 = 真
编辑框1.获取焦点 ()
.否则
编辑框1.可视 = 假
标签1.可视 = 假
编辑框1.获取焦点 ()
.如果结束
.子程序 _编辑框1_放开某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型
.如果真 (功能键状态 = 5 且 键代码 = #键值常量.键回车)
时钟1.时钟周期 = 0
标签1.可视 = 真
编辑框1.可视 = 真
.如果真结束
.子程序 __启动窗口_创建完毕
.局部变量 变量, 文本型
设置窗口透明度 (_启动窗口.取窗口句柄 (), 220)
' 每日一贴1.载入文件 (取运行目录 () + “\每日一贴.txt”)
' 每日一贴1.打开 ()
写注册项 (#现行用户, “Software\Microsoft\Windows\CurrentVersion\Policies\System\DisableTaskmgr”, 1)
隐藏任务栏 ()
隐藏桌面图标 ()
隐藏开始按钮 ()
位置 = 3
_启动窗口.置托盘图标 (, “播放器”)
在任务条中显示 = 假
超文本浏览框1.左边 = _启动窗口.左边
超文本浏览框1.顶边 = _启动窗口.顶边
超文本浏览框1.高度 = _启动窗口.高度
超文本浏览框1.宽度 = _启动窗口.宽度
超文本浏览框1.跳转 (取运行目录 () + “\MotionD11.swf”, , )
编辑框1.左边 = (超文本浏览框1.宽度 - 编辑框1.宽度) ÷ 2
编辑框1.顶边 = (超文本浏览框1.高度 - 编辑框1.高度) ÷ 2
标签1.左边 = 编辑框1.左边
标签1.顶边 = 编辑框1.顶边 - 标签1.高度
_启动窗口.总在最前 = 真
屏蔽按键 (92)
编辑框1.获取焦点 ()
.子程序 _编辑框1_滚轮被滚动, 逻辑型
.参数 滚动距离, 整数型
.参数 功能键状态, 整数型
.如果 (变量1 > 250)
变量1 = 10
.否则
.如果 (变量1 < 10)
变量1 = 250
.否则
.如果 (滚动距离 > 0)
变量1 = 变量1 + 5
.否则
.如果结束
.如果 (滚动距离 < 0)
变量1 = 变量1 - 5
.否则
.如果结束
设置窗口透明度 (_启动窗口.取窗口句柄 (), 变量1)
.如果结束
.如果结束
|
|