易语言如何把SMQL查询结果显示到表格中，如下代码，谢谢！

yoosea

.如果 (_启动窗口.外部数据库.打开 (“DRIVER=SQL Server;SERVER=” ＋ 服务器 ＋ “;UID=” ＋ 服务器用户名 ＋ “;PWD=” ＋ 服务器密码 ＋ “;WSID=” ＋ 取主机名 () ＋ “;DATABASE=” ＋ 服务器数据库, , ))
    脚本 ＝ “select  单据编号 from 往来零售单ID”
    记录集1=SQL数据库.查询(脚本)

qinyu511

对不起，路过……帮不上你，

zhaoij

我一点都不懂  不过我

飞达

回复 1# yoosea


    看不明白

乖乖龙

自己研究的，速度又快，还可以判断数据类型
.版本 2
.支持库 eDB
.支持库 eGrid

.子程序 高级表格读取记录集数据
.参数 sql语句, 文本型, , sql脚本
.参数 记录集, 记录集, , 记录集控件
.参数 高级表格, 高级表格, , 接收记录集返回的高级表格控件
.局部变量 行数, 整数型
.局部变量 列数, 整数型
.局部变量 单元格_逻辑, 逻辑型
.局部变量 单元格_文本, 文本型
.局部变量 单元格_货币, 整数型
.局部变量 单元格属性值, 整数型
.局部变量 时间, 整数型

时间 ＝ 取启动时间 ()
置等待鼠标 ()
高级表格.清空数据 ()
记录集.打开 (sql语句, #SQL语句, )
高级表格.行数 ＝ 记录集.记录数量 ＋ 1
高级表格.列数 ＝ 记录集.字段数量 ＋ 1
.计次循环首 (高级表格.列数 － 1, 列数)
    高级表格.置数据 (0, 列数, #表格常量.文本型, 记录集.取字段名 (列数 － 1))
    单元格属性值 ＝ 记录集.取字段类型 (列数 － 1)
    .如果 (单元格属性值 ＝ 20 或 单元格属性值 ＝ 5 或 单元格属性值 ＝ 14 或 单元格属性值 ＝ 3 或 单元格属性值 ＝ 21 或 单元格属性值 ＝ 19 或 单元格属性值 ＝ 18)
        高级表格.置列类型 (列数, #表格常量.数值型)
    .否则
        .如果 (单元格属性值 ＝ 133 或 单元格属性值 ＝ 135)
            高级表格.置列类型 (列数, #表格常量.日期型)
        .否则
            .如果 (单元格属性值 ＝ 205)
                高级表格.置列类型 (列数, #表格常量.图|片型)
            .否则
                .如果 (单元格属性值 ＝ 6)
                    高级表格.置列类型 (列数, #表格常量.货币型)
                    高级表格.置单元格小数位数 (列数, 2)
                    高级表格.置字体属性 (1, 列数, 高级表格.行数 － 1, 列数, #粗体)
                    高级表格.置单元格文字颜色 (1, 列数, 高级表格.行数 － 1, 列数, #藏青)
                .否则
                    .如果 (单元格属性值 ＝ 11)
                        高级表格.置列类型 (列数, #表格常量.选择型)
                    .否则

                    .如果结束


                .如果结束

            .如果结束


        .如果结束

    .如果结束

.计次循环尾 ()
.计次循环首 (记录集.记录数量, 行数)
    .计次循环首 (高级表格.列数 － 1, 列数)
        .如果 (记录集.取字段类型 (列数 － 1) ＝ 11)
            记录集.读逻辑值 (列数 － 1, 单元格_逻辑)
            高级表格.置数据 (行数, 列数, #表格常量.选择型, 单元格_逻辑)
        .否则

            记录集.读文本 (列数 － 1, 单元格_文本)
            高级表格.置数据 (行数, 列数, #表格常量.文本型, 单元格_文本)
        .如果结束

    .计次循环尾 ()
    记录集.到下一条 ()
.计次循环尾 ()

乖乖龙

调用格式例子
高级表格读取记录集数据 (sql查询头 ＋ sql条件文本 ＋ sql排序文本, 主窗口.记录集, 高级表格1)

乖乖龙

另外我还有保存调整列宽的呵呵

乖乖龙

.版本 2
.支持库 eGrid

.子程序 高级表格读列宽
.参数 高级表格, 高级表格
.参数 高级表格列宽节点, 文本型
.局部变量 i, 整数型

.计次循环首 (高级表格.列数, i)
    高级表格.置列宽 (i － 1, 到整数 (读配置项 (取运行目录 () ＋ “\sqlsyscolumns.ini”, 高级表格列宽节点, 到文本 (i), “60”)))

.计次循环尾 ()


.子程序 高级表格保存列宽
.参数 高级表格, 高级表格
.参数 高级表格列宽节点, 文本型
.局部变量 i, 整数型

.计次循环首 (高级表格.列数, i)
    写配置项 (取运行目录 () ＋ “\sqlsyscolumns.ini”, 高级表格列宽节点, 到文本 (i), 到文本 (高级表格.取列宽 (i － 1)))
.计次循环尾 ()

l凌蓝雪

不太明白楼主讲的是什么？？

win768

完全可以采用5楼的