QQ登陆窗口怎么截图

奋斗中的大毛驴

QQ2013登陆窗口怎么截图，精易的模块都不行。求支持

宇智波·晓易

[e]
.版本 2

.子程序 图片_强力截图, 字节集, 公开, ※注：GIF输出最快，BMP最慢但质量最好，PNG较快质量也较好。
.参数 输出格式, 整数型, 可空, 1.BMP；2.JPG；3.GIF；4.TIFF；5.PNG，留空默认为BMP。
.参数 窗口句柄, 整数型, 可空
.参数 输出宽度, 整数型, 可空
.参数 输出高度, 整数型, 可空
.局部变量 n, 整数型
.局部变量 TempFormat, 整数型
.局部变量 Value, 整数型
.局部变量 TempGlobal_1, 整数型
.局部变量 TempGlobal_2, 整数型
.局部变量 Format, 整数型, , "0"
.局部变量 hGlobal, 整数型, , "0"
.局部变量 hThread, 整数型
.局部变量 hBitmap, 整数型
.局部变量 hScrDC, 整数型
.局部变量 hScrMemDC, 整数型
.局部变量 hWinBitmap, 整数型
.局部变量 hWinDC, 整数型
.局部变量 hWinMemDC, 整数型
.局部变量 RECT, 整数型, , "4"
.局部变量 Width, 整数型
.局部变量 Height, 整数型
.局部变量 DataStream, 对象
.局部变量 pStream, 整数型
.局部变量 Bitmap, 整数型
.局部变量 hMemData, 整数型
.局部变量 Data, 字节集

GdiplusStartup1 (0, { 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 }, 0)
.如果真 (OpenClipboard (0) ＝ 0 或 是否为空 (窗口句柄) ＝ 假 且 IsWindow (窗口句柄) ＝ 0)
    返回 ({  })
.如果真结束
TempFormat ＝ EnumClipboardFormats (0)
.判断循环首 (TempFormat ≠ 0)
    加入成员 (Format, TempFormat)
    TempGlobal_1 ＝ GetClipboardData (TempFormat)
    Value ＝ GlobalSize (TempGlobal_1)
    TempGlobal_2 ＝ GlobalAlloc (8194, Value)
    CopyMemory2 (GlobalLock (TempGlobal_2), GlobalLock (TempGlobal_1), Value)
    GlobalUnlock (TempGlobal_1)
    GlobalUnlock (TempGlobal_2)
    加入成员 (hGlobal, TempGlobal_2)
    DeleteObject (TempGlobal_1)
    TempFormat ＝ EnumClipboardFormats (TempFormat)
.判断循环尾 ()
EmptyClipboard ()
CloseClipboard ()

keybd_event1 (44, 0, 0, 0)
keybd_event1 (44, 0, 2, 0)
处理事件 ()
OpenClipboard (0)
Value ＝ GetClipboardData (2)
.如果真 (Value ＝ 0)
    CloseClipboard ()
    keybd_event1 (17, 0, 0, 0)
    keybd_event1 (18, 0, 0, 0)
    keybd_event1 (107, 0, 0, 0)
    keybd_event1 (107, 0, 2, 0)
    keybd_event1 (17, 0, 2, 0)
    keybd_event1 (18, 0, 2, 0)
    处理事件 ()
    OpenClipboard (0)
    Value ＝ GetClipboardData (2)
.如果真结束

.如果真 (是否为空 (窗口句柄) ＝ 假)
    GetWindowRect1 (窗口句柄, RECT)
    hScrDC ＝ GetDC (0)
    hScrMemDC ＝ CreateCompatibleDC (hScrDC)
    DeleteObject (SelectObject (hScrMemDC, Value))

    hWinDC ＝ GetDC (窗口句柄)
    hWinMemDC ＝ CreateCompatibleDC (hWinDC)
    Width ＝ RECT [3] － RECT [1]
    Height ＝ RECT [4] － RECT [2]
    hWinBitmap ＝ CreateCompatibleBitmap (hWinDC, Width, Height)
    DeleteObject (SelectObject (hWinMemDC, hWinBitmap))
    BitBlt (hWinMemDC, 0, 0, Width, Height, hScrMemDC, RECT [1] － 1, RECT [2] － 1, 13369376)

    ReleaseDC (0, hScrDC)
    ReleaseDC (0, hWinDC)
    DeleteDC (hScrMemDC)
    DeleteDC (hWinMemDC)
    DeleteObject (Value)
    Value ＝ hWinBitmap
.如果真结束
.如果 (是否为空 (输出高度) ＝ 假 且 是否为空 (输出宽度) ＝ 假)
    hBitmap ＝ CopyImage (Value, 0, 输出宽度, 输出高度, 4)
    DeleteObject (Value)
.否则
    hBitmap ＝ Value
.如果结束

GdipCreateBitmapFromHBITMAP (hBitmap, 0, Bitmap)
CreateStreamOnHGlobal1 (0, 真, DataStream)
CopyMemory3 (pStream, DataStream, 4)
.如果真 (输出格式 ＜ 1 或 输出格式 ＞ 5)
    输出格式 ＝ 1
.如果真结束
GdipSaveImageToStream (Bitmap, pStream, 多项选择 (输出格式, { 0 }, { 1 }, { 2 }, { 5 }, { 6 }) ＋ { 244, 124, 85, 4, 26, 211, 17, 154, 115, 0, 0, 248, 30, 243, 46 }, 0)
GetHGlobalFromStream (pStream, hMemData)
Data ＝ 指针到字节集 (GlobalLock (hMemData), GlobalSize (hMemData))
GlobalUnlock (hMemData)
GdipDisposeImage (Bitmap)
GlobalFree (hMemData)
DeleteObject (hBitmap)
EmptyClipboard ()

.计次循环首 (取数组成员数 (Format), n)
    SetClipboardData (Format [n], hGlobal [n])
    GlobalFree (hGlobal [n])
.计次循环尾 ()
CloseClipboard ()

返回 (Data)
[/e]

奋斗中的大毛驴

晓易 发表于 2013-6-12 22:08
[e]
.版本 2

高人啊 人才 亲

奋斗中的大毛驴

晓易 发表于 2013-6-12 22:08
[e]
.版本 2

缺点DLL啊  不能调试 遗憾

萧杨

快照即可！

清歌流觞

一大堆代码看不懂！！

默默`

晓易 发表于 2013-6-12 22:08
[e]
.版本 2

你叫LZ情何以堪。。。。

Hoibben

默默` 发表于 2013-6-13 08:14
你叫LZ情何以堪。。。。

我也是这个意思，嘎嘎。。。。

Sywer╮P

用快照功能啊