超级菜鸟求助图片展示问题

niubi7789639

刚刚注册的新号码，小弟刚刚接触易语言，也想自己做一个小工具

具体思路
启动窗口点击按钮打开窗口1

窗口1下面有4个按钮   上一个     自动   下一个   返回
按下一个   会有转场效果并顺序播放一张提前写入软件的图片
按上一个    会有转场效果并反序播放图片
按自动       会隔4秒顺序播放一张图片
按返回       关闭窗口一，返回启动窗口

思路基本就这样，小弟不知道实现起来有多难，可能在你们眼里小儿科，但是我的确刚入的小白，所以，好多不懂的地方，

小弟刚接触是在不知道怎么才能实现，看了别人的源码，但是不明白，修改了也不能用，希望有大虾能帮帮我，小弟不胜感激，谢谢了，

小弟在此跪谢各位坛子里的大大们，谢谢你们了，帮帮忙吧！！！


我想请教各位大侠，就是最好能给我讲讲怎么用，用什么命令，我就是不懂，因为看别人的源码，也不明白，按照教程做的小程序没有这个功能，

我自己做了下，其他都基本没有问题，就是那个图片顺序播放带转场效果，那个地方怎么琢磨都写不出来

用了画板，隐蔽画板，也不大会弄，，，


在此谢谢那位大侠能给我讲解下，或者举个小例子，让我能明白了以后，自己研究写代码就OK了，呵呵

在此特别感谢特别感谢7楼的唐老湿   给我发了个，我研究下，谢谢，



回复唐老师

首先说明，，你的这个源码，基本符合我的要求，就是没有转场，，专场就是图片切换不是直接切换，是有那种特效的切换，风格可以随机

我这有一个源码，就是带那种效果，只不过这个是用画板隐藏画板组合达到的效果，我试着改了下，发现怎么都不行，就用你写的那个改了下，发现可以了，就差转场了，起码都可以了，

我把那个别人写的发下，你看下，你肯定能明白，麻烦你看了以后，帮我写下吧
谢谢了
.版本 2
.程序集 窗口程序集1
.程序集变量 速度, 整数型
.子程序 __启动窗口_创建完毕
置随机数种子 ()
隐藏画板.宽度 ＝ 演示画板.宽度
隐藏画板2.宽度 ＝ 演示画板.宽度
隐藏画板3.宽度 ＝ 演示画板.宽度
隐藏画板.高度 ＝ 演示画板.高度
隐藏画板2.高度 ＝ 演示画板.高度
隐藏画板3.高度 ＝ 演示画板.高度
' 程序数组 ＝ { &从左往右推出效果, &从右往左推出效果, &从上往下推出效果, &从下往上推出效果, &从左边抽出效果, &从右边抽出效果, &从上边抽出效果, &从下边抽出效果, &从左上抽出效果, &从左下抽出效果, &从右上抽出效果, &从右下抽出效果, &四块抽出效果, &水平条状抽出效果, &垂直条状抽出效果, &从左往右插入效果, &从右往左插入效果, &从上往下插入效果, &从下往上插入效果, &从左上插入效果, &从左下插入效果, &从右上插入效果, &从右下插入效果, &四块插入效果, &水平条状插入效果, &垂直条状插入效果, &从左往右擦除效果, &从右往左擦除效果, &从上往下擦除效果, &从下往上擦除效果, &盒状展开效果, &中间向左右展开效果, &中间向上下展开效果, &盒状收缩效果, &左右向中间收缩效果, &上下向中间收缩效果, &从左往右百叶窗效果, &从右往左百叶窗效果, &从上往下百叶窗效果, &从下往上百叶窗效果, &从左往右棋盘效果, &从右往左棋盘效果, &从上往下棋盘效果, &从下往上棋盘效果, &溶解效果, &水平随机线效果, &垂直随机线效果, &下落线效果 }
演示画板.底图 ＝ #图片2
隐藏画板.底图 ＝ #图片1
.子程序 _按钮1_被单击
_启动窗口.标题 ＝ 到文本 (取随机数 (31, 47))
可随机演示 (到数值 (_启动窗口.标题))

