https下载器

林一学编程

3666谢谢分享新手

sjtkxy

谢谢分享新手

xjshuaishuai

谢谢分享！

WSW120

谢谢分享

无敌灰灰

修改了啥至少说一下吧

深圳梦

感谢分享！

清风徐来2

感谢分享

杰西卡技术传媒

感谢分享！

晨晨88

飞机

吴亚杰

不知道这么修改发布的帖子  我修改了源码

.版本 2
.支持库 iext
.支持库 eAPI

.程序集 窗口程序集_启动窗口, , , www.eyuyan.la
.程序集变量 皮肤, 自绘皮肤
.程序集变量 子皮肤, 多功能外形框
.程序集变量 结果, 文本型, , "0"
.程序集变量 下载, 下载标识数据, , "0"

.子程序 __启动窗口_创建完毕
.局部变量 目录, 文本型


取命令行 (结果)
创建管道 (“wbfxcgesdzrzgazergss”, &数据到达)
.如果真 (禁止重复运行 (“askmmhjsgsgsefgu”) ＝ 真)
    .如果真 (取数组成员数 (结果) ＞ 0)
        .如果真 (连接管道 () ≠ 0)
            发送数据 (结果 [1])
            结束 ()
        .如果真结束

    .如果真结束

.如果真结束
.如果真 (取数组成员数 (结果) ＞ 0)
    下载 (结果 [1])
.如果真结束
目录 ＝ 取运行目录 () ＋ “\背景图片\”

