易语言怎么清除某个网站cookie?

从未被超越

[e]
.版本 2

.子程序 网页_清除Cookie, , 公开
.参数 域名, 文本型, , 只接受域名
.局部变量 Cookie值1, 文本型
.局部变量 Cookie值2, 文本型
.局部变量 Cookie, 文本型, , "0"
.局部变量 计次, 整数型
.局部变量 最终Cookie, 文本型
.局部变量 Cookie名, 文本型

Cookie值1 ＝ “deleted; expires=Fri, 1-Jan-1999 1:1:1 GMT; path=/;”
Cookie值2 ＝ Cookie值1 ＋ “ domain=” ＋ 网页_取域名 (域名, 真)
最终Cookie ＝ 网页_取Cookie (域名)
Cookie ＝ 分割文本 (最终Cookie, “;”, )
.计次循环首 (取数组成员数 (Cookie), 计次)
    Cookie名 ＝ 内部_Cookie取名 (Cookie [计次])
    InternetSetCookieA (“http://” ＋ 域名, Cookie名, Cookie值1)
    InternetSetCookieA (“http://” ＋ 域名, Cookie名, Cookie值2)
.计次循环尾 ()

.子程序 网页_清除Cookie文件, 逻辑型, 公开, 【此命令由小磊提供】
.参数 关键字, 文本型, 可空, 输入Cookie文件的关键字即可,空则清除全部
.参数 Cookie路径, 文本型, 参考 可空, 传递Cookie路径
.局部变量 文件名, 文本型
.局部变量 已删除, 逻辑型

Cookie路径 ＝ 取文本注册项 (3, “Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\Cookies”, )
文件名 ＝ 寻找文件 (Cookie路径 ＋ “\*.txt”, )
.判断循环首 (文件名 ≠ “”)
    .如果真 (寻找文本 (文件名, 关键字, 1, 假) ≠ -1 或 关键字 ＝ “”)
        .如果真 (删除文件 (Cookie路径 ＋ “\” ＋ 文件名))
            已删除 ＝ 真
        .如果真结束

    .如果真结束
    文件名 ＝ 寻找文件 (, )
.判断循环尾 ()
返回 (已删除)
[/e]

dagangcool

已经得到解答了

笑红尘゛

精易模块源码已经附上 精易模块.rar (414.44 KB, 下载次数: 1)

2014-1-16 13:44 上传

点击文件名下载附件

紫禁城『凌哥』

精易模块命令：网页_清除cookie("baidu.com")