目录_枚举子目录 的改进建议。建议增加一个参数，能枚举其中的子目录数。默认不枚举

wjt741106

改进的源码：

.版本 2
.子程序 目录_枚举子目录, 整数型, 公开, 取一个文件夹下级子目录；成功返回子目录数量，失败返回0；通过是否枚举子目录参数，可以枚举所有的子目录
.参数 父文件夹路径, 文本型, , 如：D:\Program Files；目录分割符请用\，路径不以\结尾会自动添加
.参数 子目录数组, 文本型, 参考 可空 数组, 用来装载返回的子目录路径；
.参数 是否带路径, 逻辑型, 可空, 假=不带，真=带;
.参数 是否枚举子目录, 逻辑型, 可空, 为空，默认不枚举。
.局部变量 子目录名, 文本型
.局部变量 本级子目录列表, 文本型, , "0"
.局部变量 目录计数器, 整数型
.局部变量 目录总数, 整数型
.如果真 (取文本右边 (父文件夹路径, 1) ≠ “\”)
    父文件夹路径 ＝ 父文件夹路径 ＋ “\”
.如果真结束
子目录名 ＝ 寻找文件 (父文件夹路径 ＋ “*.*”, #子目录)
.判断循环首 (子目录名 ≠ “”)
    .如果真 (取文本左边 (子目录名, 1) ≠ “.”)
        加入成员 (本级子目录列表, 子目录名)
        .如果 (是否带路径 ＝ 假)
            加入成员 (子目录数组, 子目录名)
        .否则
            加入成员 (子目录数组, 父文件夹路径 ＋ 子目录名)
        .如果结束
    .如果真结束
    处理事件 ()
    子目录名 ＝ 寻找文件 (, #子目录)
.判断循环尾 ()
目录总数 ＝ 取数组成员数 (本级子目录列表)
.如果真 (是否枚举子目录 ＝ 真)
    .计次循环首 (取数组成员数 (本级子目录列表), 目录计数器)
        .如果真 (目录_是否有子目录 (父文件夹路径 ＋ 本级子目录列表 [目录计数器]) ＝ 真)
            目录总数 ＝ 目录总数 ＋ 目录_枚举子目录 (父文件夹路径 ＋ 本级子目录列表 [目录计数器], 子目录数组, 是否带路径, 是否枚举子目录)
        .如果真结束
    .计次循环尾 ()
.如果真结束
返回 (目录总数)

wjt741106

当要枚举子目录，包括下级子目录时，会自动把是否带路径 这个值置为真，即当要枚举多级子目录，自动带路径。

这是新修改后的代码

.版本 2

.子程序 目录_枚举子目录, 整数型, 公开, 取一个文件夹下级子目录；成功返回子目录数量，失败返回0；通过是否枚举子目录参数，可以枚举所有的子目录
.参数 父文件夹路径, 文本型, , 如：D:\Program Files；目录分割符请用\，路径不以\结尾会自动添加
.参数 子目录数组, 文本型, 参考 可空 数组, 用来装载返回的子目录路径；
.参数 是否带路径, 逻辑型, 可空, 假=不带，真=带;
.参数 是否枚举子目录, 逻辑型, 可空, 为空，默认不枚举。当要 是否枚举子目录=真， 是否带路径会 自动置为真，带绝对路径
.局部变量 子目录名, 文本型
.局部变量 本级子目录列表, 文本型, , "0"
.局部变量 目录计数器, 整数型
.局部变量 目录总数, 整数型

.如果真 (取文本右边 (父文件夹路径, 1) ≠ “\”)
    父文件夹路径 ＝ 父文件夹路径 ＋ “\”
.如果真结束
.如果真 (是否枚举子目录 ＝ 真)
    是否带路径 ＝ 真
.如果真结束
子目录名 ＝ 寻找文件 (父文件夹路径 ＋ “*.*”, #子目录)
.判断循环首 (子目录名 ≠ “”)
    .如果真 (取文本左边 (子目录名, 1) ≠ “.”)
        加入成员 (本级子目录列表, 子目录名)
        .如果 (是否带路径 ＝ 假)
            加入成员 (子目录数组, 子目录名)
        .否则
            加入成员 (子目录数组, 父文件夹路径 ＋ 子目录名)
        .如果结束

    .如果真结束
    处理事件 ()
    子目录名 ＝ 寻找文件 (, #子目录)
.判断循环尾 ()
目录总数 ＝ 取数组成员数 (本级子目录列表)
.如果真 (是否枚举子目录 ＝ 真)
    .计次循环首 (取数组成员数 (本级子目录列表), 目录计数器)
        .如果真 (目录_是否有子目录 (父文件夹路径 ＋ 本级子目录列表 [目录计数器]) ＝ 真)
            目录总数 ＝ 目录总数 ＋ 目录_枚举子目录 (父文件夹路径 ＋ 本级子目录列表 [目录计数器], 子目录数组, 是否带路径, 是否枚举子目录)
        .如果真结束

    .计次循环尾 ()
.如果真结束
返回 (目录总数)

wjt741106

加一个参数，增加一个功能，不然实现这个功能还得再写代码