.如果 (目录_是否存在W (目录) ＝ 假)
    .如果真 (文件是否存在 (目录 ＋ “说明.txt”) ＝ 假)
        写到文件 (目录 ＋ “说明.txt”, 到字节集 (#说明))
    .如果真结束

.否则
    创建目录 (取运行目录 () ＋ “\背景图片\”)
    处理事件 ()
    写到文件 (目录 ＋ “说明.txt”, 到字节集 (#说明))
    处理事件 ()
.如果结束

皮肤 ()


.子程序 下载
.参数 内容, 文本型
.局部变量 地址, 文本型
.局部变量 分割, 文本型, , "0"
.局部变量 索引, 整数型
.局部变量 文件名称, 文本型
.局部变量 临时数据, 下载标识数据

分割 ＝ 分割文本 (内容, “&&”, )
文件名称 ＝ 子文本替换 (分割 [2], “?”, , , , 真)  ' 去掉问号
.如果 (取数组成员数 (分割) ＝ 2)  ' 判断是否输入了保存地址
    地址 ＝ 取运行目录 () ＋ “\” ＋ 文件名称 ＋ 取文本右边 (分割 [1], 取文本长度 (分割 [1]) － 倒找文本 (分割 [1], “.”, , 假) ＋ 1)  ' 没有保存地址 默认为运行目录
.否则
    地址 ＝ 分割 [3] ＋ “\” ＋ 文件名称 ＋ 取文本右边 (分割 [1], 取文本长度 (分割 [1]) － 倒找文本 (分割 [1], “.”, , 假) ＋ 1)  ' 有保存目录
.如果结束
局_下载标识 ＝ 局_下载标识 ＋ 1
临时数据.下载名称 ＝ 地址
临时数据.下载地址 ＝ 分割 [1]
临时数据.下载标识 ＝ 局_下载标识
加入成员 (下载, 临时数据)
HTTP下载_开始 (分割 [1], 地址, 到整数 (&下载回调), 局_下载标识)
索引 ＝ _启动窗口.超级列表框1.插入表项 (, , , , , 局_下载标识)
超级列表框1.置标题 (索引, 0, 文件名称)
超级列表框1.置标题 (索引, 1, 分割 [1])

.子程序 检测进程, 逻辑型
.参数 进程名, 文本型
.局部变量 进程信息, 进程信息, , "0"
.局部变量 i, 整数型
.局部变量 a, 逻辑型

a ＝ 假
进程信息 ＝ 取系统进程列表 ()
.计次循环首 (取数组成员数 (进程信息), i)
    .如果真 (进程信息 .进程名称 ＝ 进程名)
        a ＝ 真
        跳出循环 ()
    .如果真结束

.计次循环尾 ()
返回 (a)

.子程序 数据到达
.参数 内容, 文本型

下载 (内容)

.子程序 下载回调, , , 本源码来自易语言资源网(www.eyuyan.la)
.参数 下载标识, 整数型, , 下载线程的标识
.参数 下载状态, 整数型, , 下载线程的状态
.参数 文件总大小, 长整数型, , B
.参数 已下载大小, 长整数型, , B
.参数 剩余大小, 长整数型, , B
.参数 下载进度, 小数型
.参数 平均速度, 小数型, , KB/S
.参数 下载用时, 整数型, , ms
.参数 下载路径, 文本型
.局部变量 文件大小, 文本型
.局部变量 下载大小, 文本型
.局部变量 a, 长整数型
.局部变量 b, 长整数型
.局部变量 速度, 文本型
.局部变量 索引, 整数型

.如果真 (文件总大小 ÷ 1024 ÷ 1024 ＝ 0)
    文件大小 ＝ 到文本 (文件总大小 ÷ 1024) ＋ “KB”
    返回 ()
.如果真结束
文件大小 ＝ 到文本 (四舍五入 (文件总大小 ÷ 1024 ÷ 1024, 1)) ＋ “MB”
.如果真 (文件总大小 ÷ 1024 ÷ 1024 ＞ 1024)
    文件大小 ＝ 到文本 (四舍五入 (文件总大小 ÷ 1024 ÷ 1024 ÷ 1024, 1)) ＋ “G”
.如果真结束


.如果真 (已下载大小 ÷ 1024 ÷ 1024 ＝ 0)
    下载大小 ＝ 到文本 (已下载大小 ÷ 1024) ＋ “KB”
    返回 ()
.如果真结束
下载大小 ＝ 到文本 (四舍五入 (已下载大小 ÷ 1024 ÷ 1024, 1)) ＋ “MB”
.如果真 (文件总大小 ÷ 1024 ＝ 0)
    下载大小 ＝ 到文本 (四舍五入 (已下载大小, 1)) ＋ “B”
.如果真结束

.如果 (平均速度 ＞ 1024)
    平均速度 ＝ 平均速度 ÷ 1024
    速度 ＝ 到文本 (四舍五入 (平均速度, 1)) ＋ “MB/S”
.否则
    速度 ＝ 到文本 (四舍五入 (平均速度, 1)) ＋ “KB/S”
.如果结束
索引 ＝ 超级列表框1.查找表项数值 (, 下载标识)
超级列表框1.置标题 (索引, 2, 文件大小)
超级列表框1.置标题 (索引, 3, 下载大小)
超级列表框1.置标题 (索引, 4, 速度)
超级列表框1.置标题 (索引, 5, 到文本 (四舍五入 (下载进度 × 100, 2)) ＋ “%”)
a ＝ a ＋ 文件总大小 ÷ 1024
b ＝ b ＋ 已下载大小 ÷ 1024

.如果真 (下载状态 ＝ 3)
    删除下载地址 (下载标识)
    超级列表框1.删除表项 (索引)
.如果真结束


.子程序 _超级列表框1_右键单击表项

.如果真 (超级列表框1.现行选中项 ≠ -1)
    弹出菜单 (菜单, , )
.如果真结束

.如果真 (超级列表框1.现行选中项 ＝ -1)
    弹出菜单 (新建, , )
.如果真结束


.子程序 _删除任务_被选择
.局部变量 标识, 整数型

标识 ＝ 超级列表框1.取表项数值 (超级列表框1.现行选中项)
HTTP下载_停止 (标识, , 500)
处理事件 ()
超级列表框1.删除表项 (超级列表框1.现行选中项)
删除下载地址 (标识, 真)
信息框 (“成功取消1个下载任务”, 0 ＋ #信息图标, “取消下载”, )

.子程序 _新建任务_被选择

载入 (窗口1, , 真)

.子程序 _复制下载地址_被选择

置剪辑板文本 (超级列表框1.取标题 (超级列表框1.现行选中项, 1))

.子程序 局_取文本中间, 文本型
.参数 原文本, 文本型
.参数 前面的文本, 文本型
.参数 后面的文本, 文本型
.局部变量 局_前位置, 整数型
.局部变量 局_后位置, 整数型

局_前位置 ＝ 倒找文本 (原文本, “\”, , 假)
局_后位置 ＝ 寻找文本 (原文本, “.”, , 假)
返回 (取文本中间 (原文本, 局_前位置 ＋ 1, 局_后位置 － 局_前位置 － 1))

.子程序 皮肤
.局部变量 图片, 文本型

图片 ＝ 背景图片 ()
皮肤.置皮肤 (, #底图, , 5353041, #背景图_缩放)
.如果 (图片 ＝ “”)
    皮肤.置皮肤 (, #底图, , 5353041, #背景图_缩放)
.否则
    皮肤.置皮肤 (图片, , , 5353041, #背景图_缩放)
.如果结束



皮肤.置控件皮肤 (真, 0)
皮肤.加入窗口 (_启动窗口.取窗口句柄 (), 110, 真, 假, 假, 假, 真, 假, 25, )

皮肤.置状态栏字体 (取窗口句柄 (), 真, 真)
皮肤.置窗口标题字体 (取窗口句柄 (), , , #蓝色)

子皮肤.置渐变风格 (#渐变风格_横向混合, #白色, 50, #黑色, 80)

.子程序 删除下载地址
.参数 标记, 整数型
.参数 是否删除文件, 逻辑型, 可空, 默认为 假 不删除文件
.局部变量 局_计次, 整数型

.计次循环首 (取数组成员数 (下载), 局_计次)

    .如果真 (下载 [局_计次].下载标识 ＝ 标记)
        .如果真 (是否为空 (是否删除文件) ＝ 假)
            .如果真 (是否删除文件 ＝ 真)
                .如果真 (删除文件 (下载 [局_计次].下载名称) ＝ 假)
                    信息框 (“删除文件失败”, 0, , )

                .如果真结束

            .如果真结束

        .如果真结束
        删除成员 (下载, 局_计次, )
        跳出循环 ()
    .如果真结束

.计次循环尾 ()




.子程序 _重新下载_被选择
.局部变量 标识, 整数型
.局部变量 局_计次, 整数型
.局部变量 局_下载地址, 下载标识数据
.局部变量 索引, 整数型
.局部变量 名称, 文本型

标识 ＝ 超级列表框1.取表项数值 (超级列表框1.现行选中项)

.计次循环首 (取数组成员数 (下载), 局_计次)

    .如果真 (下载 [局_计次].下载标识 ＝ 标识)
        HTTP下载_停止 (标识, , 500)
        处理事件 ()
        超级列表框1.删除表项 (超级列表框1.现行选中项)
        局_下载标识 ＝ 局_下载标识 ＋ 1
        局_下载地址.下载名称 ＝ 下载 [局_计次].下载名称
        局_下载地址.下载地址 ＝ 下载 [局_计次].下载地址
        局_下载地址.下载标识 ＝ 局_下载标识
        加入成员 (下载, 局_下载地址)
        删除下载地址 (标识, 真)
        HTTP下载_开始 (局_下载地址.下载地址, 局_下载地址.下载名称, 到整数 (&下载回调), 局_下载标识)
        索引 ＝ _启动窗口.超级列表框1.插入表项 (, , , , , 局_下载标识)
        名称 ＝ 取文本右边 (局_下载地址.下载名称, 取文本长度 (局_下载地址.下载名称) － 倒找文本 (局_下载地址.下载名称, “\”, , 假))
        超级列表框1.置标题 (索引, 0, 名称)
        超级列表框1.置标题 (索引, 1, 局_下载地址.下载地址)


    .如果真结束

.计次循环尾 ()


.子程序 背景图片, 文本型, 公开
.局部变量 文件名, 文本型
.局部变量 文件句柄, 整数型
.局部变量 文本, 文本型
.局部变量 ts路径, 文本型

ts路径 ＝ 取运行目录 () ＋ “\背景图片\”
.如果真 (取文本右边 (ts路径, 1) ≠ “\”)
    ts路径 ＝ ts路径 ＋ “\”
.如果真结束
文件名 ＝ 寻找文件 (ts路径 ＋ “*.jpg”, 1 ＋ 2 ＋ 4 ＋ 16 ＋ 32)
.判断循环首 (文件名 ≠ “”)
    .如果真 (文件名 ＝ “.” 或 文件名 ＝ “..”)
        文件名 ＝ 寻找文件 (, 1 ＋ 2 ＋ 4 ＋ 16 ＋ 32)
        到循环尾 ()
    .如果真结束
    ' 遍历子录下的文件'
    文本 ＝ ts路径 ＋ 文件名
    文件名 ＝ 寻找文件 (, 1 ＋ 2 ＋ 4 ＋ 16 ＋ 32)
    .如果真 (文本 ≠ “”)
        跳出循环 ()
    .如果真结束

.判断循环尾 ()

返回 (文本)