系统_匿名管道运行DOS[啸锐升级版]

乖乖你快回来

看看源码怎么写的

aijianli

源码调试不成功  有没有示例让看看呗

鲁凯啸

ssdlh 发表于 2013-8-5 09:13
紧急需要！！！！！！！！！！！

附件在8楼已补充

鲁凯啸

whdwit 发表于 2014-1-12 16:38
楼主啊，你的附件没办法下载了呢，真的很想看看你的作品。。。

DosEc.rar (4 KB, 下载次数: 174)

2013-4-20 15:40 上传

点击文件名下载附件     重新上传源码附件




源码：-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=--=


程序集部分
[e]
.版本 2
.支持库 eAPI
.支持库 spec

.程序集 匿名DOS, , , 精易论坛 鲁凯啸 （啸锐）  
.程序集变量 安全属性a, 安全属性
.程序集变量 a输出管道, 整数型
.程序集变量 a输入管道, 整数型
.程序集变量 安全属性b, 安全属性
.程序集变量 b输出管道, 整数型
.程序集变量 b输入管道, 整数型
.程序集变量 启动信息, 启动信息
.程序集变量 进程信息, 进程信息_

.子程序 _启动子程序, 整数型, , 请在本子程序中放置易模块初始化代码


_临时子程序 ()  ' 在初始化代码执行完毕后调用测试代码
返回 (0)  ' 可以根据您的需要返回任意数值

.子程序 _临时子程序

' 本名称子程序用作测试程序用，仅在开发及调试环境中有效，编译发布程序前将被系统自动清空，请将所有用作测试的临时代码放在本子程序中。 ***注意不要修改本子程序的名称、参数及返回值类型。
系统_匿名管道运行DOS (“ping baidu.com” ＋ “&&echo Ec.End”, , 到整数 (&回调子程序))






' 这是网络上收集的一段代码，然后我修改了一下
' 使得可移植性更好了，大家看看这个需要加入模块么？

' 调用代码： 如果代码显示不正常，请切换至IE内核的浏览器，或者切换一下浏览模式。

' 系统_匿名管道运行DOS ("欲运行的DOS命令[文本型]", "该命令所在目录[文本型]", "回调子程序指针[整数型]")


' 调用代码示例：
' 01..系统_匿名管道运行DOS (“ping baidu.com” ＋ “&&echo Ec.End”, , 到整数 (&回调子程序))

' 02..       ┠ 欲运行的DOS命令：  “ping baidu.com” ＋ “&&echo Ec.End”

' 03..       ┃      ┠ 被加数或文本或字节集：“ping baidu.com”      '有实际作用的DOS命令

' 04..       ┃      ┗ 加数或文本或字节集：   “&&echo Ec.End”      '无实际作用的DOS命令，判断DOS是否运行完毕

' 05..       ┠ 该命令所在目录：      [可空]         欲运行的命令所在的目录。注意以斜杠结尾。

' 06..       ┗ 回调事件：    整数型  [可空]         到整数(&回调子程序)   该子程序有一个文本型参数不可为空
' 复制代码上源码：
' DosEc.rar (3.33 KB, 下载次数: 0)
' 19 分钟前 上传点击文件名下载附件

' 模块描述：系统_匿名管道运行DOS
' -----------☆此模块共调用了3个支持库☆-----------
' 系统核心支持库[krnln] (5.0)版 标识符：d09f2340818511d396f6aaf844c7e325
' 应用接口支持库[eAPI] (3.1)版 标识符：F7FC1AE45C5C4758AF03EF19F18A395D
' 特殊功能支持库[spec] (3.1)版 标识符：A512548E76954B6E92C21055517615B0




' 本文章来自：精易论坛(http://bbs.125.la/thread-13645557-1-1.html）请保留此链接, 感谢!


.子程序 系统_匿名管道运行DOS, , 公开, 以匿名管道方式运行DOS系列命令。
.参数 欲运行的DOS命令, 文本型, , 命令连同后面的参数。如“dir c:”
.参数 该命令所在目录, 文本型, 可空, 欲运行的命令所在的目录。为空默认为系统当前目录。注意以斜杠结尾。
.参数 回调事件, 整数型, 可空, 指定命令实时回显事件接收子程序。不指定则不回显。  如 到整数(&回调子程序) 有一个文本型的参数
.局部变量 管道a, 整数型
.局部变量 管道b, 整数型
.局部变量 创建进程, 整数型
.局部变量 系统信息1, 系统信息


取系统信息 (系统信息1)
安全属性a.长度 ＝ 12
安全属性a.权限 ＝ 0
安全属性a.句柄 ＝ -1
安全属性b.长度 ＝ 12
安全属性b.权限 ＝ 0
安全属性b.句柄 ＝ -1
改变目录 (系统信息1.系统目录)
.如果真 (该命令所在目录 ≠ “”)
    改变目录 (该命令所在目录)
.如果真结束

管道a ＝ 创建匿名管道 (a输出管道, a输入管道, 安全属性a, 0)
管道b ＝ 创建匿名管道 (b输出管道, b输入管道, 安全属性b, 0)
获取启动信息_ (启动信息)
启动信息.dwFlags ＝ 257  ' 大小类型
启动信息.hStdInput ＝ a输出管道  ' 重定向标准输入
启动信息.hStdOutput ＝ b输入管道  ' 重定向标准输出
启动信息.hStdError ＝ b输入管道  ' 重定向标准错误输出
启动信息.wShowWindow ＝ 0  ' 隐藏运行
创建进程 ＝ 创建进程 (0, “cmd.exe”, 0, 0, -1, 0, 0, 取当前目录 (), 启动信息, 进程信息)
系统_匿名管道运行DOS_写管道 (欲运行的DOS命令)
系统_匿名管道运行DOS_读管道 (回调事件)