.如果 (隐藏画板.底图 ＝ #图片2)
    隐藏画板.底图 ＝ #图片1
.否则
    隐藏画板.底图 ＝ #图片2
.如果结束

.子程序 按要求演示
.参数 效果1, 整数型
.参数 效果2, 整数型
.判断开始 (效果1 ＝ 1)
    .判断开始 (效果2 ＝ 1)
        推出效果之从左往右1 ()
    .判断 (效果2 ＝ 2)
        推出效果之从右往左2 ()
    .判断 (效果2 ＝ 3)
        推出效果之从上往下3 ()
    .判断 (效果2 ＝ 4)
        推出效果之从下往上4 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 2)
    .判断开始 (效果2 ＝ 1)
        抽出效果之从左边1 ()
    .判断 (效果2 ＝ 2)
        抽出效果之从右边2 ()
    .判断 (效果2 ＝ 3)
        抽出效果之从上边3 ()
    .判断 (效果2 ＝ 4)
        抽出效果之从下边4 ()
    .判断 (效果2 ＝ 5)
        抽出效果之从左上5 ()
    .判断 (效果2 ＝ 6)
        抽出效果从左下6 ()
    .判断 (效果2 ＝ 7)
        抽出效果之从右上7 ()
    .判断 (效果2 ＝ 8)
        抽出效果之从右下8 ()
    .判断 (效果2 ＝ 9)
        抽出效果之四块9 ()
    .判断 (效果2 ＝ 10)
        抽出效果之水平条状10 ()
    .判断 (效果2 ＝ 11)
        抽出效果之垂直条状11 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 3)
    .判断开始 (效果2 ＝ 1)
        插入效果之从左往右1 ()
    .判断 (效果2 ＝ 2)
        插入效果之从右往左2 ()
    .判断 (效果2 ＝ 3)
        插入效果之从上往下3 ()
    .判断 (效果2 ＝ 4)
        插入效果之从下往上4 ()
    .判断 (效果2 ＝ 5)
        插入效果之从左上5 ()
    .判断 (效果2 ＝ 6)
        插入效果之从左下6 ()
    .判断 (效果2 ＝ 7)
        插入效果之从右上7 ()
    .判断 (效果2 ＝ 8)
        插入效果之从右下8 ()
    .判断 (效果2 ＝ 9)
        插入效果之四块9 ()
    .判断 (效果2 ＝ 10)
        插入效果之水平条状10 ()
    .判断 (效果2 ＝ 11)
        插入效果之垂直条状11 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 4)
    .判断开始 (效果2 ＝ 1)
        擦除效果之从左往右1 ()
    .判断 (效果2 ＝ 2)
        擦除效果之从右往左2 ()
    .判断 (效果2 ＝ 3)
        擦除效果之从上往下3 ()
    .判断 (效果2 ＝ 4)
        擦除效果之从下往上4 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 5)
    .判断开始 (效果2 ＝ 1)
        展开效果之盒状1 ()
    .判断 (效果2 ＝ 2)
        展开效果之中间向左右2 ()
    .判断 (效果2 ＝ 3)
        展开效果之中间向上下3 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 6)
    .判断开始 (效果2 ＝ 1)
        收缩效果之盒状1 ()
    .判断 (效果2 ＝ 2)
        收缩效果之左右向中间2 ()
    .判断 (效果2 ＝ 3)
        收缩效果之上下向中间3 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 7)
    .判断开始 (效果2 ＝ 1)
        百叶窗效果之从左往右1 ()
    .判断 (效果2 ＝ 2)
        百叶窗效果之从右往左2 ()
    .判断 (效果2 ＝ 3)
        百叶窗效果之从上往下3 ()
    .判断 (效果2 ＝ 4)
        百叶窗效果之从下往上4 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 8)
    .判断开始 (效果2 ＝ 1)
        棋盘效果之从左往右1 ()
    .判断 (效果2 ＝ 2)
        棋盘效果之从右往左2 ()
    .判断 (效果2 ＝ 3)
        棋盘效果之从上往下3 ()
    .判断 (效果2 ＝ 4)
        棋盘效果之从下往上4 ()
    .默认
    .判断结束
.判断 (效果1 ＝ 9)
    溶解效果 ()
.判断 (效果1 ＝ 10)
    .判断开始 (效果2 ＝ 1)
        随机线效果之水平1 ()
    .判断 (效果2 ＝ 2)
        随机线效果之垂直2 ()
    .判断 (效果2 ＝ 3)
        随机线效果之下落3 ()
    .默认
    .判断结束
.默认
.判断结束

