【70精币】这个ini排名改怎么写啊。。。

鬼圈 · 发表于 2013-5-26 12:55:55

实在是不会写。。。
大致要的格式是节名称下的七天内的数据加起来
然后对比这些数据的大小，做出排名
QQ截图20130526125527.png

scqandcy · 发表于 2013-5-26 12:55:56

[e]
.版本 2

.程序集窗口程序集1
.程序集变量节名数组, 文本型, , "0"
.程序集变量计数结果, 整数型, , "0"
.程序集变量项名数组, 文本型, , "0"

.子程序 __启动窗口_创建完毕
.局部变量配置文件名, 文本型
.局部变量计数器甲, 整数型
.局部变量计数器乙, 整数型

配置文件名＝取当前目录 () ＋ “\QQ.ini”
文件_取配置节名数组 (配置文件名, 节名数组)
重定义数组 (计数结果, 假, 取数组成员数 (节名数组))
.计次循环首 (取数组成员数 (节名数组), 计数器甲)
文件_取配置项名数组 (配置文件名, 节名数组 [计数器甲], 项名数组)
.计次循环首 (取数组成员数 (项名数组), 计数器乙)
      .如果真 (取整 (取时间间隔 (取现行时间 (), 到时间 (项名数组 [计数器乙]), #日)) ≤ 7)  ' 取离软件运行日期最近的7天
         计数结果 [计数器甲] ＝计数结果 [计数器甲] ＋到整数 (读配置项 (配置文件名, 节名数组 [计数器甲], 项名数组 [计数器乙], ))
      .如果真结束

.计次循环尾 ()
.计次循环尾 ()

.子程序 _按钮1_被单击

冒泡排序法 ()

.子程序冒泡排序法
.局部变量临时变量甲, 整数型
.局部变量临时变量乙, 文本型
.局部变量计数器甲, 整数型
.局部变量计数器乙, 整数型
.局部变量局部节名数组, 文本型, , "0"
.局部变量计数器, 整数型

局部节名数组＝节名数组
.变量循环首 (1, 取数组成员数 (计数结果), 1, 计数器甲)
.变量循环首 (计数器甲＋ 1, 取数组成员数 (计数结果), 1, 计数器乙)
      .如果真 (计数结果 [计数器甲] ＞计数结果 [计数器乙])  ' 升序就是> 降序就是<
         临时变量甲＝计数结果 [计数器甲]
         计数结果 [计数器甲] ＝计数结果 [计数器乙]
         计数结果 [计数器乙] ＝临时变量甲
         临时变量乙＝局部节名数组 [计数器甲]
         局部节名数组 [计数器甲] ＝局部节名数组 [计数器乙]
         局部节名数组 [计数器乙] ＝临时变量乙
      .如果真结束

.变量循环尾 ()
.变量循环尾 ()
.计次循环首 (取数组成员数 (计数结果), 计数器)
编辑框1.加入文本 (局部节名数组 [计数器] ＋ “=” ＋到文本 (计数结果 [计数器]) ＋ #换行符)
.计次循环尾 ()[/e]

这就是整个程序  你新建一个按钮新建一个文本框多行那种。