mp3播放者

想学坏的小孩

.版本 2

.程序集 窗口程序集1

.子程序 _开始播放按钮_被单击
.局部变量 待播放MP3, 文本型, , "0"
.局部变量 容器1, 整数型

.计次循环首 (选择列表框1.取项目数 (), 容器1)
    .如果真 (选择列表框1.是否被选中 (容器1 － 1) ＝ 真)
        加入成员 (待播放MP3, 选择列表框1.取项目文本 (容器1 － 1))
    .如果真结束

.计次循环尾 ()
.如果真 (取数组成员数 (待播放MP3) ＞ 0)
    播放MP3 (-1, 待播放MP3)
.如果真结束


.子程序 _停止播放按钮_被单击

停止播放 ()

.子程序 _搜寻按钮_被单击

选择列表框1.清空 ()
载入 (窗口1, , 真)

.子程序 _全部选中按钮_被单击
.局部变量 容器1, 整数型

.计次循环首 (选择列表框1.取项目数 (), 容器1)
    选择列表框1.选中项目 (容器1 － 1, 真)
.计次循环尾 ()

.子程序 _保存列表按钮_被单击
.局部变量 字段表, 字段信息, , "1"
.局部变量 容器1, 整数型

.如果真 (通用对话框1.打开 () ＝ 真)
    字段表 [1].名称 ＝ “MP3文件名”
    字段表 [1].类型 ＝ #文本型
    字段表 [1].最大文本长度 ＝ 256
    .如果真 (创建 (通用对话框1.文件名, 字段表) ＝ 假 或 打开 (通用对话框1.文件名, , , , , , ) ＝ 假)
        信息框 (“保存歌曲列表失败！”, 0, )
        返回 ()
    .如果真结束
    .计次循环首 (选择列表框1.取项目数 (), 容器1)
        .如果真 (选择列表框1.是否被选中 (容器1 － 1) ＝ 真)
            加记录 (选择列表框1.取项目文本 (容器1 － 1))
        .如果真结束

    .计次循环尾 ()
    关闭 ()
.如果真结束


.子程序 _载入列表按钮_被单击

.如果真 (通用对话框2.打开 () ＝ 真 且 打开 (通用对话框2.文件名, , , , , , ) ＝ 真)
    选择列表框1.清空 ()
    .判断循环首 (尾记录后 () ＝ 假)
        选择列表框1.选中项目 (选择列表框1.加入项目 (读 (“MP3文件名”), ), 真)
        跳过 ()
    .判断循环尾 ()
    关闭 ()
.如果真结束





.版本 2

.程序集 窗口程序集2

.子程序 _窗口1_可否被关闭, 逻辑型

返回 (假)  ' 不允许本窗口被用户关闭

.子程序 _窗口1_首次激活

搜寻 (_启动窗口.驱动器框1.驱动器 ＋ “:\”)
.如果真 (是否已创建 (窗口1) ＝ 真)  ' 如果用户没有通过单击停止按钮销毁本窗口，则销毁。
    销毁 ()
.如果真结束


.子程序 搜寻
.参数 目录, 文本型
.局部变量 文件名, 文本型

处理事件 ()  ' 给出机会以接收停止按钮事件。
.如果真 (是否已创建 (窗口1) ＝ 假)  ' 如果用户单击停止按钮销毁了本窗口，则直接返回。
    返回 ()
.如果真结束
.如果真 (取文本右边 (目录, 1) ≠ “\”)
    目录 ＝ 目录 ＋ “\”
.如果真结束
文件名 ＝ 寻找文件 (目录 ＋ “*.mp3”, )
.判断循环首 (文件名 ≠ “”)
    标签2.标题 ＝ 目录 ＋ 文件名
    标签2.刷新显示 ()
    _启动窗口.选择列表框1.加入项目 (目录 ＋ 文件名, )
    文件名 ＝ 寻找文件 (, )
.判断循环尾 ()
文件名 ＝ 寻找文件 (目录 ＋ “*.*”, #子目录)
.判断循环首 (文件名 ≠ “”)
    .如果真 (取文本左边 (文件名, 1) ≠ “.”)
        搜寻 (目录 ＋ 文件名)
    .如果真结束
    文件名 ＝ 寻找文件 (, #子目录)
.判断循环尾 ()

.子程序 _停止按钮_被单击

销毁 ()

sanbuqu

嗯不错，外卖的，路过

泪涟涟

下载看一下。。。