' 启动线程 (&读管道, 回调事件, )

.子程序 系统_匿名管道运行DOS_读管道, , 公开
.参数 回调事件, 整数型
.局部变量 实际尺寸, 整数型
.局部变量 缓存, 字节集
.局部变量 临时文本, 文本型


缓存 ＝ 取空白字节集 (260)
.判断循环首 (读文件 (b输出管道, 缓存, 260, 实际尺寸, 0) ≠ 0 且 实际尺寸 ≠ 0)
    临时文本 ＝ 到文本 (取字节集左边 (缓存, 实际尺寸))
    调用子程序 (回调事件, , , 临时文本)
    .如果真 (寻找文本 (临时文本, “Ec.End”, , 假) ≠ -1 且 寻找文本 (临时文本, “&”, , 假) ＝ -1)
        系统_匿名管道运行DOS_写管道 (“exit”)
        跳出循环 ()
    .如果真结束

.判断循环尾 ()

.子程序 系统_匿名管道运行DOS_写管道, , 公开
.参数 命令名, 文本型
.局部变量 shell, 字节集
.局部变量 实际尺寸, 整数型

shell ＝ 到字节集 (命令名 ＋ #换行符)
写文件 (a输入管道, shell, 取字节集长度 (shell), 实际尺寸, 0)




[/e]





dll部分
[e]

.版本 2

.DLL命令 创建匿名管道, 整数型, , "CreatePipe"
    .参数 输出管道, 整数型, 传址
    .参数 输入管道, 整数型, 传址
    .参数 管道属性, 安全属性, 传址
    .参数 尺寸, 整数型

.DLL命令 获取启动信息_, 整数型, "kernel32", "GetStartupInfoA"
    .参数 启动信息, 启动信息, 传址

.DLL命令 创建进程, 整数型, , "CreateProcessA"
    .参数 程序名称, 整数型, , 32位程序用，可设为文本型
    .参数 命令行, 文本型
    .参数 进程属性, 整数型
    .参数 线程属性, 整数型
    .参数 参数一, 整数型
    .参数 参数二, 整数型
    .参数 参数三, 整数型
    .参数 运行目录, 文本型, , 如需指定运行目录设为文本行
    .参数 启动信息, 启动信息
    .参数 进程信息, 进程信息_

.DLL命令 读文件, 整数型, , "ReadFile"
    .参数 文件号, 整数型
    .参数 缓存, 字节集, 传址
    .参数 读取尺寸, 整数型
    .参数 实际尺寸, 整数型, 传址
    .参数 参数, 整数型

.DLL命令 写文件, 整数型, , "WriteFile"
    .参数 文件号, 整数型
    .参数 写入内容, 字节集, 传址
    .参数 写入尺寸, 整数型
    .参数 实际尺寸, 整数型, 传址
    .参数 参数, 整数型

.DLL命令 关闭句柄, 整数型, , "CloseHandle"
    .参数 句柄, 整数型

.DLL命令 结束进程, 逻辑型, , "TerminateProcess"
    .参数 指定进程, 整数型
    .参数 退出标记, 整数型

.DLL命令 打开进程句柄, 整数型, , "OpenProcess"
    .参数 访问方法, 整数型
    .参数 子程序继承, 逻辑型, , 是否由子程序继承
    .参数 进程标识符, 整数型


[/e]







数据类型部分
[e]

.版本 2

.数据类型 安全属性, , SECURITY_ATTRIBUTES
    .成员 长度, 整数型
    .成员 权限, 整数型
    .成员 句柄, 整数型

.数据类型 启动信息
    .成员 cb, 整数型
    .成员 lpReserved, 整数型
    .成员 lpDesktop, 整数型
    .成员 lpTitle, 整数型
    .成员 dwX, 整数型
    .成员 dwY, 整数型
    .成员 dwXSize, 整数型
    .成员 dwYSize, 整数型
    .成员 dwXCountChars, 整数型
    .成员 dwYCountChars, 整数型
    .成员 dwFillAttribute, 整数型
    .成员 dwFlags, 整数型
    .成员 wShowWindow, 短整数型
    .成员 cbReserved2, 短整数型
    .成员 lpReserved2, 整数型
    .成员 hStdInput, 整数型
    .成员 hStdOutput, 整数型
    .成员 hStdError, 整数型

.数据类型 进程信息_
    .成员 进程号, 整数型
    .成员 线程号, 整数型
    .成员 进程ID, 整数型
    .成员 线程ID, 整数型


[/e]

whdwit

楼主啊，你的附件没办法下载了呢，真的很想看看你的作品。。。

ssdlh

紧急需要！！！！！！！！！！！

momoca

log.rar (1.26 KB, 下载次数: 34)

2013-7-5 21:25 上传

点击文件名下载附件

鲁凯啸

larry011 发表于 2013-5-8 12:57
之前网上一个源码不好之处在于没有关闭打开的管道，结果进程里面N个CMD.EXE

这个里面有关闭方法，即上面代码第四行的：

加数或文本或字节集：   “&&echo Ec.End”      '无实际作用的DOS命令，判断DOS是否运行完毕

larry011

之前网上一个源码不好之处在于没有关闭打开的管道，结果进程里面N个CMD.EXE

小磊

核心库以外的命令不考虑过收录