|
|
25精币
如何在这个源码增加快速搜索功能
.版本 2
.支持库 iext
.程序集 窗口程序集_启动窗口
.程序集变量 编辑模式, 整数型, , , 0新增，1修改
.程序集变量 时钟计时, 整数型, , , 如果有密码5分钟后自动锁定
.程序集变量 是否锁定, 逻辑型, , , 判断当前软件是否锁定
.子程序 __启动窗口_创建完毕
时钟计时 ＝ 0
是否锁定 ＝ 假
置托盘图标 (#icon, “远程桌面管理器”)
连接数据库 ()
时钟1.时钟周期 ＝ 1000
加载配置列表 ()
.子程序 连接数据库
.参数 密码, 文本型, 可空
.局部变量 数据库路径, 文本型
数据库路径 ＝ 取运行目录 () ＋ “\data.db”
.如果真 (文件是否存在 (数据库路径) ＝ 假)
' //写出一个没有密码的空数据库
写到文件 (取运行目录 () ＋ “\data.db”, #data)
.如果真结束
.判断循环首 (打开 (数据库路径, “db”, , , , 密码, ) ＝ 假)
.如果真 (输入密码 (密码, 0) ＝ 假)
结束 ()
返回 ()
.如果真结束
.判断循环尾 ()
.子程序 加载配置列表
.局部变量 i, 整数型
.局部变量 r, 整数型
列表框.全部删除 ()
.计次循环首 (取记录数 (), i)
跳到 (i)
r ＝ 列表框.插入表项 (-1, 到文本 (i), , , , )
列表框.置标题 (r, 1, 读 (“IP域名”))
列表框.置标题 (r, 2, 到文本 (读 (“连接端口”)))
列表框.置标题 (r, 3, 读 (“用户名”))
列表框.置标题 (r, 4, 读 (“备注”))
.计次循环尾 ()
.子程序 _列表框_被双击, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
_超级按钮连接_被单击 ()
.子程序 _超级按钮连接_被单击, , , 本源码来自易语言资源网(www.eyuyan.la)
.局部变量 索引, 整数型
.局部变量 文件, 文本型
.局部变量 路径, 文本型
.局部变量 窗口标题, 文本型
.局部变量 窗口句柄, 整数型
索引 ＝ 列表框.现行选中项
.如果真 (索引 ＝ -1)
提示框 (“请选择一项再连接”, , _启动窗口)
返回 ()
.如果真结束
跳到 (索引 ＋ 1)
.如果 (读 (“是否全屏”))
文件 ＝ 文件 ＋ “screen mode id:i:2” ＋ #换行符 ' //1当前位置，2全屏
.否则
文件 ＝ 文件 ＋ “screen mode id:i:1” ＋ #换行符 ' //1当前位置，2全屏
.如果结束
文件 ＝ 文件 ＋ “winposstr:s:0,1,364,170,2300,1289” ＋ #换行符
文件 ＝ 文件 ＋ “compression:i:1” ＋ #换行符 ' //是否压缩
文件 ＝ 文件 ＋ “use multimon:i:0” ＋ #换行符 ' //全屏/将我的所有监视器用于远程会话(U)。本程序不用这个参数
文件 ＝ 文件 ＋ “username:s:” ＋ 读 (“用户名”) ＋ #换行符 ' //登录名
文件 ＝ 文件 ＋ “full address:s:” ＋ 读 (“IP域名”) ＋ “:” ＋ 到文本 (读 (“连接端口”)) ＋ #换行符
文件 ＝ 文件 ＋ “password 51:b:” ＋ 取Crypt密码 (读 (“密码”)) ＋ #换行符
文件 ＝ 文件 ＋ “desktopwidth:i:” ＋ 到文本 (读 (“屏幕宽度”)) ＋ #换行符
文件 ＝ 文件 ＋ “desktopheight:i:” ＋ 到文本 (读 (“屏幕高度”)) ＋ #换行符
文件 ＝ 文件 ＋ “session bpp:i:” ＋ 到文本 (读 (“颜色”)) ＋ #换行符
文件 ＝ 文件 ＋ “displayconnectionbar:i:” ＋ 选择 (读 (“连接栏”), “1”, “0”) ＋ #换行符
文件 ＝ 文件 ＋ “keyboardhook:i:” ＋ 到文本 (读 (“键盘”)) ＋ #换行符 ' //键盘挂钩，0，1，2
文件 ＝ 文件 ＋ “audiocapturemode:i:” ＋ 到文本 (读 (“音频录制”)) ＋ #换行符 ' //远程音频录制 1,0
文件 ＝ 文件 ＋ “audiomode:i:” ＋ 到文本 (读 (“远程音频”)) ＋ #换行符 ' //音频模式 0，1，2
文件 ＝ 文件 ＋ “videoplaybackmode:i:1” ＋ #换行符 ' //视频播放模式
文件 ＝ 文件 ＋ “networkautodetect:i:1” ＋ #换行符 ' //自动检测网络
文件 ＝ 文件 ＋ “bandwidthautodetect:i:1” ＋ #换行符 ' //宽带自动检测
文件 ＝ 文件 ＋ “enableworkspacereconnect:i:0” ＋ #换行符 ' //启动工作区自动连接
文件 ＝ 文件 ＋ “disable cursor setting:i:0” ＋ #换行符 ' //禁用光标设置
文件 ＝ 文件 ＋ “connection type:i:” ＋ 到文本 (读 (“性能”)) ＋ #换行符
文件 ＝ 文件 ＋ “disable wallpaper:i:” ＋ 选择 (读 (“桌面背景”), “0”, “1”) ＋ #换行符
文件 ＝ 文件 ＋ “allow font smoothing:i:” ＋ 选择 (读 (“字体平滑”), “0”, “1”) ＋ #换行符
文件 ＝ 文件 ＋ “allow desktop composition:i:” ＋ 选择 (读 (“桌面合成”), “0”, “1”) ＋ #换行符
文件 ＝ 文件 ＋ “disable full window drag:i:” ＋ 选择 (读 (“拖动显示”), “0”, “1”) ＋ #换行符
文件 ＝ 文件 ＋ “disable menu anims:i:” ＋ 选择 (读 (“菜单动画”), “0”, “1”) ＋ #换行符
文件 ＝ 文件 ＋ “disable themes:i:” ＋ 选择 (读 (“视觉样式”), “0”, “1”) ＋ #换行符
文件 ＝ 文件 ＋ “bitmapcachepersistenable:i:” ＋ 选择 (读 (“持久位图”), “1”, “0”) ＋ #换行符
文件 ＝ 文件 ＋ “autoreconnection enabled:i:” ＋ 选择 (读 (“自动连接”), “1”, “0”) ＋ #换行符
文件 ＝ 文件 ＋ “redirectprinters:i:” ＋ 选择 (读 (“打印机”), “1”, “0”) ＋ #换行符 ' //打印机
文件 ＝ 文件 ＋ “redirectclipboard:i:” ＋ 选择 (读 (“剪贴板”), “1”, “0”) ＋ #换行符 ' //剪贴板
文件 ＝ 文件 ＋ “redirectcomports:i:” ＋ 选择 (读 (“端口”), “1”, “0”) ＋ #换行符 ' //端口
文件 ＝ 文件 ＋ “redirectsmartcards:i:” ＋ 选择 (读 (“智能卡”), “1”, “0”) ＋ #换行符 ' //智能卡
.如果 (读 (“驱动器”))
文件 ＝ 文件 ＋ “drivestoredirect:s:*” ＋ #换行符 ' 驱动器，“”时没有驱动器
.否则
文件 ＝ 文件 ＋ “drivestoredirect:s:” ＋ #换行符 ' 驱动器，“”时没有驱动器
.如果结束
.如果 (读 (“视频捕获”))
文件 ＝ 文件 ＋ “camerastoredirect:s:*” ＋ #换行符 ' 视频捕获，“”时不捕获
.否则
文件 ＝ 文件 ＋ “camerastoredirect:s:” ＋ #换行符 ' 视频捕获，“”时不捕获
.如果结束
.如果 (读 (“其他设备”))
文件 ＝ 文件 ＋ “devicestoredirect:s:*” ＋ #换行符 ' 其他支持，“”时不支持
.否则
文件 ＝ 文件 ＋ “devicestoredirect:s:” ＋ #换行符 ' 其他支持，“”时不支持
.如果结束
文件 ＝ 文件 ＋ “redirectposdevices:i:0” ＋ #换行符 ' //重定向mos器件
文件 ＝ 文件 ＋ “authentication level:i:” ＋ 到文本 (读 (“身份验证”)) ＋ #换行符 ' //身份验证级别，0，1，2
' 文件 ＝ 文件 ＋ “gatewayhostname:s:” ＋ #换行符 ' 网关主机名
' 文件 ＝ 文件 ＋ “gatewayusagemethod:i:2” ＋ #换行符 ' 网关
' 文件 ＝ 文件 ＋ “gatewaycredentialssource:i:4” ＋ #换行符 ' 网关证书源
' 文件 ＝ 文件 ＋ “gatewayprofileusagemethod:i:0” ＋ #换行符 ' 网关配置
' 文件 ＝ 文件 ＋ “promptcredentialonce:i:0” ＋ #换行符 ' 快速认证
' 文件 ＝ 文件 ＋ “gatewaybrokeringtype:i:0” ＋ #换行符 ' 代理类型
' 文件 ＝ 文件 ＋ “gatewayprofileusagemethod:i:0” ＋ #换行符 ' 网关配置
' 目录_取特定目录EX (35)
窗口标题 ＝ 到文本 (索引) ＋ “ - ” ＋ 列表框.取标题 (索引, 1) ＋ “:” ＋ 列表框.取标题 (索引, 2) ＋ “ - 远程桌面连接”
窗口句柄 ＝ 窗口_取句柄 (, , , 窗口标题)
.如果 (窗口句柄 ＞ 0)
窗口_置状态 (窗口句柄, 3)
.否则
路径 ＝ 目录_取特定目录EX (35) ＋ “\” ＋ 到文本 (索引) ＋ “.rdp”
写到文件 (路径, 到字节集 (文件))
运行 (“mstsc ” ＋ 路径 ＋ “ /console”, 真, )
.如果结束
' 删除文件 (路径)
位置 ＝ 2
.子程序 _超级按钮添加_被单击
编辑模式 ＝ 0
载入 (连接编辑, _启动窗口, 真)
.子程序 _超级按钮修改_被单击
.局部变量 索引, 整数型
索引 ＝ 列表框.现行选中项
.如果真 (索引 ＝ -1)
提示框 (“请选择一项再修改”, , _启动窗口)
返回 ()
.如果真结束
编辑模式 ＝ 1
载入 (连接编辑, _启动窗口, 真)
.子程序 _超级按钮删除_被单击
.局部变量 索引, 整数型
.局部变量 条件
索引 ＝ 列表框.现行选中项
.如果真 (索引 ＝ -1)
提示框 (“请选择一项再删除”, , _启动窗口)
返回 ()
.如果真结束
.如果真 (信息框 (“是否删除 ” ＋ 列表框.取标题 (索引, 1) ＋ “(” ＋ 列表框.取标题 (索引, 4) ＋ “) 连接配置？”, #是否钮, “删除配置”, ) ＝ #否钮)
返回 ()
.如果真结束
跳到 (索引 ＋ 1)
删除 ()
彻底删除 ()
加载配置列表 ()
.子程序 __启动窗口_位置被改变
窗口_提示框位置更新 (_启动窗口)
.子程序 __启动窗口_尺寸被改变
.如果真 (位置 ＝ 2)
可视 ＝ 假
.如果真结束
.子程序 __启动窗口_托盘事件
.参数 操作类型, 整数型
.局部变量 密码, 文本型
.如果真 (是否已加密 (取运行目录 () ＋ “\data.db”) 且 是否锁定)
.如果 (输入密码 (密码, 0))
连接数据库 (密码)
时钟1.时钟周期 ＝ 1000
加载配置列表 ()
是否锁定 ＝ 假
时钟计时 ＝ 0
.否则
返回 ()
.如果结束
.如果真结束
可视 ＝ 真
位置 ＝ 0
.子程序 _时钟1_周期事件
.局部变量 i, 整数型
.局部变量 窗口标题, 文本型
.局部变量 窗口句柄, 整数型
.计次循环首 (列表框.取表项数 (), i)
窗口标题 ＝ 到文本 (i － 1) ＋ “ - ” ＋ 列表框.取标题 (i － 1, 1) ＋ “:” ＋ 列表框.取标题 (i － 1, 2) ＋ “ - 远程桌面连接”
窗口句柄 ＝ 窗口_取句柄 (, , , 窗口标题)
.如果 (窗口句柄 ＞ 0)
列表框.置图片 (i － 1, 0, 0)
.否则
列表框.置图片 (i － 1, 0, -1)
删除文件 (目录_取特定目录EX (35) ＋ “\” ＋ 到文本 (i － 1) ＋ “.rpd”)
.如果结束
.计次循环尾 ()
时钟计时 ＝ 时钟计时 ＋ 1
.如果真 (时钟计时 ＝ 5 × 60) ' //5分钟
时钟1.时钟周期 ＝ 0
全部关闭 ()
列表框.全部删除 ()
是否锁定 ＝ 真
位置 ＝ 2
.如果真结束
.子程序 _超级按钮设置_被单击
.局部变量 密码, 文本型
.如果真 (输入密码 (密码, 1))
.如果 (置数据库密码 (密码))
提示框 (“密码修改成功”, , _启动窗口)
.否则
提示框 (“密码修改失败”, , _启动窗口)
.如果结束
.如果真结束
.子程序 __启动窗口_将被销毁
.局部变量 i, 整数型
.计次循环首 (列表框.取表项数 (), i)
删除文件 (目录_取特定目录EX (35) ＋ “\” ＋ 到文本 (i － 1) ＋ “.rpd”)
.计次循环尾 ()
|
|
粤公网安备 44522102000125 增值电信业务经营许可证 粤B2-20192173
发表于 2024-9-7 17:45:48
主题置顶卡
沉默卡
变色卡
楼主
扫一扫，关注易界动态