求助！！！多线程 操作 excel

丰乳肥臀

代码不知道怎么提交不了，也不是用ie模式啊！  也不懂在哪里设置下载附件免费
  ' ----------------想要实现，不用每次创建 和打开excel 就能够 用线程 读出单元格数据！，如果每次都创建 打开excel ，速度会很慢！
.版本 2
.支持库 EThread
.支持库 spec

.程序集 窗口程序集_启动窗口
.程序集变量 许可, 整数型
.程序集变量 句柄, 整数型
.程序集变量 e, EXCEL类

.子程序 __启动窗口_创建完毕

许可 ＝ 创建进入许可证 ()
启动线程 (&子程序1, , 句柄)

.子程序 子程序1
.局部变量 dm, 对象
.局部变量 时间, 整数型

进入许可区 (许可)
初始化COM库 (0)
调试输出 (e.创建 ())
e.打开EXCEL (取运行目录 () ＋ “\2018年2月份.xls”)
调试输出 (e.读单元格文本 (1, “a1”))
启动线程 (&子程序2, , )
销毁COM库 ()
退出许可区 (许可)


.子程序 子程序2

调试输出 (“程序可以运行到这里”)
进入许可区 (许可)
初始化COM库 (0)
' 调试输出 (e.创建 ())  ' ----------------想要实现，不用每次创建 和打开excel 就能够 用线程 读出单元格数据！，如果每次都创建 打开excel ，速度会很慢！
' e.打开EXCEL (取运行目录 () ＋ “\2018年2月份.xls”)  ' 如果屏蔽上面这两行代码，就读不出来。
调试输出 (e.读单元格文本 (1, “a1”))  ' 这个读不出来，难道每次都要 创建-打开  才能读出来吗，大神帮帮忙
销毁COM库 ()
退出许可区 (许可)


.子程序 __启动窗口_将被销毁

e.关闭 ()

.子程序 _按钮1_被单击

子程序2 ()

丰乳肥臀

csc123

回答你的问题,然后下载附件还需要扣1精币,你觉得这样正常吗?

水深与云起

还没解决么都2020年了

chenhui56

我没你的excel类，用的自带的excel com库
**********************************
.版本 2
.支持库 EThread
.支持库 spec

.程序集 窗口程序集_启动窗口
.程序集变量 许可, 整数型
.程序集变量 句柄, 整数型
.程序集变量 exl, 对象
.程序集变量 工作簿集, 对象
.程序集变量 工作簿, 对象
.程序集变量 工作表, 对象

.子程序 __启动窗口_创建完毕
许可 ＝ 创建进入许可证 ()
' 卸载单线程com库
CoUninitialize ()
' 初始化多线程com库
CoInitializeEx (0, 0)
启动线程 (&子程序1, , 句柄)

.子程序 子程序1
.局部变量 文件路径, 文本型
.局部变量 单元格内容, 文本型
.局部变量 i, 整数型
进入许可区 (许可)
调试输出 (exl.创建 (“excel.application”, ))
工作簿集 ＝ exl.读对象型属性 (“Workbooks”, )
文件路径 ＝ 取运行目录 () ＋ “\2018年2月份.xls”
调试输出 (“文件路径”, 文件路径)
工作簿 ＝ 工作簿集.对象型方法 (“Open”, 文件路径)
.如果 (工作簿.是否为空 ())
    调试输出 (“子程序1 excel打开失败！”)
.否则
    工作表 ＝ 工作簿.读对象型属性 (“ActiveSheet”, )
    i ＝ 1
    .循环判断首 ()
        单元格内容 ＝ 工作表.读对象型属性 (“Range”, “a” ＋ 到文本 (i)).读属性 (“Text”, ).取文本 ()
        调试输出 (“子程序1 单元格内容”, 单元格内容)
        i ＝ i ＋ 1
    .循环判断尾 (单元格内容 ≠ “”)
.如果结束
启动线程 (&子程序2, , )

.子程序 子程序2
.局部变量 局_工作簿集, 对象
.局部变量 局_工作簿, 对象
.局部变量 局_工作表, 对象
.局部变量 单元格内容, 文本型
.局部变量 文件路径, 文本型
.局部变量 i, 整数型
调试输出 (“程序可以运行到这里”)
' 调试输出 (e.创建 ())  ' ----------------想要实现，不用每次创建 和打开excel 就能够 用线程 读出单元格数据！，如果每次都创建 打开excel ，速度会很慢！
' e.打开EXCEL (取运行目录 () ＋ “\2018年2月份.xls”)  ' 如果屏蔽上面这两行代码，就读不出来。
.如果真 (exl.是否为空 ())
    调试输出 (“exl对象未创建，需要重新创建”, exl.创建 (“excel.application”, ))
    工作簿集 ＝ exl.读对象型属性 (“Workbooks”, )
    文件路径 ＝ 取运行目录 () ＋ “\2018年2月份.xls”
    工作簿 ＝ 工作簿集.对象型方法 (“Open”, 文件路径)
    .如果 (工作簿.是否为空 ())
        调试输出 (“子程序2 excel打开失败！”)
    .否则
        工作表 ＝ 工作簿.读对象型属性 (“ActiveSheet”, )
    .如果结束
.如果真结束
局_工作簿集 ＝ 工作簿集
局_工作簿 ＝ 工作簿
局_工作表 ＝ 工作表
i ＝ 1
.循环判断首 ()
    单元格内容 ＝ 局_工作表.读对象型属性 (“Range”, “a” ＋ 到文本 (i)).读属性 (“Text”, ).取文本 ()
    调试输出 (“子程序2 单元格内容”, 单元格内容)
    i ＝ i ＋ 1
.循环判断尾 (单元格内容 ≠ “”)

' 调试输出 (e.读单元格文本 (1, “a1”))  ' 这个读不出来，难道每次都要 创建-打开  才能读出来吗，大神帮帮忙

.子程序 __启动窗口_将被销毁
调试输出 (“删除进入许可证”, 删除进入许可证 (许可))
.如果真 (工作簿.是否为空 () ＝ 假)
    工作簿.方法 (“Close”, )
.如果真结束
.如果真 (工作簿集.是否为空 () ＝ 假)
    工作簿集.方法 (“Close”, )
.如果真结束
.如果真 (exl.是否为空 () ＝ 假)
    exl.方法 (“Quit”, )
    exl.清除 ()

.如果真结束
退出许可区 (许可)
' 卸载多线程com库
CoUninitialize ()

.子程序 _按钮1_被单击
子程序2 ()