蓝奏云4月2号

轨迹轨迹

蓝奏云又更新呐

轨迹轨迹

.版本 2
.支持库 spec
.支持库 RegEx
.支持库 wmp9

.程序集 窗口程序集_启动窗口

.子程序 蓝奏云直链解析, 文本型, 公开
.参数 下载链接, 文本型
.参数 下载密码, 文本型, 可空
.局部变量 协议头管理, 类_POST数据类
.局部变量 网页源码, 文本型
.局部变量 解析结果, 文本型
.局部变量 JSON解析, 类_json

.判断开始 (下载密码 ＝ “”)
    解析结果 ＝ 无密码解析 (下载链接)
.默认
    解析结果 ＝ 带密码解析 (下载链接, 下载密码)
.判断结束

返回 (函数_蓝奏直链 (解析结果))

.子程序 带密码解析, 文本型
.参数 下载链接, 文本型
.参数 密码, 文本型
.局部变量 协议头, 文本型
.局部变量 网页源码, 文本型
.局部变量 接口路径, 文本型
.局部变量 请求地址, 文本型
.局部变量 提交数据, 文本型
.局部变量 JSON解析, 类_json
.局部变量 局_二次协议头, 文本型
.局部变量 下载连接, 文本型

协议头 ＝ 生成协议头 (“referer”, 下载链接)
网页源码 ＝ 获取网页源码 (下载链接, 协议头)
接口路径 ＝ 方法_取url (网页源码)
调试输出 (网页源码)
请求地址 ＝ 构造请求地址 (下载链接, 接口路径)
调试输出 (“二次提交网址：”, 请求地址)
提交数据 ＝ “action=downprocess” ＋ “&sign=” ＋ 方法_取sign (网页源码) ＋ “&kd=1&p=” ＋ 密码
调试输出 (“提交数据 ：”, 提交数据)
局_二次协议头 ＝ “referer:” ＋ 下载链接 ＋ #换行符 ＋ 协议头
网页源码 ＝ 编码_Utf8到Ansi (网页_访问 (请求地址, 1, 提交数据, , , 局_二次协议头, , , , , , , , ))
JSON解析.解析 (网页源码, , )
返回 (JSON解析.取通用属性 (“dom”, ) ＋ “/file/” ＋ JSON解析.取通用属性 (“url”, ))

.子程序 无密码解析, 文本型
.参数 下载链接, 文本型
.局部变量 基础域名, 文本型
.局部变量 框架路径, 文本型
.局部变量 网页源码, 文本型
.局部变量 接口路径, 文本型
.局部变量 提交数据, 文本型
.局部变量 JSON解析, 类_json
.局部变量 key, 文本型
.局部变量 wp_sign, 文本型

基础域名 ＝ 提取基础域名 (下载链接)
框架路径 ＝ 获取框架路径 (下载链接)
.如果真 (框架路径 ＝ “”)
    返回 (“”)
.如果真结束

网页源码 ＝ 获取网页源码 (基础域名 ＋ 框架路径, 生成协议头 (“referer”, 下载链接))
.如果真 (网页源码 ＝ “”)
    返回 (“”)
.如果真结束

接口路径 ＝ 正则_匹配接口路径 (网页源码)
key ＝ 提取参数 (网页源码, “key”)
wp_sign ＝ 提取参数 (网页源码, “wp_sign”)
提交数据 ＝ “action=downprocess&signs=%3Fctdf&websignkey=” ＋ key ＋ “&sign=” ＋ wp_sign ＋ “&websign=&kd=1&ves=1”
网页源码 ＝ 编码_Utf8到Ansi (网页_访问_对象 (基础域名 ＋ “/” ＋ 接口路径, 1, 提交数据, , , 生成协议头 (“referer”, 基础域名 ＋ 框架路径), , , , , , , , , , , , , ))
JSON解析.解析 (网页源码, , )
返回 (JSON解析.取通用属性 (“dom”, ) ＋ “/file/” ＋ JSON解析.取通用属性 (“url”, ))

.子程序 正则_匹配接口路径, 文本型
.参数 网页源码, 文本型
.局部变量 正则, 正则表达式类

正则.创建 (“url\s*:\s*'/(.*?)'”, 网页源码, , , , )
返回 (正则.取子匹配文本 (1, 1, ))


.子程序 生成协议头, 文本型
.参数 附加头, 文本型, 可空
.参数 值, 文本型, 可空
.局部变量 协议头管理, 类_POST数据类

协议头管理.添加 (“user-agent”, “Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36”, )
协议头管理.添加 (“accept-language”, “zh-CN,zh;q=0.9”, )
协议头管理.添加 (附加头, 值, )
返回 (协议头管理.获取协议头数据 ())