.子程序 推出效果之从左往右1, , , 从左往右
.局部变量 左边1, 整数型
.判断循环首 (左边1 ＜ 演示画板.宽度 ＋ 5)
    演示画板.复制 (左边1, 0, 演示画板.宽度 － 左边1, 演示画板.高度, , 左边1 ＋ 5, 0, )
    左边1 ＝ 左边1 ＋ 5
    隐藏画板.复制 (隐藏画板.宽度 － 左边1, 0, 左边1, 隐藏画板.高度, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 推出效果之从右往左2
.局部变量 左边1, 整数型
.判断循环首 (左边1 ＜ 演示画板.宽度 ＋ 5)
    演示画板.复制 (5, 0, 演示画板.宽度 － 左边1, 演示画板.高度, , 0, 0, )
    左边1 ＝ 左边1 ＋ 5
    隐藏画板.复制 (0, 0, 左边1, 隐藏画板.高度, 演示画板, 演示画板.宽度 － 左边1 ＋ 5, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 推出效果之从上往下3
.局部变量 顶边1, 整数型
.判断循环首 (顶边1 ＜ 演示画板.高度 ＋ 5)
    演示画板.复制 (0, 顶边1, 演示画板.宽度, 演示画板.高度 － 顶边1, , 0, 顶边1 ＋ 5, )
    顶边1 ＝ 顶边1 ＋ 5
    隐藏画板.复制 (0, 隐藏画板.高度 － 顶边1, 隐藏画板.宽度, 顶边1, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 推出效果之从下往上4
.局部变量 顶边1, 整数型
.判断循环首 (顶边1 ＜ 演示画板.高度 ＋ 5)
    演示画板.复制 (0, 5, 演示画板.宽度, 演示画板.高度 － 顶边1, , 0, 0, )
    顶边1 ＝ 顶边1 ＋ 5
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 顶边1, 演示画板, 0, 演示画板.高度 － 顶边1 ＋ 5, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之从左边1, , , 从左边
.局部变量 左边1, 整数型
.判断循环首 (左边1 ＜ 演示画板.宽度 ＋ 5)
    演示画板.复制 (0, 0, 演示画板.宽度 － 左边1, 演示画板.高度, , -5, 0, )
    左边1 ＝ 左边1 ＋ 5
    隐藏画板.复制 (隐藏画板.宽度 － 左边1, 0, 左边1, 隐藏画板.高度, 演示画板, 演示画板.宽度 － 左边1, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之从右边2
.局部变量 左边1, 整数型
.判断循环首 (左边1 ＜ 演示画板.宽度 ＋ 5)
    演示画板.复制 (左边1, 0, 演示画板.宽度 － 左边1, 演示画板.高度, , 左边1 ＋ 5, 0, )
    左边1 ＝ 左边1 ＋ 5
    隐藏画板.复制 (0, 0, 左边1, 隐藏画板.高度, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之从上边3
.局部变量 顶边1, 整数型
.判断循环首 (顶边1 ＜ 演示画板.高度 ＋ 5)
    演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度 － 顶边1, , 0, -5, )
    顶边1 ＝ 顶边1 ＋ 5
    隐藏画板.复制 (0, 隐藏画板.高度 － 顶边1, 隐藏画板.宽度, 顶边1, 演示画板, 0, 演示画板.高度 － 顶边1, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之从下边4
.局部变量 顶边1, 整数型
.判断循环首 (顶边1 ＜ 演示画板.高度 ＋ 5)
    演示画板.复制 (0, 顶边1, 演示画板.宽度, 演示画板.高度 － 顶边1, , 0, 顶边1 ＋ 5, )
    顶边1 ＝ 顶边1 ＋ 5
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 顶边1, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之从左上5
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    隐藏画板2.复制 (复制宽度, 复制高度, 隐藏画板2.宽度 － 复制宽度, 隐藏画板2.高度 － 复制高度, 隐藏画板3, -5, -5, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果从左下6
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    隐藏画板2.复制 (复制宽度, 0, 隐藏画板2.宽度 － 复制宽度, 隐藏画板2.高度 － 复制高度, 隐藏画板3, -5, 复制高度 ＋ 5, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之从右上7
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    隐藏画板2.复制 (0, 复制高度, 隐藏画板2.宽度 － 复制宽度, 隐藏画板2.高度 － 复制高度, 隐藏画板3, 复制宽度 ＋ 5, -5, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之从右下8
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    隐藏画板2.复制 (0, 0, 隐藏画板2.宽度 － 复制宽度, 隐藏画板2.高度 － 复制高度, 隐藏画板3, 复制宽度 ＋ 5, 复制高度 ＋ 5, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之四块9
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ÷ 2 ＋ 4)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    隐藏画板2.复制 (复制宽度, 复制高度, 隐藏画板2.宽度 ÷ 2 － 复制宽度, 隐藏画板2.高度 ÷ 2 － 复制高度, 隐藏画板3, -5, -5, )  ' 左上
    隐藏画板2.复制 (复制宽度, 隐藏画板2.高度 ÷ 2, 隐藏画板2.宽度 ÷ 2 － 复制宽度, 隐藏画板2.高度 ÷ 2 － 复制高度, 隐藏画板3, -5, 隐藏画板2.高度 ÷ 2 ＋ 复制高度 ＋ 5, )  ' 左下
    隐藏画板2.复制 (隐藏画板2.宽度 ÷ 2, 复制高度, 隐藏画板2.宽度 ÷ 2 － 复制宽度, 隐藏画板2.高度 ÷ 2 － 复制高度, 隐藏画板3, 隐藏画板2.宽度 ÷ 2 ＋ 复制宽度 ＋ 5, 0, )  ' 右上
    隐藏画板2.复制 (隐藏画板2.宽度 ÷ 2, 隐藏画板2.高度 ÷ 2, 隐藏画板2.宽度 ÷ 2 － 复制宽度, 隐藏画板2.高度 ÷ 2 － 复制高度, 隐藏画板3, 隐藏画板2.宽度 ÷ 2 ＋ 复制宽度 ＋ 5, 隐藏画板2.高度 ÷ 2 ＋ 复制高度 ＋ 5, )  ' 右下
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之水平条状10
.局部变量 复制宽度, 整数型
.局部变量 容器1, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    .变量循环首 (1, 10, 1, 容器1)
        .如果 (容器1 ％ 2 ＝ 1)
            隐藏画板2.复制 (复制宽度, 隐藏画板2.高度 ÷ 10 × (容器1 － 1), 隐藏画板2.宽度 － 复制宽度, 隐藏画板2.高度 ÷ 10, 隐藏画板3, -5, 隐藏画板3.高度 ÷ 10 × (容器1 － 1), )
        .否则
            隐藏画板2.复制 (0, 隐藏画板2.高度 ÷ 10 × (容器1 － 1), 隐藏画板2.宽度 － 复制宽度, 隐藏画板2.高度 ÷ 10, 隐藏画板3, 复制宽度 ＋ 5, 演示画板.高度 ÷ 10 × (容器1 － 1), )
        .如果结束
    .变量循环尾 ()
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    复制宽度 ＝ 复制宽度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 抽出效果之垂直条状11
.局部变量 复制高度, 整数型
.局部变量 容器1, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.判断循环首 (复制高度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    .变量循环首 (1, 10, 1, 容器1)
        .如果 (容器1 ％ 2 ＝ 1)
            隐藏画板2.复制 (隐藏画板2.宽度 ÷ 10 × (容器1 － 1), 复制高度, 隐藏画板2.宽度 ÷ 10, 隐藏画板2.高度 － 复制高度, 隐藏画板3, 隐藏画板3.宽度 ÷ 10 × (容器1 － 1), -5, )
        .否则
            隐藏画板2.复制 (隐藏画板2.宽度 ÷ 10 × (容器1 － 1), 0, 隐藏画板2.宽度 ÷ 10, 隐藏画板2.高度 － 复制高度, 隐藏画板3, 演示画板.宽度 ÷ 10 × (容器1 － 1), 复制高度 ＋ 5, )
        .如果结束
    .变量循环尾 ()
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    复制高度 ＝ 复制高度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从左往右1
.局部变量 左边1, 整数型
.判断循环首 (左边1 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (隐藏画板.宽度 － 左边1, 0, 左边1, 隐藏画板.高度, 演示画板, 0, 0, )
    左边1 ＝ 左边1 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从右往左2
.局部变量 左边1, 整数型
.判断循环首 (左边1 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 左边1, 隐藏画板.高度, 演示画板, 隐藏画板.宽度 － 左边1, 0, )
    左边1 ＝ 左边1 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从上往下3
.局部变量 顶边1, 整数型
.判断循环首 (顶边1 ＜ 演示画板.高度 ＋ 5)
    隐藏画板.复制 (0, 隐藏画板.高度 － 顶边1, 隐藏画板.宽度, 顶边1, 演示画板, 0, 0, )
    顶边1 ＝ 顶边1 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从下往上4
.局部变量 顶边1, 整数型
.判断循环首 (顶边1 ＜ 演示画板.高度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 顶边1, 演示画板, 0, 隐藏画板.高度 － 顶边1, )
    顶边1 ＝ 顶边1 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从左上5
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (隐藏画板.宽度 － 复制宽度, 隐藏画板.高度 － 复制高度, 复制宽度, 复制高度, 演示画板, 0, 0, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从左下6
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (隐藏画板.宽度 － 复制宽度, 0, 复制宽度, 复制高度, 演示画板, 0, 演示画板.高度 － 复制高度, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从右上7
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 隐藏画板.高度 － 复制高度, 复制宽度, 复制高度, 演示画板, 隐藏画板.宽度 － 复制宽度, 0, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之从右下8
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 复制宽度, 复制高度, 演示画板, 隐藏画板.宽度 － 复制宽度, 隐藏画板.高度 － 复制高度, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之四块9
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ÷ 2 ＋ 4)
    隐藏画板.复制 (隐藏画板.宽度 ÷ 2 － 复制宽度, 隐藏画板.高度 ÷ 2 － 复制高度, 复制宽度, 复制高度, 演示画板, 0, 0, )
    隐藏画板.复制 (隐藏画板.宽度 ÷ 2 － 复制宽度, 隐藏画板.高度 ÷ 2, 复制宽度, 复制高度, 演示画板, 0, 隐藏画板.高度 － 复制高度, )
    隐藏画板.复制 (隐藏画板.宽度 ÷ 2, 隐藏画板.高度 ÷ 2 － 复制高度, 复制宽度, 复制高度, 演示画板, 隐藏画板.宽度 － 复制宽度, 0, )
    隐藏画板.复制 (隐藏画板.宽度 ÷ 2, 隐藏画板.高度 ÷ 2, 复制宽度, 复制高度, 演示画板, 演示画板.宽度 － 复制宽度, 演示画板.高度 － 复制高度, )
    复制宽度 ＝ 复制宽度 ＋ 4
    复制高度 ＝ 复制高度 ＋ 3
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之水平条状10
.局部变量 复制宽度, 整数型
.局部变量 容器1, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    .变量循环首 (1, 10, 1, 容器1)
        .如果 (容器1 ％ 2 ＝ 1)
            隐藏画板.复制 (隐藏画板.宽度 － 复制宽度, 隐藏画板.高度 ÷ 10 × (容器1 － 1), 复制宽度, 隐藏画板.高度 ÷ 10, 演示画板, 0, 演示画板.高度 ÷ 10 × (容器1 － 1), )
        .否则
            隐藏画板.复制 (0, 隐藏画板.高度 ÷ 10 × (容器1 － 1), 复制宽度, 隐藏画板.高度 ÷ 10, 演示画板, 演示画板.宽度 － 复制宽度, 演示画板.高度 ÷ 10 × (容器1 － 1), )
        .如果结束
    .变量循环尾 ()
    复制宽度 ＝ 复制宽度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 插入效果之垂直条状11
.局部变量 复制高度, 整数型
.局部变量 容器1, 整数型
.判断循环首 (复制高度 ＜ 演示画板.高度 ＋ 5)
    .变量循环首 (1, 10, 1, 容器1)
        .如果 (容器1 ％ 2 ＝ 1)
            隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (容器1 － 1), 隐藏画板.高度 － 复制高度, 隐藏画板.宽度 ÷ 10, 复制高度, 演示画板, 演示画板.宽度 ÷ 10 × (容器1 － 1), 0, )
        .否则
            隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (容器1 － 1), 0, 隐藏画板.宽度 ÷ 10, 复制高度, 演示画板, 演示画板.宽度 ÷ 10 × (容器1 － 1), 演示画板.高度 － 复制高度, )
        .如果结束
    .变量循环尾 ()
    复制高度 ＝ 复制高度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 擦除效果之从左往右1
.局部变量 复制宽度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (0, 0, 复制宽度, 隐藏画板.高度, 演示画板, 0, 0, )
    复制宽度 ＝ 复制宽度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 擦除效果之从右往左2
.局部变量 复制宽度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 (隐藏画板.宽度 － 复制宽度, 0, 复制宽度, 隐藏画板.高度, 演示画板, 隐藏画板.宽度 － 复制宽度, 0, )
    复制宽度 ＝ 复制宽度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 擦除效果之从上往下3
.局部变量 复制高度, 整数型
.判断循环首 (复制高度 ＜ 演示画板.高度 ＋ 5)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 复制高度, 演示画板, 0, 0, )
    复制高度 ＝ 复制高度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 擦除效果之从下往上4
.局部变量 复制高度, 整数型
.判断循环首 (复制高度 ＜ 演示画板.高度 ＋ 5)
    隐藏画板.复制 (0, 隐藏画板.高度 － 复制高度, 隐藏画板.宽度, 复制高度, 演示画板, 0, 隐藏画板.高度 － 复制高度, )
    复制高度 ＝ 复制高度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 展开效果之盒状1, , , ?
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 4)
    隐藏画板.复制 ((隐藏画板.宽度 － 复制宽度) ÷ 2, (隐藏画板.高度 － 复制高度) ÷ 2, 复制宽度, 复制高度, 演示画板, (演示画板.宽度 － 复制宽度) ÷ 2, (演示画板.高度 － 复制高度) ÷ 2, )
    复制宽度 ＝ 复制宽度 ＋ 8
    复制高度 ＝ 复制高度 ＋ 6
    延时 (速度)
.判断循环尾 ()
.子程序 展开效果之中间向左右2
.局部变量 复制宽度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ＋ 5)
    隐藏画板.复制 ((隐藏画板.宽度 － 复制宽度) ÷ 2, 0, 复制宽度, 隐藏画板.高度, 演示画板, (演示画板.宽度 － 复制宽度) ÷ 2, 0, )
    复制宽度 ＝ 复制宽度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 展开效果之中间向上下3
.局部变量 复制高度, 整数型
.判断循环首 (复制高度 ＜ 演示画板.高度 ＋ 5)
    隐藏画板.复制 (0, (隐藏画板.高度 － 复制高度) ÷ 2, 隐藏画板.宽度, 复制高度, 演示画板, 0, (演示画板.高度 － 复制高度) ÷ 2, )
    复制高度 ＝ 复制高度 ＋ 5
    延时 (速度)
.判断循环尾 ()
.子程序 收缩效果之盒状1
.局部变量 复制宽度, 整数型
.局部变量 复制高度, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板3, 0, 0, )
复制宽度 ＝ 隐藏画板.宽度
复制高度 ＝ 隐藏画板.高度
.判断循环首 (复制宽度 ＋ 4 ＞ 0)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 隐藏画板.高度, 隐藏画板3, 0, 0, )
    隐藏画板2.复制 ((隐藏画板2.宽度 － 复制宽度) ÷ 2, (隐藏画板2.高度 － 复制高度) ÷ 2, 复制宽度, 复制高度, 隐藏画板3, (隐藏画板3.宽度 － 复制宽度) ÷ 2, (隐藏画板3.高度 － 复制高度) ÷ 2, )
    隐藏画板3.复制 (0, 0, 隐藏画板3.宽度, 隐藏画板3.高度, 演示画板, 0, 0, )
    复制宽度 ＝ 复制宽度 － 8
    复制高度 ＝ 复制高度 － 6
    延时 (速度)
.判断循环尾 ()
.子程序 收缩效果之左右向中间2
.局部变量 复制宽度, 整数型
.判断循环首 (复制宽度 ＜ 演示画板.宽度 ÷ 2 ＋ 3)
    隐藏画板.复制 (0, 0, 复制宽度, 隐藏画板.高度, 演示画板, 0, 0, )
    隐藏画板.复制 (隐藏画板.宽度 － 复制宽度, 0, 复制宽度, 隐藏画板.高度, 演示画板, 演示画板.宽度 － 复制宽度, 0, )
    复制宽度 ＝ 复制宽度 ＋ 3
    延时 (速度)
.判断循环尾 ()
.子程序 收缩效果之上下向中间3
.局部变量 复制高度, 整数型
.判断循环首 (复制高度 ＜ 演示画板.高度 ÷ 2 ＋ 3)
    隐藏画板.复制 (0, 0, 隐藏画板.宽度, 复制高度, 演示画板, 0, 0, )
    隐藏画板.复制 (0, 隐藏画板.高度 － 复制高度, 隐藏画板.宽度, 复制高度, 演示画板, 0, 演示画板.高度 － 复制高度, )
    复制高度 ＝ 复制高度 ＋ 3
    延时 (速度)
.判断循环尾 ()
.子程序 百叶窗效果之从左往右1
.局部变量 百叶宽度, 整数型
.局部变量 容器1, 整数型
.判断循环首 (百叶宽度 ＜ 演示画板.宽度 ÷ 10 ＋ 1)
    .变量循环首 (1, 10, 1, 容器1)
        隐藏画板.复制 ((容器1 － 1) × 隐藏画板.宽度 ÷ 10, 0, 百叶宽度, 隐藏画板.高度, 演示画板, (容器1 － 1) × 演示画板.宽度 ÷ 10, 0, )
    .变量循环尾 ()
    百叶宽度 ＝ 百叶宽度 ＋ 1
    延时 (速度)
.判断循环尾 ()
.子程序 百叶窗效果之从右往左2
.局部变量 百叶宽度, 整数型
.局部变量 容器1, 整数型
.判断循环首 (百叶宽度 ＜ 演示画板.宽度 ÷ 10 ＋ 1)
    .变量循环首 (1, 10, 1, 容器1)
        隐藏画板.复制 (容器1 × 隐藏画板.宽度 ÷ 10 － 百叶宽度, 0, 百叶宽度, 隐藏画板.高度, 演示画板, 容器1 × 演示画板.宽度 ÷ 10 － 百叶宽度, 0, )
    .变量循环尾 ()
    百叶宽度 ＝ 百叶宽度 ＋ 1
    延时 (速度)
.判断循环尾 ()
.子程序 百叶窗效果之从上往下3
.局部变量 百叶高度, 整数型
.局部变量 容器1, 整数型
.判断循环首 (百叶高度 ＜ 演示画板.高度 ÷ 10 ＋ 1)
    .变量循环首 (1, 10, 1, 容器1)
        隐藏画板.复制 (0, (容器1 － 1) × 隐藏画板.高度 ÷ 10, 隐藏画板.宽度, 百叶高度, 演示画板, 0, (容器1 － 1) × 演示画板.高度 ÷ 10, )
    .变量循环尾 ()
    百叶高度 ＝ 百叶高度 ＋ 1
    延时 (速度)
.判断循环尾 ()
.子程序 百叶窗效果之从下往上4
.局部变量 百叶高度, 整数型
.局部变量 容器1, 整数型
.判断循环首 (百叶高度 ＜ 演示画板.高度 ÷ 10 ＋ 1)
    .变量循环首 (1, 10, 1, 容器1)
        隐藏画板.复制 (0, 容器1 × 隐藏画板.高度 ÷ 10 － 百叶高度, 隐藏画板.宽度, 百叶高度, 演示画板, 0, 容器1 × 演示画板.高度 ÷ 10 － 百叶高度, )
    .变量循环尾 ()
    百叶高度 ＝ 百叶高度 ＋ 1
    延时 (速度)
.判断循环尾 ()
.子程序 棋盘效果之从左往右1
.局部变量 棋盘宽度, 整数型
.局部变量 宽位置, 整数型
.局部变量 高位置, 整数型
.判断循环首 (棋盘宽度 ＜ 演示画板.宽度 ÷ 10 ＋ 2)
    .变量循环首 (1, 10, 1, 宽位置)
        .变量循环首 (1, 10, 1, 高位置)
            .如果 (高位置 ％ 2 ＝ 1)
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1), 隐藏画板.高度 ÷ 10 × (高位置 － 1), 棋盘宽度, 隐藏画板.高度 ÷ 10, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1), 演示画板.高度 ÷ 10 × (高位置 － 1), )
            .否则
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1) ＋ 隐藏画板.宽度 ÷ 20, 隐藏画板.高度 ÷ 10 × (高位置 － 1), 棋盘宽度, 隐藏画板.高度 ÷ 10, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1) ＋ 演示画板.宽度 ÷ 20, 演示画板.高度 ÷ 10 × (高位置 － 1), )
                .如果真 (棋盘宽度 ＞ 隐藏画板.宽度 ÷ 20 且 宽位置 ＝ 10)
                    隐藏画板.复制 (0, 隐藏画板.高度 ÷ 10 × (高位置 － 1), 棋盘宽度 － 隐藏画板.宽度 ÷ 20, 隐藏画板.高度 ÷ 10, 演示画板, 0, 演示画板.高度 ÷ 10 × (高位置 － 1), )
                .如果真结束
            .如果结束
        .变量循环尾 ()
    .变量循环尾 ()
    棋盘宽度 ＝ 棋盘宽度 ＋ 2
    延时 (速度 ÷ 2)
