易语言代码转火山视窗

zhou425

.子程序 加密, 文本型
.参数 输入文本, 文本型
.局部变量 i, 整数型
.局部变量 输出文本, 文本型
.局部变量 字节129, 字节型

字节129 ＝ 129
输出文本 ＝ “解密({”
.变量循环首 (1, 取文本长度 (输入文本), 1, i)
输出文本 ＝ 输出文本 ＋ 到文本 (位异或 (到字节 (取代码 (取文本中间 (输入文本, i, 1), )), 字节129)) ＋ “, ”
.变量循环尾 ()
返回 (取文本左边 (输出文本, 取文本长度 (输出文本) － 2) ＋ “})”)


.子程序 解密, 文本型
.参数 加密数组, 字节型, 数组
.局部变量 i, 整数型
.局部变量 输出文本, 文本型
.局部变量 字节129, 字节型

字节129 ＝ 129
.变量循环首 (1, 取数组下标 (加密数组, ), 1, i)
输出文本 ＝ 输出文本 ＋ 字符 (位异或 (到字节 (加密数组 [i]), 字节129))
.变量循环尾 ()
返回 (输出文本)

TBit

<火山程序 类型 = "通常" 版本 = 1 />

方法 加密 <类型 = 文本型 折叠>
参数 输入文本 <类型 = 文本型>
{
    变量 i <类型 = 整数>
    变量 输入文本字节集 <类型 = 字节集类>
    变量 结果 <类型 = 文本型>
    输入文本字节集 = 文本到多字节 (输入文本, 假)
    循环 (0, 输入文本字节集.取字节集长度 (), i)
    {
        加入文本 (结果, "," + 到文本 (位异或 (无符号字节到整数 (输入文本字节集.取字节集数据 (i, 字节)), 129)))
    }
    删除字符 (结果, 0, 1)
    返回 ("解密(\"" + 结果 + "\")")
}

方法 解密 <类型 = 文本型 折叠>
参数 加密数组 <类型 = 文本型>
{
    变量 字符数组 <类型 = 文本数组类>
    变量 字节集数据 <类型 = 字节集类>
    分割子文本 (加密数组, ",", 字符数组, , )
    字符数组.枚举循环 ()
    {
        字节集数据.添加字节集内容 (位异或 (文本到整数 (字符数组.取枚举值 ()), 129))
    }
    返回 (多字节到文本 (字节集数据))
}

大司命

这些命令火山视窗也有啊！直接用火山视窗照着写一遍就是了~