求CRC8,CRC16怎么取

a285277906

如题 精易有CRC32，但是CRC8,CRC16怎么取？？？？

2114203

yangzaishen

.版本 2

.子程序 CRC8, 整数型, , CRC8查表算法
.参数 欲校验的整数, 字节集
.局部变量 CRC, 整数型
.局部变量 table, 整数型, , "256"
.局部变量 i, 整数型

' * Name:    CRC-8  x8+x2+x+1
' * Poly:    0x07
' * lnit:    0x00
' * Refin:   False
' * Refout:  False
' * Xorout:  0x00
' * Note:
' —————————————————输入、输出不反转、结果不异或————————————————————
.变量循环首 (0, 255, 1, i)
    CRC ＝ i
    .变量循环首 (0, 7, 1, )
        .如果 (位与 (CRC, 128) ≠ 0)  ' “0x80”
            CRC ＝ 位异或 (左移 (CRC, 1), 7)  ' // 多项式 “0x07”
        .否则
            CRC ＝ 左移 (CRC, 1)
        .如果结束

    .变量循环尾 ()
    table [i ＋ 1] ＝ CRC
.变量循环尾 ()
CRC ＝ 0  ' 初始值“0x00”
.变量循环首 (1, 取字节集长度 (欲校验的整数), 1, i)
    CRC ＝ 位与 (table [位异或 (欲校验的整数 [i], 位与 (CRC, 255)) ＋ 1], 255)
.变量循环尾 ()
返回 (CRC)

yangzaishen

.版本 2

.子程序 CRC16_IBM, 整数型, , CRC-16标准查表算法
.参数 欲校验的整数, 字节集
.局部变量 CRC, 整数型
.局部变量 table, 整数型, , "256"
.局部变量 i, 整数型

' Name:    CRC-16/IBM  X16+X15+X2+1
' Poly:    0x8005
' lnit:    0x0000
' Refin:   Ture
' Refout:  Ture
' Xorout:  0x0000
' Note:    CRC-16,CRC-16/ARC,CRC-16LHA
' —————————————————输入、输出反转、结果不异或————————————————————
.变量循环首 (0, 255, 1, i)
    CRC ＝ i
    .变量循环首 (1, 8, 1, )
        .如果 (位与 (CRC, 1) ≠ 0)
            CRC ＝ 位异或 (右移 (CRC, 1), 40961)  ' // 多项式 “0xA001”= Reverse 0x8005
        .否则
            CRC ＝ 右移 (CRC, 1)
        .如果结束

    .变量循环尾 ()
    table [i ＋ 1] ＝ CRC
.变量循环尾 ()
CRC ＝ 0  ' 初始值“0x0000”
.变量循环首 (1, 取字节集长度 (欲校验的整数), 1, i)
    CRC ＝ 位异或 (右移 (CRC, 8), table [位异或 (欲校验的整数 [i], 位与 (CRC, 255)) ＋ 1])
.变量循环尾 ()
返回 (CRC)

yangzaishen

全套CRC算法都有，CRC16有好几种，CRC32也有两种，还有CRC8，CRC4,CRC5 CRC6 CRC7算法。

男拥有

yangzaishen 发表于 2020-3-8 23:12
全套CRC算法都有，CRC16有好几种，CRC32也有两种，还有CRC8，CRC4,CRC5 CRC6 CRC7算法。

求一套   CRC16有好几种，CRC32也有两种，还有CRC8，CRC4,CRC5 CRC6 CRC7算法。

扶苏沐

yangzaishen 发表于 2020-3-8 23:12
全套CRC算法都有，CRC16有好几种，CRC32也有两种，还有CRC8，CRC4,CRC5 CRC6 CRC7算法。

全套的源码方便发下吗

扶苏沐

yangzaishen 发表于 2020-3-8 23:12
全套CRC算法都有，CRC16有好几种，CRC32也有两种，还有CRC8，CRC4,CRC5 CRC6 CRC7算法。

算法可以分享下吗

7787430

yangzaishen 发表于 2020-3-8 23:12
全套CRC算法都有，CRC16有好几种，CRC32也有两种，还有CRC8，CRC4,CRC5 CRC6 CRC7算法。

需要一套CRC算法，给不给发我一套，谢谢

扶苏沐

yangzaishen 发表于 2020-3-8 23:12
全套CRC算法都有，CRC16有好几种，CRC32也有两种，还有CRC8，CRC4,CRC5 CRC6 CRC7算法。 ...

求算法求算法求算法求算法