.判断循环尾 ()
.子程序 棋盘效果之从右往左2
.局部变量 棋盘宽度, 整数型
.局部变量 宽位置, 整数型
.局部变量 高位置, 整数型
.判断循环首 (棋盘宽度 ＜ 演示画板.宽度 ÷ 10 ＋ 2)
    .变量循环首 (1, 10, 1, 宽位置)
        .变量循环首 (1, 10, 1, 高位置)
            .如果 (高位置 ％ 2 ＝ 1)
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × 宽位置 － 棋盘宽度, 隐藏画板.高度 ÷ 10 × (高位置 － 1), 棋盘宽度, 隐藏画板.高度 ÷ 10, 演示画板, 演示画板.宽度 ÷ 10 × 宽位置 － 棋盘宽度, 演示画板.高度 ÷ 10 × (高位置 － 1), )
            .否则
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1) － 棋盘宽度 ＋ 隐藏画板.宽度 ÷ 20, 隐藏画板.高度 ÷ 10 × (高位置 － 1), 棋盘宽度, 隐藏画板.高度 ÷ 10, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1) ＋ 演示画板.宽度 ÷ 20 － 棋盘宽度, 演示画板.高度 ÷ 10 × (高位置 － 1), )
                .如果真 (棋盘宽度 ＞ 隐藏画板.宽度 ÷ 20 且 宽位置 ＝ 1)
                    隐藏画板.复制 (隐藏画板.宽度 ＋ 隐藏画板.宽度 ÷ 20 － 棋盘宽度, 隐藏画板.高度 ÷ 10 × (高位置 － 1), 棋盘宽度 － 隐藏画板.宽度 ÷ 20, 隐藏画板.高度 ÷ 10, 演示画板, 隐藏画板.宽度 ＋ 隐藏画板.宽度 ÷ 20 － 棋盘宽度, 演示画板.高度 ÷ 10 × (高位置 － 1), )
                .如果真结束
            .如果结束
        .变量循环尾 ()
    .变量循环尾 ()
    棋盘宽度 ＝ 棋盘宽度 ＋ 2
    延时 (速度 ÷ 2)
