网页访问，怎么控制超时的呀

御风软件

新的网页访问，没有超时的功能，得让我们多纠结啊

网页访问，没有超时的参数，好吧，那教下我，用别的办法怎么判断是否超时啊

现在网页访问，一直在访问中啊，，，要等好久啊，难道是内置的超时？那超时多久啊？

希望能让用户设置下啊，不然，网络卡的时候，就卡死在网页访问这里啊。，。。悲剧的人啊。。。。

小磊

暂不支持超时

御风软件

Cand 发表于 2013-11-24 21:39
[e]
.版本 2

额，你这是那找的代码，3.12的么，还是超级网页访问的，，我是希望新的精易模块加上啊，，让小磊改

Cand

[e]
.版本 2

.子程序 网页访问, 字节集, 公开, 出错或超时将返回空，本命令将设置Cookies到本地
.参数 网址, 文本型, , 完整的网页地址
.参数 访问方式, 文本型, 可空, "GET" or "POST",为空默认"GET"
.参数 提交信息, 文本型, 可空, "POST"专用
.参数 提交Cookies, 文本型, 参考 可空, 提交的Cookie 注：本参数传递变量时会自动回传返回的Cookie
.参数 返回Cookies, 文本型, 参考 可空, 返回的Cookie
.参数 附加协议头, 文本型, 可空, 一行一个请用换行符隔开
.参数 返回协议头, 文本型, 参考 可空, Location
.参数 超时, 整数型, 可空, 秒|默认为15秒,-1为无限等待
.参数 完整协议头, 文本型, 参考 可空, 返回完整的协议头
.参数 字节集提交, 字节集, 可空, 提交字节集数据
.局部变量 局部_WinHttp, 对象
.局部变量 局部_返回Cookies, 文本型, , "0"
.局部变量 局部_计次, 整数型
.局部变量 局部_网页数据, 字节集
.局部变量 局部_发送协议头, 文本型, , "0"
.局部变量 局部_协议头处理, 文本型, , "0"
.局部变量 局部_变体提交, 变体型

CoInitialize (0)
.如果真 (局部_WinHttp.创建 (“WinHttp.WinHttpRequest.5.1”, ) ＝ 假)
    .如果真 (局部_WinHttp.创建 (“MSXML2.ServerXMLHTTP.6.0”, ) ＝ 假)
        返回 ({  })
    .如果真结束

.如果真结束
' 局部_WinHttp.查看 ()
访问方式 ＝ 到大写 (访问方式)
.如果真 (访问方式 ＝ “”)
    访问方式 ＝ “GET”
.如果真结束

.如果真 (超时 ≠ -1)
    .如果 (超时 ＜ 1)
        超时 ＝ 15000
    .否则
        超时 ＝ 超时 × 1000
    .如果结束
    局部_WinHttp.方法 (“SetTimeouts”, 超时, 超时, 超时, 超时)
.如果真结束

.如果真 (集_代理地址 ≠ “”)
    局部_WinHttp.方法 (“SetProxy”, 2, 集_代理地址)
    .如果真 (集_用户名 ≠ “”)
        局部_WinHttp.方法 (“SetProxyCredentials”, 集_用户名, 集_密码, 集_代理标识)
    .如果真结束

.如果真结束
局部_WinHttp.方法 (“Open”, 访问方式, 网址, 假)
局部_WinHttp.写属性 (“Option”, 6, 0)
.如果真 (附加协议头 ＝ “”)
    附加协议头 ＝ “Referer: ” ＋ 网址 ＋ #换行符 ＋ #协议头_网页
.如果真结束
提交Cookies ＝ COOKIE合并更新 (取COOKIE (取域名 (网址, 真)), 提交Cookies)
.如果真 (提交Cookies ≠ “”)
    局部_WinHttp.方法 (“SetRequestHeader”, “Cookie”, 提交Cookies)
.如果真结束

