文本逐字分割源码及优化历程

shituo · 发表于 2022-10-28 17:11:03

本帖最后由 shituo 于 2022-10-28 17:34 编辑

.版本 2

.子程序文本_逐字分割, 整数型, 公开, 将指定文本逐字分割出来,目前只支持半角格式,支持汉字和换行符。返回字符总数（一个汉字只算一个长度），by:shituo
.参数参_原始文本, 文本型, , 需要取出来的汉字
.参数参_返回数组, 文本型, 参考数组, 保存取出结果的数组变量。不提供变量时，仅返回字符总数量，不分割文本以节省时间
.局部变量字符索引, 整数型
.局部变量临时文本, 文本型
.局部变量内部字节, 字节集
.局部变量字节长度, 整数型
.局部变量数组索引, 整数型

' ---------- 优化思路：从文本中获取字符代码的方式感觉效率不高，不如转成字节集直接处理来得快 ----------
字符索引＝ 1  ' 从首字符开始
内部字节＝到字节集 (参_原始文本)  ' 将文本转换为字节集，以加快速度
字节长度＝取字节集长度 (内部字节)
' 字符数量＝取文本实际长度_asm (参_原始文本)
重定义数组 (参_返回数组, 假, 字节长度)  ' 先一次性定义好数组，比一个一个加入成员要快。（因为每加入一次成员都涉及到内存申请与释放）

.判断循环首 (字符索引 ≤ 字节长度)
.判断开始 (内部字节 [字符索引] ＝ 13)  ' 处理回车符
      .如果真 (内部字节 [字符索引＋ 1] ＝ 10)  ' 下一个字符是换行符字符(10)
         临时文本＝ #换行符
         字符索引＝字符索引＋ 1
      .如果真结束

.判断 (内部字节 [字符索引] ＞ 127)  ' 处理双字节字符，比如汉字
      临时文本＝字符 (内部字节 [字符索引]) ＋字符 (内部字节 [字符索引＋ 1])  ' 将双字节字符组合成一个字
      字符索引＝字符索引＋ 1

.默认
      ' -------------------- 单字节字符
      临时文本＝字符 (内部字节 [字符索引])
.判断结束

数组索引＝数组索引＋ 1
参_返回数组 [数组索引] ＝临时文本
字符索引＝字符索引＋ 1
.判断循环尾 ()

.如果真 (字节长度 ≠ 数组索引)  ' 可能存在双字节字符，需要重新定义数组维数
' 重定义数组 (参_返回数组, 真, 数组索引)
删除成员 (参_返回数组, 数组索引＋ 1, 字节长度－数组索引)  ' 删除成员() 命令比重定义数组() 要快
.如果真结束

返回 (数组索引)