.判断循环尾 ()
.子程序 棋盘效果之从上往下3
.局部变量 棋盘高度, 整数型
.局部变量 高位置, 整数型
.局部变量 宽位置, 整数型
.判断循环首 (棋盘高度 ＜ 演示画板.高度 ÷ 10 ＋ 2)
    .变量循环首 (1, 10, 1, 高位置)
        .变量循环首 (1, 10, 1, 宽位置)
            .如果 (宽位置 ％ 2 ＝ 1)
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1), 隐藏画板.高度 ÷ 10 × (高位置 － 1), 隐藏画板.宽度 ÷ 10, 棋盘高度, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1), 演示画板.高度 ÷ 10 × (高位置 － 1), )
            .否则
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1), 隐藏画板.高度 ÷ 10 × (高位置 － 1) ＋ 隐藏画板.高度 ÷ 20, 隐藏画板.宽度 ÷ 10, 棋盘高度, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1), 演示画板.高度 ÷ 10 × (高位置 － 1) ＋ 演示画板.高度 ÷ 20, )
                .如果真 (棋盘高度 ＞ 隐藏画板.宽度 ÷ 20 且 高位置 ＝ 10)
                    隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1), 0, 隐藏画板.宽度 ÷ 10, 棋盘高度 － 隐藏画板.高度 ÷ 20, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1), 0, )
                .如果真结束
            .如果结束
        .变量循环尾 ()
    .变量循环尾 ()
    棋盘高度 ＝ 棋盘高度 ＋ 2
    延时 (速度 ÷ 2)
