谷歌语音识别源码易语言教学YY：130790

yxw770

YY:130790易语言免费教学，每周一、三、五晚上8点上课
毅鹏教育论坛：www.eduyipeng.com频道给力讲师

[e=2][/e].版本 2
.支持库 eMMedia
.程序集 窗口程序集1
.程序集变量 Temp, 文本型
.子程序 __启动窗口_创建完毕
Temp ＝ 取临时文件名 ()  ' 创建临时文件
.子程序 _按钮1_被单击
.局部变量 采样率
.局部变量 WinHttp, 对象
.局部变量 中转站, 变体型
.局部变量 Text, 文本型
采样率 ＝ 8000  ' 应该是值越高 越准确 但文件越大
.判断开始 (按钮1.标题 ＝ “开始录制”)
    录音1.置格式 (1, 采样率, 16)
    录音1.录制 ()
    标签1.标题 ＝ “ 请长官讲话”
    按钮1.标题 ＝ “开始识别”
.判断 (按钮1.标题 ＝ “开始识别”)
    录音1.停止 ()
    录音1.保存文件 (Temp, 真)
    标签1.标题 ＝ “ 正在识别中 请稍后...”
    WinHttp.创建 (“WinHttp.WinHttpRequest.5.1”, )  ' 创建对象
    WinHttp.方法 (“Open”, “POST”, “http://www.google.com/speech-api/v1/recognize?xjerr=1&client=chromium&lang=zh-CN”, 假)  ' 打开
    WinHttp.方法 (“SetRequestHeader”, “Content-Type”, “audio/L16; rate=” ＋ 到文本 (采样率))  ' 设置协议头
    中转站.赋值 (读入文件 (Temp), )
    WinHttp.方法 (“Send”, 中转站)  ' 发送识别数据
    Text ＝ WinHttp.读文本属性 (“ResponseText”, )
    Text ＝ 取指定内容 (Text, “[”, “]”)
    .如果 (Text ≠ “”)  ' confidence 是准确率 utterance识别结果
        Text ＝ 取指定内容 (Text, “utterance” ＋ #引号 ＋ “:” ＋ #引号, #引号 ＋ “,” ＋ #引号 ＋ “confidence”)
        标签1.标题 ＝ “ ” ＋ Text
    .否则
        标签1.标题 ＝ “ 报告长官识别失败”
    .如果结束
    WinHttp.清除 ()
    按钮1.标题 ＝ “开始录制”
.默认
.判断结束

.子程序 __启动窗口_将被销毁
删除文件 (Temp)  ' 清理战场
.子程序 取指定内容, 文本型, 公开, 取出想要的内容
.参数 完整内容, 文本型, , 完整内容
.参数 左边文本, 文本型, 可空, 左边文本
.参数 右边文本, 文本型, 可空, 右边文本
.局部变量 临时位置, 整数型
.局部变量 总长度, 整数型
.局部变量 临时文本, 文本型
总长度 ＝ 取文本长度 (完整内容)
.判断开始 (右边文本 ＝ “”)
    .如果 (寻找文本 (完整内容, 左边文本, , 假) ＞ -1)
        临时位置 ＝ 寻找文本 (完整内容, 左边文本, , 假) ＋ 取文本长度 (左边文本)
        临时文本 ＝ 取文本中间 (完整内容, 临时位置, 总长度)
        返回 (临时文本)
    .否则
        返回 (“”)
    .如果结束
.判断 (左边文本 ＝ “”)
    .如果 (寻找文本 (完整内容, 右边文本, , 假) ＞ -1)
        临时位置 ＝ 寻找文本 (完整内容, 右边文本, , 假) － 1  ' － 取文本长度 (右边文本)
        临时文本 ＝ 取文本左边 (完整内容, 临时位置)
        返回 (临时文本)
    .否则
        返回 (“”)
    .如果结束
.判断 (左边文本 ＝ “” 且 右边文本 ＝ “ ”)
    返回 (“”)
.默认
    .如果 (寻找文本 (完整内容, 左边文本, , 假) ＞ -1)
        临时位置 ＝ 寻找文本 (完整内容, 左边文本, , 假) ＋ 取文本长度 (左边文本)
        临时文本 ＝ 取文本中间 (完整内容, 临时位置, 总长度)
        总长度 ＝ 取文本长度 (临时文本)
        临时位置 ＝ 寻找文本 (临时文本, 右边文本, , 假) － 1
        临时文本 ＝ 取文本中间 (临时文本, 1, 临时位置)
        返回 (临时文本)
    .否则
        返回 (“”)
    .如果结束
.判断结束

徒弟

不错

魔方软件

不错。支持下。