怎么全盘搜索所有文件夹

无名d晓峰

搜索一个文件夹里面的文件夹，再搜索里面的文件夹，把所有搜索到的文件夹都记录下来

冬天风雪来

.版本 2



.子程序 目录_枚举子目录_下下级, 整数型, 公开, 取一个文件夹下级子目录；成功返回子目录数量，失败返回0；通过是否枚举子目录参数，可以枚举所有的子目录
.参数 父文件夹路径, 文本型, , 如：D:\Program Files；目录分割符请用\，路径不以\结尾会自动添加
.参数 子目录数组, 文本型, 参考 可空 数组, 用来装载返回的子目录路径；
.参数 是否带路径, 逻辑型, 可空, 可为空默认为真,假=不带，真=带;
.参数 是否继续向下枚举, 逻辑型, 可空, 为空，默认不枚举。
.局部变量 子目录名, 文本型
.局部变量 本级子目录列表, 文本型, , "0"
.局部变量 目录计数器, 整数型
.局部变量 目录总数, 整数型
.局部变量 局_目录, 文本型

局_目录 ＝ 父文件夹路径
.如果真 (取文本右边 (局_目录, 1) ≠ “\”)
    局_目录 ＝ 局_目录 ＋ “\”
.如果真结束
子目录名 ＝ 寻找文件 (局_目录 ＋ “*.*”, #子目录)
是否带路径 ＝ 选择 (是否为空 (是否带路径), 真, 是否带路径)
.判断循环首 (子目录名 ≠ “”)
    .如果真 (取文本左边 (子目录名, 1) ≠ “.”)
        加入成员 (本级子目录列表, 子目录名)
        .如果 (是否带路径)
            加入成员 (子目录数组, 局_目录 ＋ 子目录名)
        .否则
            加入成员 (子目录数组, 子目录名)
        .如果结束

    .如果真结束
    处理事件 ()
    子目录名 ＝ 寻找文件 (, #子目录)
.判断循环尾 ()
目录总数 ＝ 取数组成员数 (本级子目录列表)
.如果真 (是否继续向下枚举)
    .计次循环首 (取数组成员数 (本级子目录列表), 目录计数器)
        .如果真 (目录_是否有子目录 (局_目录 ＋ 本级子目录列表 [目录计数器]))
            目录总数 ＝ 目录总数 ＋ 目录_枚举子目录_下下级 (局_目录 ＋ 本级子目录列表 [目录计数器], 子目录数组, 是否带路径, 是否继续向下枚举)
        .如果真结束

    .计次循环尾 ()
.如果真结束
返回 (目录总数)

.子程序 目录_是否有子目录, 逻辑型, 公开, 判断一个目录下有无下级子目录
.参数 当前目录, 文本型, , 目录不以\结尾会自动添加
.局部变量 文件名, 文本型
.局部变量 局_目录, 文本型

局_目录 ＝ 当前目录
.如果真 (取文本右边 (局_目录, 1) ≠ “\”)
    局_目录 ＝ 局_目录 ＋ “\”
.如果真结束
文件名 ＝ 寻找文件 (局_目录 ＋ “*.*”, #子目录)
.判断循环首 (文件名 ≠ “”)
    .如果真 (文件名 ≠ “” 且 文件名 ≠ “.” 且 文件名 ≠ “..”)
        返回 (真)
    .如果真结束
    文件名 ＝ 寻找文件 (, #子目录)
.判断循环尾 ()
返回 (假)

大司命

如此，这般~

石榴熟了

指定文件后缀全盘搜索
http://bbs.125.la/forum.php?mod=viewthread&tid=14006583
(出处: 精易论坛)