.判断循环尾 ()
.子程序 棋盘效果之从下往上4, , , ?
.局部变量 棋盘高度, 整数型
.局部变量 高位置, 整数型
.局部变量 宽位置, 整数型
.判断循环首 (棋盘高度 ＜ 演示画板.宽度 ÷ 10 ＋ 2)
    .变量循环首 (1, 10, 1, 高位置)
        .变量循环首 (1, 10, 1, 宽位置)
            .如果 (宽位置 ％ 2 ＝ 1)
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1), 隐藏画板.高度 ÷ 10 × 高位置 － 棋盘高度, 隐藏画板.宽度 ÷ 10, 棋盘高度, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1), 演示画板.高度 ÷ 10 × 高位置 － 棋盘高度, )
            .否则
                隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1), 隐藏画板.高度 ÷ 10 × (高位置 － 1) － 棋盘高度 ＋ 隐藏画板.高度 ÷ 20, 隐藏画板.宽度 ÷ 10, 棋盘高度, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1), 演示画板.高度 ÷ 10 × (高位置 － 1) ＋ 演示画板.高度 ÷ 20 － 棋盘高度, )
                .如果真 (棋盘高度 ＞ 隐藏画板.宽度 ÷ 20 且 高位置 ＝ 1)
                    隐藏画板.复制 (隐藏画板.宽度 ÷ 10 × (宽位置 － 1), 隐藏画板.高度 ＋ 隐藏画板.高度 ÷ 20 － 棋盘高度, 隐藏画板.宽度 ÷ 10, 棋盘高度 － 隐藏画板.高度 ÷ 20, 演示画板, 演示画板.宽度 ÷ 10 × (宽位置 － 1), 隐藏画板.高度 ＋ 隐藏画板.高度 ÷ 20 － 棋盘高度, )
                .如果真结束
            .如果结束
        .变量循环尾 ()
    .变量循环尾 ()
    棋盘高度 ＝ 棋盘高度 ＋ 2
    延时 (速度 ÷ 2)
.判断循环尾 ()
.子程序 溶解效果
.局部变量 位置数组, 文本型, , "0"
.局部变量 随机位置, 整数型
.局部变量 横, 整数型
.局部变量 竖, 整数型
重定义数组 (位置数组, 假, 0)
.判断循环首 (横 ≤ 演示画板.高度 ÷ 10)
    .判断循环首 (竖 ≤ 演示画板.宽度 ÷ 20)
        加入成员 (位置数组, 到文本 (竖) ＋ “,” ＋ 到文本 (横))
        竖 ＝ 竖 ＋ 1
    .判断循环尾 ()
    横 ＝ 横 ＋ 1
    竖 ＝ 0
