请各位老师看看这段代码有什么奥妙？

秂苼茹戏

这是一个智能查询电话的源代码，程序只能查询7个字段，并且1，2必须是汉字，3可以是汉字或数字，4-7必须是数字，如果用结构器把查汉字的和查数字的字段互换位置，查询时就查不到已储存在这个字段上的内容，如下边我把手机和备注互换了位置，现在手机却有查汉字和数字的功能，而备注只能查数字了，如果再加一个编辑框，（加了个QQ框）虽然能储存但查询不到内容，如在这个编辑框里储存11111，在智能框里打1111就查不到。
    说了这么多，希望有能看得懂我意思的老师
.版本 2
.支持库 iext2

.程序集 主程序集
.程序集变量 记录数组, 整数型, , "2"
.程序集变量 标签表当前页, 整数型
.程序集变量 标签表当前行, 整数型
.程序集变量 鼠标位置, 整数型
.程序集变量 上次查询内容, 文本型

.子程序 __启动窗口_创建完毕
.局部变量 存档成功, 逻辑型
.局部变量 取消成功, 逻辑型


标签表当前行 ＝ 1
_查询按钮_被单击 ()

存档成功 ＝ 置文件属性 (取执行文件名 (), 32)
取消成功 ＝ 置文件属性 (取执行文件名 (), 0)
.如果真 (取反 (存档成功 且 取消成功))
    信息框 (“    本程序在只读环境中无法正常运行，请取消磁盘的写保护。如果程序在光盘中,请将程序复制到硬盘或优盘中使用。”, 0, “ 程序不能在只读环境中运行。”)
    结束 ()
.如果真结束

.如果真 (取反 (文件是否存在 (“DHB.EDB”)))
    建立数据库 ()
    _输入按钮_被单击 ()
    标签表帮助 (1)
