逻辑门运算实现的加减法运算，一篇源码是看懂cpu是如何计算1+1以及1-1的

9876543210

通过这样的方式进行运算，内置了全加器以及全减器的源码，移植到保密文件中进行运算，因为这种方法主要的运算很少会去访问cpu的加减指令，大多数是逻辑判断以及数值传送指令完成的加减运算，顶级防破加固的唯一方法就是一些算法用几条逻辑运算指令去完成，运算速度并不重要，也看懂了cpu是如何进行加减计算的，没有做不到的只有想不到的。主要的运算是由 并且() 或者() 取反() 以及逻辑型数组实现功能强大复杂的运算，拿给大神反汇编看的话大多数会被看得一脸懵逼。
暂时没有加入数字大小比较以及乘除取余计算，懂数电的大神门可以继续完善以及优化，源码有问题请在楼下回复。
[e]
.版本 2
.支持库 spec

.程序集 窗口程序集_启动子程序

.子程序 _启动子程序, 整数型
.局部变量 进位, 逻辑型
.局部变量 A, 整数型
.局部变量 B, 整数型
.局部变量 加减运算, 逻辑型

.计次循环首 (1000000, )
    A ＝ 取随机数 (0, 255)
    B ＝ 取随机数 (0, 255)

    加减运算 ＝ 取随机数 (0, 1) ＝ 0
    调试输出 (A, B)
    .如果 (加减运算)
        .如果真 (加 (A, B) ≠ 到字节 (A ＋ B))
            暂停 ()
        .如果真结束


    .否则
        .如果真 (减 (A, B) ≠ 到字节 (A － B))
            暂停 ()
        .如果真结束

    .如果结束


.计次循环尾 ()
返回 (0)

.子程序 与门, 逻辑型
.参数 A, 逻辑型
.参数 B, 逻辑型

返回 (A 且 B)



.子程序 或门, 逻辑型
.参数 A, 逻辑型
.参数 B, 逻辑型

返回 (A 或 B)

.子程序 非门, 逻辑型
.参数 A, 逻辑型

返回 (取反 (A))

.子程序 与非门, 逻辑型
.参数 A, 逻辑型
.参数 B, 逻辑型

返回 (非门 (与门 (A, B)))




.子程序 或非门, 逻辑型
.参数 A, 逻辑型
.参数 B, 逻辑型

返回 (非门 (或门 (A, B)))


.子程序 异或门, 逻辑型
.参数 A, 逻辑型
.参数 B, 逻辑型

返回 (与门 (与非门 (A, B), 或门 (A, B)))


.子程序 同或门, 逻辑型
.参数 A, 逻辑型
.参数 B, 逻辑型

返回 (与非门 (与非门 (A, B), 或门 (A, B)))


.子程序 一位全加器, 逻辑型
.参数 被加数, 逻辑型
.参数 加数, 逻辑型
.参数 进位, 逻辑型, 参考
.局部变量 A, 逻辑型, , "4"

A [1] ＝ 与门 (被加数, 加数)
A [2] ＝ 异或门 (被加数, 加数)
A [3] ＝ 与门 (进位, A [2])
A [4] ＝ 异或门 (进位, A [2])
进位 ＝ 或门 (A [1], A [3])
返回 (A [4])

.子程序 一位全减器, 逻辑型
.参数 被减数, 逻辑型
.参数 减数, 逻辑型
.参数 借位, 逻辑型, 参考
.局部变量 A, 逻辑型, , "6"

A [1] ＝ 异或门 (被减数, 减数)
A [6] ＝ 异或门 (借位, A [1])
A [2] ＝ 非门 (被减数)
A [3] ＝ 与门 (A [2], 减数)
A [4] ＝ 非门 (A [1])
A [5] ＝ 与门 (A [4], 借位)
借位 ＝ 或门 (A [5], A [3])
返回 (A [6])

.子程序 加, 字节型
.参数 被加数, 字节型
.参数 加数, 字节型
.参数 进位, 逻辑型, 参考 可空
.局部变量 被加数逻辑, 逻辑型, , "8"
.局部变量 加数逻辑, 逻辑型, , "8"
.局部变量 和逻辑, 逻辑型, , "8"
.局部变量 位计数, 整数型

字节到逻辑型数组 (被加数, 被加数逻辑)
字节到逻辑型数组 (加数, 加数逻辑)
.计次循环首 (8, 位计数)
    和逻辑 [位计数] ＝ 一位全加器 (被加数逻辑 [位计数], 加数逻辑 [位计数], 进位)
.计次循环尾 ()
返回 (逻辑型数组到字节 (和逻辑))

.子程序 减, 字节型
.参数 被减数, 字节型
.参数 减数, 字节型
.参数 借位, 逻辑型, 参考 可空
.局部变量 被减数逻辑, 逻辑型, , "8"
.局部变量 减数逻辑, 逻辑型, , "8"
.局部变量 差逻辑, 逻辑型, , "8"
.局部变量 位计数, 整数型

字节到逻辑型数组 (被减数, 被减数逻辑)
字节到逻辑型数组 (减数, 减数逻辑)
.计次循环首 (8, 位计数)
    差逻辑 [位计数] ＝ 一位全减器 (被减数逻辑 [位计数], 减数逻辑 [位计数], 借位)
.计次循环尾 ()
返回 (逻辑型数组到字节 (差逻辑))

.子程序 逻辑型数组到字节, 字节型
.参数 逻辑数组, 逻辑型, 数组
.局部变量 移位, 整数型
.局部变量 返回值, 字节型

.变量循环首 (0, 7, 1, 移位)
    返回值 ＝ 位或 (返回值, 左移 (到字节 (逻辑数组 [移位 ＋ 1]), 移位))
.变量循环尾 ()
返回 (返回值)

.子程序 字节到逻辑型数组
.参数 字节, 字节型
.参数 逻辑数组, 逻辑型, 参考 数组
.局部变量 移位, 整数型


.变量循环首 (0, 7, 1, 移位)
    逻辑数组 [移位 ＋ 1] ＝ 位与 (字节, 左移 (1, 移位)) ≠ 0
.变量循环尾 ()


.子程序 是否相等, 逻辑型
.参数 A, 字节型
.参数 B, 字节型
.局部变量 A逻辑, 逻辑型, , "8"
.局部变量 B逻辑, 逻辑型, , "8"
.局部变量 同或逻辑, 逻辑型, , "8"
.局部变量 位计数, 整数型

字节到逻辑型数组 (A, A逻辑)
字节到逻辑型数组 (B, B逻辑)
.计次循环首 (8, 位计数)
    同或逻辑 [位计数] ＝ 同或门 (A逻辑 [位计数], B逻辑 [位计数])
.计次循环尾 ()
返回 (逻辑型数组到字节 (同或逻辑) ＝ 255)

[/e]

Narkylix

可以的,很棒

Narkylix

我就不信我种不了

Narkylix

那一波JB...

a393198821

牛逼，谢谢你的分享

616153492

牛逼，谢谢你的分享

wuwang

瞬间回到mc建造计算器是时刻

2446789312

！！一脸懵逼！！

545176793

头有点晕!!

sa123123

有点晕