.判断开始 (寻找文本 (附加协议头, #换行符, , 假) ＞ -1)
    局部_发送协议头 ＝ 分割文本 (附加协议头, #换行符, )
    .计次循环首 (取数组成员数 (局部_发送协议头), 局部_计次)
        .如果真 (寻找文本 (局部_发送协议头 [局部_计次], “:”, , 假) ＞ -1)
            清除数组 (局部_协议头处理)
            局部_协议头处理 ＝ 分割文本 (局部_发送协议头 [局部_计次], “:”, )
            局部_计次 ＝ 2
            .判断循环首 (真)
                局部_计次 ＝ 局部_计次 ＋ 1
                .如果真 (局部_计次 ＞ 取数组成员数 (局部_协议头处理))
                    跳出循环 ()
                .如果真结束
                局部_协议头处理 [2] ＝ 局部_协议头处理 [2] ＋ “:” ＋ 局部_协议头处理 [局部_计次]
            .判断循环尾 ()
            局部_WinHttp.方法 (“SetRequestHeader”, 局部_协议头处理 [1], 局部_协议头处理 [2])
        .如果真结束

    .计次循环尾 ()
.默认
    .如果真 (寻找文本 (附加协议头, “:”, , 假) ＞ -1)
        局部_协议头处理 ＝ 分割文本 (附加协议头, “:”, )
        局部_计次 ＝ 2
        .判断循环首 (真)
            局部_计次 ＝ 局部_计次 ＋ 1
            .如果真 (局部_计次 ＞ 取数组成员数 (局部_协议头处理))
                跳出循环 ()
            .如果真结束
            局部_协议头处理 [2] ＝ 局部_协议头处理 [2] ＋ “:” ＋ 局部_协议头处理 [局部_计次]
        .判断循环尾 ()
        局部_WinHttp.方法 (“SetRequestHeader”, 局部_协议头处理 [1], 局部_协议头处理 [2])
    .如果真结束

.判断结束

.判断开始 (字节集提交 ＝ {  })
    局部_WinHttp.方法 (“Send”, 提交信息)
.默认
    局部_变体提交.赋值 (字节集提交, )
    局部_WinHttp.方法 (“Send”, 局部_变体提交)
.判断结束
局部_网页数据 ＝ 局部_WinHttp.读属性 (“ResponseBody”, ).取字节集 ()
完整协议头 ＝ 局部_WinHttp.读文本属性 (“GetallResponseHeaders”, )
局部_返回Cookies ＝ 分割文本 (完整协议头, #换行符, )
返回Cookies ＝ “”
.计次循环首 (取数组成员数 (局部_返回Cookies), 局部_计次)
    .如果真 (寻找文本 (局部_返回Cookies [局部_计次], “Location:”, , 假) ＞ -1)
        返回协议头 ＝ 删首尾空 (子文本替换 (局部_返回Cookies [局部_计次], “Location:”, , , 1, 假))
    .如果真结束

    .如果真 (寻找文本 (局部_返回Cookies [局部_计次], “Set-Cookie”, , 假) ＞ -1)
        返回Cookies ＝ 返回Cookies ＋ 删首尾空 (文本_取出中间文本 (局部_返回Cookies [局部_计次], “Set-Cookie:”, “;”)) ＋ “; ”
    .如果真结束

.计次循环尾 ()
COOKIE合并更新 (提交Cookies, 返回Cookies)
设COOKIE (取域名 (网址, 真), 提交Cookies)
.如果真 (返回协议头 ＝ “”)
    返回协议头 ＝ 完整协议头
.如果真结束
CoUninitialize ()
返回 (局部_网页数据)
[/e]
虽然不懂。但是我觉得那个超时的方法应该是这样的

Violation

确实是卡死在网页访问里啊

平心静气

启动线程  然后等待线程，在等待线程里设置超时

Hoibben

貌似那个对象访问的有超时，其他的自己加呗，呵呵。。。。

残血小羽

御风软件 发表于 2013-11-24 18:26
其实，小磊更新后的都不能超时设置，3.12及之前的那个版本，才有超时设置的。。

吓我一跳。还以为Microsoft出新协议了、、、超时自己加一个不就得了

御风软件

残血小羽 发表于 2013-11-24 18:23
新网页访问？？？什么玩意儿？？出新协议了？

其实，小磊更新后的都不能超时设置，3.12及之前的那个版本，才有超时设置的。。

残血小羽

新网页访问？？？什么玩意儿？？出新协议了？