.如果真结束
置文件属性 (“DHB.EDB”, 32)
打开 (“DHB.EDB”, , , , , , )
_启动窗口.图标 ＝ #图标1
_启动窗口.置托盘图标 (#图标1, “迷你114查号台”)



.子程序 _查询按钮_被单击


查询按钮.禁止 ＝ 真
输入按钮.禁止 ＝ 假
表格按钮.禁止 ＝ 假

确定按钮.禁止 ＝ 真
确定按钮.可视 ＝ 假
查询框.边框 ＝ 5

查询框.禁止 ＝ 假
姓名框.禁止 ＝ 真
手机框.禁止 ＝ 真
单位框.禁止 ＝ 真
办公框.禁止 ＝ 真
家里框.禁止 ＝ 真
小灵通框.禁止 ＝ 真
备注框.禁止 ＝ 真
QQ框.禁止 ＝ 真
上翻页按钮.禁止 ＝ 真
下翻页按钮.禁止 ＝ 真

说明标签6.标题 ＝ “智能查询输入”
查询框.内容 ＝ “”
上次查询内容 ＝ “”
查询框.获取焦点 ()

重定义数组 (记录数组, 假, 0)

清空输入框表 ()
标签表帮助 (0)


.子程序 _输入按钮_被单击


查询按钮.禁止 ＝ 假
输入按钮.禁止 ＝ 真
表格按钮.禁止 ＝ 假

查询框.边框 ＝ 0
查询框.文本颜色 ＝ #黑色
查询框.背景颜色 ＝ #白色
确定按钮.禁止 ＝ 假
确定按钮.可视 ＝ 真

查询框.禁止 ＝ 真
姓名框.禁止 ＝ 假
手机框.禁止 ＝ 假
单位框.禁止 ＝ 假
办公框.禁止 ＝ 假
家里框.禁止 ＝ 假
小灵通框.禁止 ＝ 假
备注框.禁止 ＝ 假
QQ框.禁止 ＝ 假
姓名框.获取焦点 ()

说明标签6.标题 ＝ “总记录数”
查询框.内容 ＝ 到文本 (取记录数 ())

重定义数组 (记录数组, 假, 0)

清空标签表 ()
清空输入框表 ()


.子程序 _表格按钮_被单击


查询按钮.禁止 ＝ 假
输入按钮.禁止 ＝ 假
表格按钮.禁止 ＝ 真

载入 (表格窗口, , 假)


.子程序 _确定按钮_被单击


加记录 (到全角 (姓名框.内容), 到全角 (单位框.内容), 手机框.内容, 办公框.内容, 家里框.内容, 备注框.内容, 小灵通框.内容, QQ框.内容)
查询框.内容 ＝ 到文本 (取记录数 ())

清空输入框表 ()

姓名框.获取焦点 ()
返回 ()


.子程序 _确定按钮_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型


.如果真 (键代码 ＝ #回车键)
    _确定按钮_被单击 ()
.如果真结束


.子程序 _确定按钮_获得焦点

_启动窗口.回车下移焦点 ＝ 假

.子程序 _上翻页按钮_被单击
.局部变量 实际页数, 整数型


实际页数 ＝ (取数组成员数 (记录数组) ＋ 4) ＼ 5 － 1
.如果真 (标签表当前页 ＞ 实际页数)
    标签表当前页 ＝ 实际页数
.如果真结束
.如果真 (标签表当前页 ＞ 0)
    标签表当前页 ＝ 标签表当前页 － 1
    更新标签表 ()
.如果真结束
翻页键状态 ()
更新输入框表 (标签表当前行)


.子程序 _下翻页按钮_被单击
.局部变量 实际页数, 整数型


实际页数 ＝ (取数组成员数 (记录数组) ＋ 4) ＼ 5 － 1
.如果真 (标签表当前页 ＜ 0)
    标签表当前页 ＝ 0
.如果真结束
.如果真 (标签表当前页 ＜ 实际页数)
    标签表当前页 ＝ 标签表当前页 ＋ 1
    更新标签表 ()
.如果真结束
翻页键状态 ()
更新输入框表 (标签表当前行)


.子程序 _关闭按钮_被单击

置托盘图标 (, )
关闭 ()
结束 ()

.子程序 __启动窗口_托盘事件
.参数 操作类型, 整数型


_启动窗口.总在最前 ＝ 真
_启动窗口.总在最前 ＝ 假
_启动窗口.可视 ＝ 真
_启动窗口.禁止 ＝ 假


.子程序 _标签表1_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型


.如果真 (鼠标位置 ≠ 1)
    鼠标位置 ＝ 1

    标签表1.背景颜色 ＝ #黄色
    标签表2.背景颜色 ＝ #银白
    标签表3.背景颜色 ＝ 16769473
    标签表4.背景颜色 ＝ #银白
    标签表5.背景颜色 ＝ 16769473

    更新输入框表 (1)
    标签表当前行 ＝ 1
.如果真结束


.子程序 _标签表2_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型


.如果真 (鼠标位置 ≠ 2)
    鼠标位置 ＝ 2

    标签表1.背景颜色 ＝ 16769473
    标签表2.背景颜色 ＝ #黄色
    标签表3.背景颜色 ＝ 16769473
    标签表4.背景颜色 ＝ #银白
    标签表5.背景颜色 ＝ 16769473

    更新输入框表 (2)
    标签表当前行 ＝ 2
.如果真结束


.子程序 _标签表3_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型


.如果真 (鼠标位置 ≠ 3)
    鼠标位置 ＝ 3

    标签表1.背景颜色 ＝ 16769473
    标签表2.背景颜色 ＝ #银白
    标签表3.背景颜色 ＝ #黄色
    标签表4.背景颜色 ＝ #银白
    标签表5.背景颜色 ＝ 16769473

    更新输入框表 (3)
    标签表当前行 ＝ 3
.如果真结束


.子程序 _标签表4_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型


.如果真 (鼠标位置 ≠ 4)
    鼠标位置 ＝ 4

    标签表1.背景颜色 ＝ 16769473
    标签表2.背景颜色 ＝ #银白
    标签表3.背景颜色 ＝ 16769473
    标签表4.背景颜色 ＝ #黄色
    标签表5.背景颜色 ＝ 16769473

    更新输入框表 (4)
    标签表当前行 ＝ 4
.如果真结束


.子程序 _标签表5_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型


.如果真 (鼠标位置 ≠ 5)
    鼠标位置 ＝ 5

    标签表1.背景颜色 ＝ 16769473
    标签表2.背景颜色 ＝ #银白
    标签表3.背景颜色 ＝ 16769473
    标签表4.背景颜色 ＝ #银白
    标签表5.背景颜色 ＝ #黄色

    更新输入框表 (5)
    标签表当前行 ＝ 5
.如果真结束


.子程序 __启动窗口_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型


.如果真 (鼠标位置 ≠ 0)
    鼠标位置 ＝ 0

    标签表1.背景颜色 ＝ 16769473
    标签表2.背景颜色 ＝ #银白
    标签表3.背景颜色 ＝ 16769473
    标签表4.背景颜色 ＝ #银白
    标签表5.背景颜色 ＝ 16769473
.如果真结束


.子程序 建立数据库
.局部变量 结构, 字段信息, , "8"


结构 [1].名称 ＝ “姓名”
结构 [1].类型 ＝ #文本型
结构 [1].最大文本长度 ＝ 10
结构 [2].名称 ＝ “单位”
结构 [2].类型 ＝ #文本型
结构 [2].最大文本长度 ＝ 24
结构 [3].名称 ＝ “手机”
结构 [3].类型 ＝ #文本型
结构 [3].最大文本长度 ＝ 11
结构 [4].名称 ＝ “办公”
结构 [4].类型 ＝ #文本型
结构 [4].最大文本长度 ＝ 13
结构 [5].名称 ＝ “家里”
结构 [5].类型 ＝ #文本型
结构 [5].最大文本长度 ＝ 13
结构 [6].名称 ＝ “备注”
结构 [6].类型 ＝ #文本型
结构 [6].最大文本长度 ＝ 32
结构 [7].名称 ＝ “小灵通”
结构 [7].类型 ＝ #文本型
结构 [7].最大文本长度 ＝ 13
结构 [8].名称 ＝ “QQ”
结构 [8].类型 ＝ #文本型
结构 [8].最大文本长度 ＝ 10

创建 (“DHB.EDB”, 结构)
返回 ()


.子程序 模糊查询, 整数型, , 返回查询到的记录数量
.参数 被查内容, 文本型, , 被查询的"首拼"或"数字"文本内容
.局部变量 临时变量, 整数型
.局部变量 内容长度, 整数型
.局部变量 循环变量, 整数型
.局部变量 几种可能, 整数型
.局部变量 检查内容, 文本型


几种可能 ＝ 1
内容长度 ＝ 取文本长度 (被查内容)
.如果真 (内容长度 ＞ 0)
    临时变量 ＝ 取代码 (被查内容, 1)
    .如果 (临时变量 ＜ 48 或 临时变量 ＞ 57)
        临时变量 ＝ 内容长度
        .如果真 (临时变量 ＞ 1)
            循环变量 ＝ 0
            .计次循环首 (临时变量 － 1, 循环变量)
                检查内容 ＝ 取文本中间 (被查内容, 循环变量, 2)
                .如果真 (检查内容 ＝ “ai”)
                    内容长度 ＝ 内容长度 － 1
                .如果真结束
                .如果真 (检查内容 ＝ “ei”)
                    内容长度 ＝ 内容长度 － 1
                .如果真结束
                .如果真 (检查内容 ＝ “ao”)
                    几种可能 ＝ 几种可能 ＋ 1
                    内容长度 ＝ 内容长度 － 1
                .如果真结束
                .如果真 (检查内容 ＝ “ou”)
                    内容长度 ＝ 内容长度 － 1
                .如果真结束
                .如果真 (检查内容 ＝ “an”)
                    几种可能 ＝ 几种可能 ＋ 1
                    内容长度 ＝ 内容长度 － 1
                .如果真结束
                .如果真 (检查内容 ＝ “en”)
                    几种可能 ＝ 几种可能 ＋ 1
                    内容长度 ＝ 内容长度 － 1
                .如果真结束
                .如果真 (检查内容 ＝ “er”)
                    几种可能 ＝ 几种可能 ＋ 1
                    内容长度 ＝ 内容长度 － 1
                .如果真结束

            .计次循环尾 ()
        .如果真结束
        .如果真 (临时变量 ＞ 2)
            循环变量 ＝ 0
            .计次循环首 (临时变量 － 2, 循环变量)
                检查内容 ＝ 取文本中间 (被查内容, 循环变量, 3)
                .如果真 (检查内容 ＝ “ang”)
                    几种可能 ＝ 几种可能 ＋ 1
                    内容长度 ＝ 内容长度 － 1
                .如果真结束

            .计次循环尾 ()
        .如果真结束
        返回 (汉字查询 (被查内容, 内容长度, 几种可能))
    .否则
        返回 (数字查询 (被查内容))
    .如果结束

.如果真结束
重定义数组 (记录数组, 假, 0)
返回 (0)


.子程序 汉字查询, 整数型, , 返回查询到的记录数量.被查询的字段为,姓名、单位、备注.
.参数 被查内容, 文本型, , 被查询的首拼文本内容
.参数 最小长度, 整数型, , 被查询的首拼所对应的查询字数
.参数 几种可能, 整数型, , 被查询的韵母字有几种可能
.局部变量 主循环数, 整数型
.局部变量 次循环数, 整数型
.局部变量 韵母计数, 整数型
.局部变量 子循环数, 整数型
.局部变量 真记录数, 整数型
.局部变量 记录总数, 整数型
.局部变量 临时文本, 文本型
.局部变量 文本长度, 整数型
.局部变量 查询结果, 逻辑型
.局部变量 总长度, 整数型


最小长度 ＝ 最小长度 × 2
.如果真 (最小长度 ＝ 0)
    重定义数组 (记录数组, 假, 0)
    返回 (0)
.如果真结束
记录总数 ＝ 取记录数 ()
重定义数组 (记录数组, 假, 记录总数)
到首记录 ()
真记录数 ＝ 0
主循环数 ＝ 0
.计次循环首 (记录总数, 主循环数)
    跳到 (主循环数)
    查询结果 ＝ 假
    次循环数 ＝ 0
    .计次循环首 (3, 次循环数)
        临时文本 ＝ “”
        临时文本 ＝ 读 (次循环数)
        文本长度 ＝ 取文本长度 (临时文本)
        韵母计数 ＝ 0
        .计次循环首 (几种可能, 韵母计数)
            总长度 ＝ 最小长度 ＋ (韵母计数 － 1) × 2
            .如果真 (文本长度 ≥ 总长度)
                子循环数 ＝ 0
                .计次循环首 ((文本长度 － 总长度 ＋ 2) ÷ 2, 子循环数)
                    查询结果 ＝ 输入字比较 (被查内容, 取文本中间 (临时文本, 子循环数 × 2 － 1, 总长度), 假, 1)
                    .如果真 (查询结果 ＝ 真)
                        跳出循环 ()
                    .如果真结束

                .计次循环尾 ()
            .如果真结束
            .如果真 (查询结果 ＝ 真)
                跳出循环 ()
            .如果真结束

        .计次循环尾 ()
        .如果真 (查询结果 ＝ 真)
            真记录数 ＝ 真记录数 ＋ 1
            记录数组 [真记录数] ＝ 主循环数
            跳出循环 ()
        .如果真结束

    .计次循环尾 ()
.计次循环尾 ()
重定义数组 (记录数组, 真, 真记录数)
返回 (真记录数)


.子程序 数字查询, 整数型, , 返回查询到的记录数量.被查询的字段为,备注、办公、家里、手机、小灵通.
.参数 被查内容, 文本型, , 被查询的数字文本内容
.局部变量 主循环数, 整数型
.局部变量 次循环数, 整数型
.局部变量 子循环数, 整数型
.局部变量 真记录数, 整数型
.局部变量 查询字数, 整数型
.局部变量 记录总数, 整数型
.局部变量 临时文本, 文本型
.局部变量 文本长度, 整数型
.局部变量 查询结果, 逻辑型


查询字数 ＝ 取文本长度 (被查内容)
.如果真 (查询字数 ＝ 0)
    重定义数组 (记录数组, 假, 0)
    返回 (0)
.如果真结束
记录总数 ＝ 取记录数 ()
重定义数组 (记录数组, 假, 记录总数)
到首记录 ()
真记录数 ＝ 0
主循环数 ＝ 0
.计次循环首 (记录总数, 主循环数)
    跳到 (主循环数)
    查询结果 ＝ 假
    次循环数 ＝ 0
    .计次循环首 (5, 次循环数)
        临时文本 ＝ “”
        临时文本 ＝ 读 (次循环数 ＋ 2)
        文本长度 ＝ 取文本长度 (临时文本)
        .如果真 (文本长度 ≥ 查询字数)
            子循环数 ＝ 0
            .计次循环首 (文本长度 － 查询字数 ＋ 1, 子循环数)
                .如果真 (被查内容 ＝ 取文本中间 (临时文本, 子循环数, 查询字数))
                    查询结果 ＝ 真
                    跳出循环 ()
                .如果真结束

            .计次循环尾 ()
        .如果真结束
        .如果真 (查询结果 ＝ 真)
            真记录数 ＝ 真记录数 ＋ 1
            记录数组 [真记录数] ＝ 主循环数
            跳出循环 ()
        .如果真结束

    .计次循环尾 ()
.计次循环尾 ()
重定义数组 (记录数组, 真, 真记录数)
返回 (真记录数)


.子程序 翻页键状态
.局部变量 最大页数, 整数型


最大页数 ＝ (取数组成员数 (记录数组) ＋ 4) ＼ 5 － 1
.如果 (最大页数 ＜ 1)
    上翻页按钮.禁止 ＝ 真
    下翻页按钮.禁止 ＝ 真
    标签表当前页 ＝ 0
.否则
    .如果 (标签表当前页 ＞ 0)
        上翻页按钮.禁止 ＝ 假
    .否则
        上翻页按钮.禁止 ＝ 真
        标签表当前页 ＝ 0
    .如果结束
    .如果 (标签表当前页 ＜ 最大页数)
        下翻页按钮.禁止 ＝ 假
    .否则
        下翻页按钮.禁止 ＝ 真
        标签表当前页 ＝ 最大页数
    .如果结束

.如果结束
返回 ()


.子程序 标签表帮助
.参数 显示第几条, 整数型, 可空


.如果真 (显示第几条 ＝ 0)
    标签表1.标题 ＝ “ 请在智能查询输入框中输入要查询的电话号码，或汉字的首拼字母。”
    标签表2.标题 ＝ “ 查询电话号码，可以输入电话号中任意几位连续数字进行模糊查询。”
    标签表3.标题 ＝ “ 查询汉字信息时，只需输入每个字的拼音声母即可查询，非常方便。”
    标签表4.标题 ＝ “ 汉字查询同样也可以输入中间几个连续字的声母进行模糊查询。”
    标签表5.标题 ＝ “ 遇到韵母字时须将韵母全部输入。如：二(er)、安(an)、昂(ang)等。”
.如果真结束

.如果真 (显示第几条 ＝ 1)
    标签表1.标题 ＝ “ 欢迎使用电话表智能查询程序，本程序拥有智能中文首拼查询功能。”
    标签表2.标题 ＝ “ 首次运行本程序时，会在程序所在文件夹内创建数据库文件 DHB.EDB 。”
    标签表3.标题 ＝ “ 新建的数据库文件是空文件，您必须输入一些信息才能使用查询功能。”
    标签表4.标题 ＝ “ 您可以逐条输入信息，也可从Excel电子表格中用复制和粘贴导入信息。”
    标签表5.标题 ＝ “ 您所输入的全部信息都被保存在 DHB.EDB 文件内。请妥善保存此文件。”
.如果真结束



.子程序 更新标签表
.局部变量 记录数量, 整数型
.局部变量 标签页五, 整数型
.局部变量 剩余数量, 整数型


标签页五 ＝ 标签表当前页 × 5
记录数量 ＝ 取数组成员数 (记录数组)
剩余数量 ＝ 记录数量 － 标签页五

.如果真 (标签表当前行 ＜ 1)
    标签表当前行 ＝ 1
.如果真结束
.如果真 (标签表当前行 ＞ 剩余数量)
    标签表当前行 ＝ 剩余数量
.如果真结束

.如果 (标签表当前行 ＝ 1)
    标签表1.背景颜色 ＝ #黄色
.否则
    标签表1.背景颜色 ＝ 16769473
.如果结束
.如果 (标签表当前行 ＝ 2)
    标签表2.背景颜色 ＝ #黄色
.否则
    标签表2.背景颜色 ＝ #银白
.如果结束
.如果 (标签表当前行 ＝ 3)
    标签表3.背景颜色 ＝ #黄色
.否则
    标签表3.背景颜色 ＝ 16769473
.如果结束
.如果 (标签表当前行 ＝ 4)
    标签表4.背景颜色 ＝ #黄色
.否则
    标签表4.背景颜色 ＝ #银白
.如果结束
.如果 (标签表当前行 ＝ 5)
    标签表5.背景颜色 ＝ #黄色
.否则
    标签表5.背景颜色 ＝ 16769473
.如果结束

.如果 (记录数量 ＞ 0)
    数量标签.标题 ＝ 到文本 (记录数量) ＋ “条”
    页数标签.标题 ＝ 到文本 (标签表当前页 ＋ 1) ＋ “/” ＋ 到文本 ((记录数量 ＋ 4) ＼ 5) ＋ “页”
.否则
    数量标签.标题 ＝ “”
    页数标签.标题 ＝ “”
.如果结束

.如果 (剩余数量 ＞ 0)
    跳到 (记录数组 [标签页五 ＋ 1])
    标签表1.标题 ＝ 到文本 (标签页五 ＋ 1) ＋ “ ” ＋ 读 (1) ＋ “ ” ＋ 读 (2) ＋ “ ” ＋ 读 (3) ＋ “ ” ＋ 读 (4) ＋ “ ” ＋ 读 (5) ＋ “ ” ＋ 读 (6) ＋ “ ” ＋ 读 (7) ＋ “ ” ＋ 读 (8)
.否则
    标签表1.标题 ＝ “”
.如果结束

.如果 (剩余数量 ＞ 1)
    跳到 (记录数组 [标签页五 ＋ 2])
    标签表2.标题 ＝ 到文本 (标签页五 ＋ 2) ＋ “ ” ＋ 读 (1) ＋ “ ” ＋ 读 (2) ＋ “ ” ＋ 读 (3) ＋ “ ” ＋ 读 (4) ＋ “ ” ＋ 读 (5) ＋ “ ” ＋ 读 (6) ＋ “ ” ＋ 读 (7) ＋ “ ” ＋ 读 (8)
.否则
    标签表2.标题 ＝ “”
.如果结束

.如果 (剩余数量 ＞ 2)
    跳到 (记录数组 [标签页五 ＋ 3])
    标签表3.标题 ＝ 到文本 (标签页五 ＋ 3) ＋ “ ” ＋ 读 (1) ＋ “ ” ＋ 读 (2) ＋ “ ” ＋ 读 (3) ＋ “ ” ＋ 读 (4) ＋ “ ” ＋ 读 (5) ＋ “ ” ＋ 读 (6) ＋ “ ” ＋ 读 (7) ＋ “ ” ＋ 读 (8)
.否则
    标签表3.标题 ＝ “”
.如果结束

.如果 (剩余数量 ＞ 3)
    跳到 (记录数组 [标签页五 ＋ 4])
    标签表4.标题 ＝ 到文本 (标签页五 ＋ 4) ＋ “ ” ＋ 读 (1) ＋ “ ” ＋ 读 (2) ＋ “ ” ＋ 读 (3) ＋ “ ” ＋ 读 (4) ＋ “ ” ＋ 读 (5) ＋ “ ” ＋ 读 (6) ＋ “ ” ＋ 读 (7) ＋ “ ” ＋ 读 (8)
.否则
    标签表4.标题 ＝ “”
.如果结束

.如果 (剩余数量 ＞ 4)
    跳到 (记录数组 [标签页五 ＋ 5])
    标签表5.标题 ＝ 到文本 (标签页五 ＋ 5) ＋ “ ” ＋ 读 (1) ＋ “ ” ＋ 读 (2) ＋ “ ” ＋ 读 (3) ＋ “ ” ＋ 读 (4) ＋ “ ” ＋ 读 (5) ＋ “ ” ＋ 读 (6) ＋ “ ” ＋ 读 (7) ＋ “ ” ＋ 读 (8)
.否则
    标签表5.标题 ＝ “”
.如果结束

返回 ()


.子程序 改变标签行, , , 改变标签表当前行的显示状态
.参数 是否上移, 逻辑型, 可空, 此值为"真"表示要向上移动当前行,如为"假"则表示向下移动.
.局部变量 标签页乘五, 整数型
.局部变量 数组长度, 整数型


标签页乘五 ＝ 标签表当前页 × 5
数组长度 ＝ 取数组成员数 (记录数组)

.如果真 (标签表当前行 ＜ 1)
    标签表当前行 ＝ 1
.如果真结束
.如果真 (标签表当前行 ＞ 数组长度 － 标签页乘五)
    标签表当前行 ＝ 数组长度 － 标签页乘五
.如果真结束

.如果 (是否上移 ＝ 真)
    .如果 (标签表当前行 ＞ 1)
        标签表当前行 ＝ 标签表当前行 － 1
    .否则
        .如果 (标签表当前页 ＞ 0)
            标签表当前页 ＝ 标签表当前页 － 1
            标签表当前行 ＝ 5
        .否则

        .如果结束

    .如果结束

.否则
    .如果 ((数组长度 ＋ 4) ＼ 5 － 1 ＞ 标签表当前页)
        .如果 (标签表当前行 ＜ 5)
            标签表当前行 ＝ 标签表当前行 ＋ 1
        .否则
            标签表当前页 ＝ 标签表当前页 ＋ 1
            标签表当前行 ＝ 1
        .如果结束

    .否则
        .如果 (数组长度 － 标签页乘五 ＞ 标签表当前行)
            标签表当前行 ＝ 标签表当前行 ＋ 1
        .否则
            标签表当前行 ＝ 数组长度 － 标签页乘五
        .如果结束

    .如果结束

.如果结束
更新标签表 ()
返回 ()


.子程序 清空标签表


标签表1.标题 ＝ “”
标签表2.标题 ＝ “”
标签表3.标题 ＝ “”
标签表4.标题 ＝ “”
标签表5.标题 ＝ “”
返回 ()


.子程序 清空输入框表


姓名框.内容 ＝ “”
单位框.内容 ＝ “”
备注框.内容 ＝ “”
办公框.内容 ＝ “”
家里框.内容 ＝ “”
手机框.内容 ＝ “”
小灵通框.内容 ＝ “”
QQ框.内容 ＝ “”

.子程序 更新输入框表
.参数 显示那条, 整数型, 可空, 显示某条标签的内容.注意:此数值不能大于5.如不输入默认为1.
.局部变量 范围容器, 整数型
.局部变量 数组长度, 整数型


范围容器 ＝ 标签表当前页 × 5
数组长度 ＝ 取数组成员数 (记录数组)
.如果真 (显示那条 ＜ 1)
    显示那条 ＝ 1
.如果真结束
.如果真 (显示那条 ＞ 5)
    显示那条 ＝ 5
.如果真结束
.如果真 (数组长度 － 范围容器 ＞ 0)
    .如果真 (范围容器 ＋ 显示那条 ≤ 数组长度)
        跳到 (记录数组 [范围容器 ＋ 显示那条])
        姓名框.内容 ＝ 读 (1)
        单位框.内容 ＝ 读 (2)
        备注框.内容 ＝ 读 (6)
        办公框.内容 ＝ 读 (4)
        家里框.内容 ＝ 读 (5)
        手机框.内容 ＝ 读 (3)
        小灵通框.内容 ＝ 读 (7)
        QQ框.内容 ＝ 读 (8)
    .如果真结束

.如果真结束
返回 ()


.子程序 _姓名框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
姓名框.背景颜色 ＝ #白色
姓名框.被选择字符数 ＝ -1

.子程序 _姓名框_失去焦点

姓名框.背景颜色 ＝ #银白

.子程序 _手机框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
手机框.背景颜色 ＝ #白色
手机框.被选择字符数 ＝ -1

.子程序 _手机框_失去焦点

手机框.背景颜色 ＝ #银白

.子程序 _家里框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
家里框.背景颜色 ＝ #白色
家里框.被选择字符数 ＝ -1

.子程序 _家里框_失去焦点

家里框.背景颜色 ＝ #银白

.子程序 _单位框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
单位框.背景颜色 ＝ #白色
单位框.被选择字符数 ＝ -1

.子程序 _单位框_失去焦点

单位框.背景颜色 ＝ #银白

.子程序 _办公框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
办公框.背景颜色 ＝ #白色
办公框.被选择字符数 ＝ -1

.子程序 _办公框_失去焦点

办公框.背景颜色 ＝ #银白

.子程序 _备注框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
备注框.背景颜色 ＝ #白色
备注框.被选择字符数 ＝ -1

.子程序 _备注框_失去焦点

备注框.背景颜色 ＝ #银白

.子程序 _小灵通框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
小灵通框.背景颜色 ＝ #白色
小灵通框.被选择字符数 ＝ -1

.子程序 _小灵通框_失去焦点

小灵通框.背景颜色 ＝ #银白

.子程序 _QQ框_获得焦点

_启动窗口.回车下移焦点 ＝ 真
QQ框.背景颜色 ＝ #白色
QQ框.被选择字符数 ＝ -1

.子程序 _QQ框_失去焦点

QQ框.背景颜色 ＝ #银白

.子程序 _查询框_获得焦点

查询框.背景颜色 ＝ #黄色
查询框.被选择字符数 ＝ -1

.子程序 _查询框_失去焦点

查询框.背景颜色 ＝ #白色

.子程序 _查询框_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型


.如果真 (键代码 ＝ #回车键)
    查询框.被选择字符数 ＝ -1
.如果真结束

清空标签表 ()

.如果真 (键代码 ＝ #PageUp键)
    _上翻页按钮_被单击 ()
.如果真结束
.如果真 (键代码 ＝ #PageDown键)
    _下翻页按钮_被单击 ()
.如果真结束

.如果真 (键代码 ＝ #左光标键)
    _上翻页按钮_被单击 ()
.如果真结束
.如果真 (键代码 ＝ #右光标键)
    _下翻页按钮_被单击 ()
.如果真结束

.如果真 (键代码 ＝ #上光标键)
    改变标签行 (真)
.如果真结束
.如果真 (键代码 ＝ #下光标键)
    改变标签行 (假)
.如果真结束


.子程序 _查询框_放开某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型


.如果真 (查询框.内容 ≠ 上次查询内容)
    上次查询内容 ＝ 查询框.内容
    模糊查询 (查询框.内容)
.如果真结束
更新标签表 ()
翻页键状态 ()
更新输入框表 (标签表当前行)

星空下的落幕

你好像是在写文章，遇到这类大的文字源码。。我直接无视。

深藏功舆名ゐ

无语  太多了。

深藏功舆名ゐ

不如楼主直接把附件上传了 - -  那样看得懂一些。

夜深殇自会来

最好开源码哦~{:3_228:}{:3_228:}

易团末

{:3_226:}你这叫我们情何以堪,那么多,!你直接上传源码好一些.  

秂苼茹戏

以前上源码的，有的老师却说：你是求助的还是来做生意的？下边是源码，首先声明下载铜板不与我的事{:3_245:}

秂苼茹戏

怎么传不上呢？压缩的
电话智能查询系统.rar (123.8 KB, 下载次数: 68)

2011-10-8 22:35 上传

点击文件名下载附件

柳叶飞

这么长的代码也就罢了，复制就行，可你写的代码把组件名称都改了，天知道你命名的是什么组件，都没法还原，只能无视了，贴源码的前提是规范化命名组件，这样别人才可以看懂啊

例：
编辑框_小灵通
编辑框_手机
单选框_查询

按钮_查询
按钮_增加

星空下的落幕

秂苼茹戏 发表于 2011-10-8 21:49
怎么传不上呢？压缩的

我告诉你吧，，你上传附件这里下载不需要钱