.子程序 方法_取url, 文本型
.参数 源文本, 文本型
.局部变量 局一次网址, 文本型, , "0"
.局部变量 i, 整数型

文本_取中间_批量 (源文本, “/ajaxm.php?file=”, “'”, 局一次网址, , , , , , , )
.计次循环首 (取数组成员数 (局一次网址), i)
    .如果真 (文本_是否为数字 (局一次网址 [i]))
        返回 (“/ajaxm.php?file=” ＋ 局一次网址 [i])
    .如果真结束

.计次循环尾 ()
返回 (“”)


.子程序 方法_取sign, 文本型, , 如果失效请更改此子程序从网页源码取出sign
.参数 源文本, 文本型
.局部变量 局一次分割网址, 文本型, , "0"
.局部变量 局二次分割网址, 文本型, , "0"
.局部变量 i, 整数型
.局部变量 正则, 正则表达式
.局部变量 结果, 搜索结果
.局部变量 最长字符串, 文本型
.局部变量 当前长度, 整数型
.局部变量 一次分割, 文本型, , "0"

一次分割 ＝ 分割文本 (源文本, “var bcdf”, )
正则.创建 (“'([A-Za-z0-9]{50,})'”, )  ' 匹配长度≥50的字符串
结果 ＝ 正则.搜索 (一次分割 [2], 1, )
.判断循环首 (真)
    当前长度 ＝ 取文本长度 (结果.取子匹配文本 (一次分割 [2], 1, ))
    .如果真 (当前长度 ＞ 取文本长度 (最长字符串))
        最长字符串 ＝ 结果.取子匹配文本 (一次分割 [2], 1, )
        返回 (最长字符串)

    .如果真结束

.判断循环尾 ()
返回 (“”)


.子程序 构造请求地址, 文本型
.参数 原始链接, 文本型
.参数 接口路径, 文本型
.局部变量 主域名, 文本型

主域名 ＝ 文本_取左边 (原始链接, “/”, -1, )
返回 (主域名 ＋ “/” ＋ 接口路径)

.子程序 提取参数, 文本型
.参数 网页源码, 文本型
.参数 参数名, 文本型
.局部变量 正则, 正则表达式类

正则.创建 (参数名 ＋ “\s*=\s*'(\w+)'”, 网页源码, , , , )

返回 (正则.取子匹配文本 (1, 1, ))

.子程序 获取框架路径, 文本型
.参数 下载链接, 文本型
.局部变量 正则, 正则表达式类
.局部变量 网页源码, 文本型

网页源码 ＝ 获取网页源码 (下载链接, 生成协议头 (“user-agent:Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/130.0.0.0 Safari/537.36 Edg/130.0.0.0”, ))
正则.创建 (“src=” ＋ #引号 ＋ “/(.*?)” ＋ #引号 ＋ “ frameborder”, 网页源码, , , , )
返回 (“/” ＋ 正则.取子匹配文本 (1, 1, ))


.子程序 提取基础域名, 文本型
.参数 下载链接, 文本型

返回 (“https://” ＋ 文本_取出中间文本 (下载链接, “https://”, “com”, , ) ＋ “com”)

.子程序 获取网页源码, 文本型
.参数 URL, 文本型
.参数 协议头, 文本型, 可空

返回 (编码_Utf8到Ansi (网页_访问 (URL, 0, , , , 协议头, , , , , , 真, , )))

.子程序 函数_蓝奏直链, 文本型
.参数 参数_临时链接, 文本型
.局部变量 局部_recv数据, 文本型

网页_访问_对象 (参数_临时链接, 1, , , , , 局部_recv数据, , 真)
返回 (网页_协议头_取信息 (局部_recv数据, “Location”))

.子程序 _按钮1_被单击
.局部变量 直链, 文本型

直链 ＝ 蓝奏云直链解析 (“https://wwqj.lanzoum.com/izuNP2slsupa”, “1234”)
编辑框1.内容 ＝ 直链
播放器1.地址 ＝ 直链


.子程序 __启动窗口_创建完毕

涤尘

感谢分享

涤尘

感谢分享

轨迹轨迹

xcxc168 发表于 2025-4-4 03:45
老表，搞个文件夹带密码的啊

文件夹带密码就和单个文件一样了

Sam8

666666666666666666666666

tang1903

解析直链成功后，使用精易模块的“文件_下载1”命令下载时下载的是个5KB的错误文件，直接在浏览器上用直链下载就没问题，有没有大佬知道是咋回事。。

叶子来了

666666666666666666666

please

感谢分享，支持开源！！！

查过

已经顶贴，感谢您对论坛的支持！

豆豆灰常开心

全都是大佬~