.判断循环尾 ()
置随机数种子 ()
.判断循环首 (取数组成员数 (位置数组) ＞ 0)
    随机位置 ＝ 取随机数 (1, 取数组成员数 (位置数组))
    横 ＝ 到数值 (取文本左边 (位置数组 [随机位置], 寻找文本 (位置数组 [随机位置], “,”, , 真) － 1))
    竖 ＝ 到数值 (取文本右边 (位置数组 [随机位置], 取文本长度 (位置数组 [随机位置]) － 寻找文本 (位置数组 [随机位置], “,”, , 真)))
    横 ＝ 横 × 20
    竖 ＝ 竖 × 10
    隐藏画板.复制 (横, 竖, 20, 10, 演示画板, 横, 竖, )
    删除成员 (位置数组, 随机位置, 1)
    延时 (速度 ÷ 2)
.判断循环尾 ()
.子程序 随机线效果之水平1
.局部变量 位置数组, 整数型, , "0"
.局部变量 随机位置, 整数型
重定义数组 (位置数组, 假, 0)
.判断循环首 (随机位置 ≤ 演示画板.高度 ÷ 2)
    加入成员 (位置数组, 随机位置)
    随机位置 ＝ 随机位置 ＋ 1
.判断循环尾 ()
置随机数种子 ()
.判断循环首 (取数组成员数 (位置数组) ＞ 0)
    随机位置 ＝ 取随机数 (1, 取数组成员数 (位置数组))
    隐藏画板.复制 (0, 位置数组 [随机位置] × 2, 隐藏画板.宽度, 2, 演示画板, 0, 位置数组 [随机位置] × 2, )
    删除成员 (位置数组, 随机位置, 1)
    延时 (速度)
.判断循环尾 ()
.子程序 随机线效果之垂直2
.局部变量 位置数组, 整数型, , "0"
.局部变量 随机位置, 整数型
重定义数组 (位置数组, 假, 0)
.判断循环首 (随机位置 ≤ 演示画板.宽度 ÷ 2)
    加入成员 (位置数组, 随机位置)
    随机位置 ＝ 随机位置 ＋ 1
.判断循环尾 ()
置随机数种子 ()
.判断循环首 (取数组成员数 (位置数组) ＞ 0)
    随机位置 ＝ 取随机数 (1, 取数组成员数 (位置数组))
    隐藏画板.复制 (位置数组 [随机位置] × 2, 0, 2, 隐藏画板.宽度, 演示画板, 位置数组 [随机位置] × 2, 0, )
    删除成员 (位置数组, 随机位置, 1)
    延时 (速度)
.判断循环尾 ()
.子程序 随机线效果之下落3
.局部变量 复制位置, 整数型
.局部变量 下落位置, 整数型
演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
.变量循环首 (演示画板.高度 ÷ 2, 0, -1, 复制位置)
    .判断循环首 (下落位置 ≤ 复制位置)
        隐藏画板2.复制 (0, 0, 隐藏画板2.宽度, 隐藏画板2.高度, 演示画板, 0, 0, )
        隐藏画板.复制 (0, 复制位置 × 2, 隐藏画板.宽度, 2, 演示画板, 0, 下落位置 × 2, )
        下落位置 ＝ 下落位置 ＋ 1
        ' 延时 (速度 ÷ 20)  
    .判断循环尾 ()
    演示画板.复制 (0, 0, 演示画板.宽度, 演示画板.高度, 隐藏画板2, 0, 0, )
    下落位置 ＝ 0
.变量循环尾 ()
.子程序 _组合框1_列表项被选择
组合框2.禁止 ＝ 假
组合框2.背景颜色 ＝ #白色
组合框2.清空 ()
.判断开始 (组合框1.现行选中项 ＝ 0)
    组合框2.加入项目 (“从左往右”, 1)
    组合框2.加入项目 (“从右往左”, 2)
    组合框2.加入项目 (“从上往下”, 3)
    组合框2.加入项目 (“从下往上”, 4)
.判断 (组合框1.现行选中项 ＝ 1)
    组合框2.加入项目 (“从左方”, 5)
    组合框2.加入项目 (“从右方”, 6)
    组合框2.加入项目 (“从上方”, 7)
    组合框2.加入项目 (“从下方”, 8)
    组合框2.加入项目 (“从左上方”, 9)
    组合框2.加入项目 (“从左下方”, 10)
    组合框2.加入项目 (“从右上方”, 11)
    组合框2.加入项目 (“从右下方”, 12)
    组合框2.加入项目 (“分成四块”, 13)
    组合框2.加入项目 (“水平条状”, 14)
    组合框2.加入项目 (“垂直条状”, 15)
.判断 (组合框1.现行选中项 ＝ 2)
    组合框2.加入项目 (“从左往右”, 16)
    组合框2.加入项目 (“从右往左”, 17)
    组合框2.加入项目 (“从上往下”, 18)
    组合框2.加入项目 (“从下往上”, 19)
    组合框2.加入项目 (“从左上方”, 20)
    组合框2.加入项目 (“从左下方”, 21)
    组合框2.加入项目 (“从右上方”, 22)
    组合框2.加入项目 (“从右下方”, 23)
    组合框2.加入项目 (“分成四块”, 24)
    组合框2.加入项目 (“水平条状”, 25)
    组合框2.加入项目 (“垂直条状”, 26)
.判断 (组合框1.现行选中项 ＝ 3)
    组合框2.加入项目 (“从左往右”, 27)
    组合框2.加入项目 (“从右往左”, 28)
    组合框2.加入项目 (“从上往下”, 29)
    组合框2.加入项目 (“从下往上”, 30)
.判断 (组合框1.现行选中项 ＝ 4)
    组合框2.加入项目 (“盒状”, 31)
    组合框2.加入项目 (“中间向左右”, 32)
    组合框2.加入项目 (“中间向上下”, 33)
