让进度条上显示文字的一个方法

不吸烟的青蛙

[e]
.版本 2
.子程序 画板变进度条, 逻辑型, 公开, 变化成功返回真，失败返回假。可能的失败原因：最大位置比最小位置小等
.参数 画板, 画板, , 要变成画板的进度条
.参数 底色, 整数型, 可空, 留空为白色
.参数 表色, 整数型, 可空, 留空为蓝色
.参数 字体, 字体, 可空, 留空为宋体、小五号，不加粗、不斜体、无下划线、无删除线
.参数 文本颜色, 整数型, 可空, 留空为黑色
.参数 文本, 文本型, , 尽量不要使用多行文本，保证会错位
.参数 方向, 逻辑型, 可空, 进度条的方向，真为纵向，假为横向，留空为假
.参数 最小位置, 整数型, 可空, 留空则为0，必须比最大位置小
.参数 最大位置, 整数型, 可空, 留空则为100，必须比最小位置大
.参数 当前位置, 整数型, , 当大于最大位置与最小位置之差时，将停留在100%进度上
.局部变量 进度条宽度, 整数型, , , 最大位置减最小位置
.局部变量 进度条覆盖宽度, 整数型
.局部变量 文本像素长度, 整数型
.局部变量 文本像素高度, 整数型
.局部变量 文本写出左边, 整数型
.局部变量 文本写出顶边, 整数型
' 这段代码用于初始化留空的参数
.如果真 (是否为空 (底色))
    底色 ＝ #白色
.如果真结束
.如果真 (是否为空 (表色))
    表色 ＝ #蓝色
.如果真结束
.如果真 (是否为空 (字体))
    字体.加粗 ＝ 假
    字体.倾斜 ＝ 假
    字体.删除线 ＝ 假
    字体.下划线 ＝ 假
    字体.字体大小 ＝ 9
    字体.字体名称 ＝ “宋体”
.如果真结束
.如果真 (是否为空 (文本颜色))
    文本颜色 ＝ #黑色
.如果真结束
.如果真 (是否为空 (方向))
    方向 ＝ 假
.如果真结束
.如果真 (是否为空 (最小位置))
    最小位置 ＝ 0
.如果真结束
.如果真 (是否为空 (最大位置))
    最大位置 ＝ 100
.如果真结束

' 这段代码用于初始化画板界面
画板.画板背景色 ＝ 底色
画板.清除 (0, 0, 画板.画板宽度, 画板.画板高度)

' 这段代码用于描绘进度条的位置
进度条宽度 ＝ 最大位置 － 最小位置
.如果真 (进度条宽度 ＜ 0)
    返回 (假)
.如果真结束
.如果真 (当前位置 ＞ 进度条宽度)
    当前位置 ＝ 进度条宽度
.如果真结束
进度条覆盖宽度 ＝ 当前位置 ÷ 进度条宽度 × 画板.画板宽度
画板.刷子颜色 ＝ 表色
.如果 (方向)
    画板.填充矩形 (0, 画板.画板高度, 画板.画板宽度, 画板.画板高度 － 进度条覆盖宽度)
.否则
    画板.填充矩形 (0, 0, 进度条覆盖宽度, 画板.画板高度)
.如果结束

' 这段代码用于居中写出进度条上的文本
文本像素长度 ＝ 四舍五入 (取文本长度 (文本) × 字体.字体大小 × 2 ÷ 3, 0)
文本像素高度 ＝ 四舍五入 (字体.字体大小 × 4 ÷ 3, 0)
文本写出左边 ＝ 四舍五入 ((画板.画板宽度 － 文本像素长度) ÷ 2, 0)
文本写出顶边 ＝ 四舍五入 ((画板.画板高度 － 文本像素高度) ÷ 2, 0)
画板.文本颜色 ＝ 文本颜色
画板.字体 ＝ 字体
画板.定位写出 (文本写出左边, 文本写出顶边, 文本)

返回 (真)

[/e]

下面是成品模块和例程的源码压缩包

画板变进度条.zip (5.4 KB, 下载次数: 106)

2011-9-11 01:29 上传

点击文件名下载附件

不吸烟的青蛙

{:3_244:}SF可以抢掉了

百里情深

看看，学习一下吧

GaмeОひеr

{:3_227:}{:3_227:}{:3_227:}

程序开发推广

来学习学习。。。

374274419

额........................

易赳赳

{:3_227:}{:3_227:}{:3_227:} 多帅

月残辅助

{:3_227:}恢复

十七人

谢谢，多谢

血龙之

看下正好有用~~~~