ASSCE

结局i

补充内容 (2018-9-22 17:40):
ACCESS数据库用外部数据库1.执行如何删除数据库里的表

奋斗的心

.版本 2
.支持库 eDB
.支持库 iext

.子程序 连接数据库

库管理文件名 ＝ 取运行目录 () ＋ “\shujuku.mdb”
.如果真 (文件是否存在 (库管理文件名) ＝ 假)
    信息框 (“数据库文件不存在，请查看文件完整性！”, 0, , )
    结束 ()
.如果真结束

.如果真 (窗口_1管理.数据库连接1.连接Access (库管理文件名, “”))
    读取数据库表到树形框 ()
.如果真结束


.子程序 读取数据库表到树形框
.局部变量 所有表名称, 文本型, , "0"
.局部变量 i, 整数型
.局部变量 sql语句, 文本型
.局部变量 部门名称, 文本型
.局部变量 字体大小, 整数型
.局部变量 部门图标eil, 整数型
.局部变量 行高, 整数型
.局部变量 索引, 整数型
.局部变量 树形索引缩进, 整数型
.局部变量 加粗, 逻辑型

.如果真 (窗口_1管理.记录集_管理.置连接 (窗口_1管理.数据库连接1) ＝ 假)
    信息框 (“连接数据库失败”, 0, , )
    返回 ()
.如果真结束
窗口_1管理.记录集_管理.打开 (“数据库关联记录”, #数据表名, )
窗口_1管理.记录集_管理.到首记录 ()
.计次循环首 (窗口_1管理.记录集_管理.记录数量, )
    窗口_1管理.记录集_管理.读整数 (“树形索引缩进”, 树形索引缩进)
    窗口_1管理.记录集_管理.读文本 (“部门名称”, 部门名称)
    窗口_1管理.记录集_管理.读整数 (“字体大小”, 字体大小)
    窗口_1管理.记录集_管理.读整数 (“行高”, 行高)
    窗口_1管理.记录集_管理.读逻辑值 (“是否加粗”, 加粗)
    窗口_1管理.记录集_管理.读整数 (“部门图标eil”, 部门图标eil)
    窗口_1管理.树型框1.加入项目 (树形索引缩进, 部门名称, 部门图标eil, 部门图标eil, , 加粗, )
    窗口_1管理.记录集_管理.到下一条 ()
.计次循环尾 ()
窗口_1管理.记录集_管理.关闭 ()

.子程序 取数据库表名, 逻辑型, 公开, 取得mdb的所有表名。
.参数 取回表名, 文本型, 参考 数组, 文本数组，存储返回的表名
.参数 acc数据库, 文本型
.参数 密码, 文本型, 可空
.局部变量 ADODB连接, 对象
.局部变量 表名列记录集, 对象
.局部变量 对象型, 对象
.局部变量 对象型1, 对象
.局部变量 变体型, 变体型
.局部变量 连接文本, 文本型
.局部变量 数据库名, 文本型
.局部变量 密码1, 文本型

清除数组 (取回表名)
.如果真 (ADODB连接.创建 (“ADODB.Connection”, ))
    ' ADODB连接.查看 ()
    密码1 ＝ 选择 (是否为空 (密码), “”, “;Jet OLEDB:DataBase Password=” ＋ 密码)
    连接文本 ＝ “Provider=Microsoft.Jet.OLEDB.4.0;User ID=Admin;Data Source=” ＋ acc数据库 ＋ 密码1  ' 后面是数据库路径
    ADODB连接.写属性 (“connectionstring”, 连接文本)
    ADODB连接.方法 (“open”, )
    对象型1 ＝ ADODB连接.读对象型属性 (“Errors”, )  ' 连接错误信息
    .如果真 (对象型1.是否为空 () ＝ 假)
        变体型.赋值 (0, )
        对象型 ＝ 对象型1.读对象型属性 (“Item”, 变体型)
        .如果真 (对象型.是否为空 () ＝ 真)
            返回 (假)
        .如果真结束

    .如果真结束
    表名列记录集 ＝ ADODB连接.对象型方法 (“OpenSchema”, 20)

    表名列记录集.方法 (“MoveFirst”, )
    .判断循环首 (表名列记录集.读逻辑属性 (“eof”, ) ＝ 假)  ' 循环取表名列表
        对象型1 ＝ 表名列记录集.读对象型属性 (“Fields”, )
        变体型.赋值 (“TABLE_TYPE”, )  ' 取表类型
        对象型 ＝ 对象型1.读对象型属性 (“Item”, 变体型)
        变体型 ＝ 对象型.读属性 (“Value”, )
        .如果真 (变体型.取文本 () ＝ “TABLE”)  ' 取表名
            变体型.赋值 (“TABLE_NAME”, )
            对象型 ＝ 对象型1.读对象型属性 (“Item”, 变体型)
            变体型 ＝ 对象型.读属性 (“Value”, )
            加入成员 (取回表名, 变体型.取文本 ())
        .如果真结束
        表名列记录集.方法 (“MoveNext”, )
    .判断循环尾 ()
    表名列记录集.方法 (“MoveFirst”, )
    表名列记录集.方法 (“Close”, )
.如果真结束
对象型.方法 (“Close”, )
对象型1.方法 (“Close”, )
表名列记录集.方法 (“Close”, )
ADODB连接.方法 (“Close”, )
返回 (真)

.子程序 创建表名
.参数 表格名, 文本型
.局部变量 SQL, 文本型
.局部变量 表名数组, 文本型, , "0"

' create Table 表格名(id Counter primary key ,字段1  nvarchar,字段2  nvarchar)
' 注：nvarchar(文本)；int（整数）；datetime（日期时间）；bit（逻辑）；text（备注）
' 输入框 (“输入创建表格名”, “创建表格”, , 表格名, , )
.如果真 (表格名 ＝ “”)
    返回 ()
.如果真结束
SQL ＝ “create Table ” ＋ 表格名
.如果真 (窗口_1管理.记录集_管理.置连接 (窗口_1管理.数据库连接1) ＝ 假)
    信息框 (“连接数据库失败”, 0, , )
    返回 ()
.如果真结束
窗口_1管理.记录集_管理.打开 (SQL, #SQL语句, )
窗口_1管理.记录集_管理.关闭 ()

.子程序 删除表
.参数 表格名, 文本型
.局部变量 SQL, 文本型
.局部变量 表名数组, 文本型, , "0"

输入框 (“输入删除表格名”, “删除表格”, , 表格名, , )
.如果真 (表格名 ＝ “”)
    返回 ()
.如果真结束
SQL ＝ “drop table ” ＋ 表格名
窗口_1管理.记录集_管理.打开 (SQL, #SQL语句, )
窗口_1管理.记录集_管理.关闭 ()

结局i

                  刚刚不小心按了一下回车键，标题都没打好就发帖了.............没有输入内容也可以发帖还有这种操作

结局i

奋斗的心 发表于 2018-9-22 17:42
.版本 2
.支持库 eDB
.支持库 iext

感谢