.判断 (组合框1.现行选中项 ＝ 5)
    组合框2.加入项目 (“盒状”, 34)
    组合框2.加入项目 (“左右向中间”, 35)
    组合框2.加入项目 (“上下向中间”, 36)
.判断 (组合框1.现行选中项 ＝ 6)
    组合框2.加入项目 (“从左往右”, 37)
    组合框2.加入项目 (“从右往左”, 38)
    组合框2.加入项目 (“从上往下”, 39)
    组合框2.加入项目 (“从下往上”, 40)
.判断 (组合框1.现行选中项 ＝ 7)
    组合框2.加入项目 (“从左往右”, 41)
    组合框2.加入项目 (“从右往左”, 42)
    组合框2.加入项目 (“从上往下”, 43)
    组合框2.加入项目 (“从下往上”, 44)
.判断 (组合框1.现行选中项 ＝ 8)
    组合框2.禁止 ＝ 真
    组合框2.背景颜色 ＝ #浅灰
.判断 (组合框1.现行选中项 ＝ 9)
    组合框2.加入项目 (“水平”, 46)
    组合框2.加入项目 (“垂直”, 47)
    组合框2.加入项目 (“下落线效果”, 48)
.默认
.判断结束
组合框2.现行选中项 ＝ 0

.子程序 可随机演示
.参数 效果2, 整数型
.判断开始 (效果2 ＝ 1)
    推出效果之从左往右1 ()
.判断 (效果2 ＝ 2)
    推出效果之从右往左2 ()
.判断 (效果2 ＝ 3)
    推出效果之从上往下3 ()
.判断 (效果2 ＝ 4)
    推出效果之从下往上4 ()
.判断 (效果2 ＝ 5)
    抽出效果之从左边1 ()
.判断 (效果2 ＝ 6)
    抽出效果之从右边2 ()
.判断 (效果2 ＝ 7)
    抽出效果之从上边3 ()
.判断 (效果2 ＝ 8)
    抽出效果之从下边4 ()
.判断 (效果2 ＝ 9)
    抽出效果之从左上5 ()
.判断 (效果2 ＝ 10)
    抽出效果从左下6 ()
.判断 (效果2 ＝ 11)
    抽出效果之从右上7 ()
.判断 (效果2 ＝ 12)
    抽出效果之从右下8 ()
.判断 (效果2 ＝ 13)
    抽出效果之四块9 ()
.判断 (效果2 ＝ 14)
    抽出效果之水平条状10 ()
.判断 (效果2 ＝ 15)
    抽出效果之垂直条状11 ()
.判断 (效果2 ＝ 16)
    插入效果之从左往右1 ()
.判断 (效果2 ＝ 17)
    插入效果之从右往左2 ()
.判断 (效果2 ＝ 18)
    插入效果之从上往下3 ()
.判断 (效果2 ＝ 19)
    插入效果之从下往上4 ()
.判断 (效果2 ＝ 20)
    插入效果之从左上5 ()
.判断 (效果2 ＝ 21)
    插入效果之从左下6 ()
.判断 (效果2 ＝ 22)
    插入效果之从右上7 ()
.判断 (效果2 ＝ 23)
    插入效果之从右下8 ()
.判断 (效果2 ＝ 24)
    插入效果之四块9 ()
.判断 (效果2 ＝ 25)
    插入效果之水平条状10 ()
.判断 (效果2 ＝ 26)
    插入效果之垂直条状11 ()
.判断 (效果2 ＝ 27)
    擦除效果之从左往右1 ()
.判断 (效果2 ＝ 28)
    擦除效果之从右往左2 ()
.判断 (效果2 ＝ 29)
    擦除效果之从上往下3 ()
.判断 (效果2 ＝ 30)
    擦除效果之从下往上4 ()
.判断 (效果2 ＝ 31)
    展开效果之盒状1 ()
.判断 (效果2 ＝ 32)
    展开效果之中间向左右2 ()
.判断 (效果2 ＝ 33)
    展开效果之中间向上下3 ()
.判断 (效果2 ＝ 34)
    收缩效果之盒状1 ()
.判断 (效果2 ＝ 35)
    收缩效果之左右向中间2 ()
.判断 (效果2 ＝ 36)
    收缩效果之上下向中间3 ()
.判断 (效果2 ＝ 37)
    百叶窗效果之从左往右1 ()
.判断 (效果2 ＝ 38)
    百叶窗效果之从右往左2 ()
.判断 (效果2 ＝ 39)
    百叶窗效果之从上往下3 ()
.判断 (效果2 ＝ 40)
    百叶窗效果之从下往上4 ()
.判断 (效果2 ＝ 41)
    棋盘效果之从左往右1 ()
.判断 (效果2 ＝ 42)
    棋盘效果之从右往左2 ()
.判断 (效果2 ＝ 43)
    棋盘效果之从上往下3 ()
.判断 (效果2 ＝ 44)
    棋盘效果之从下往上4 ()
.判断 (效果2 ＝ 45)
    溶解效果 ()
.判断 (效果2 ＝ 46)
    随机线效果之水平1 ()
.判断 (效果2 ＝ 47)
    随机线效果之垂直2 ()
.判断 (效果2 ＝ 48)
    随机线效果之下落3 ()
.默认
.判断结束

我把源码放上了，如果你看不明白我复制的，你可以看下源码，下载后改后缀名为E

Hoibben

呵呵，超超级菜鸟路过。。。

小K（βOO）

我不会我本来是来抢沙发的
但是没有抢到

洃铯‰感伤

菜鸟路过

月光族

本人也是一个菜鸟路过

唐老湿

请速度解释 转场是什么意思？

唐老湿

这是菜鸟的写法,希望同为菜鸟的你能够看懂
觉得好请采纳

ゆ复述旧时光

菜鸟路过

niubi7789639

唐老湿 发表于 2013-7-31 08:43
请速度解释 转场是什么意思？

我回复你的问题，在问题里面编辑的，因为代码太长，这不能直接回复，麻烦你看下我问题上面重新编辑过的，谢谢

小K（βOO）

我来灌水啦哈哈