进程优先级问题

让我倾听

ccini 发表于 2011-10-17 12:49

麻烦告诉下代码写法
第一个和第二个参数怎么写？

ccini

让我倾听 发表于 2011-10-19 19:47
麻烦告诉下代码写法
第一个和第二个参数怎么写？

[e]
.版本 2
.程序集 窗口程序集1
.子程序 __启动窗口_创建完毕
设置进程优先级 (GetCurrentProcessId (), 0)
.子程序 设置进程优先级, 逻辑型, , 设置一个进程的优先级别,
.参数 进程标识符, 整数型, , 欲设置的进程标识符
.参数 进程级别, 整数型, , 0等于最高,1等于高于标准,2等于实时,3等于标准,4等于低于标准,5等于低
.局部变量 B, 整数型
.局部变量 C, 整数型
.局部变量 A, 逻辑型
.局部变量 E, 整数型
.如果真 (进程级别 ＝ 0)
    E ＝ #HIGH_PRIORITY_CLASS
.如果真结束
.如果真 (进程级别 ＝ 1)
    E ＝ #ABOVE_NORMAL_PRIORITY_CLASS
.如果真结束
.如果真 (进程级别 ＝ 2)
    E ＝ #REALTIME_PRIORITY_CLASS
.如果真结束
.如果真 (进程级别 ＝ 3)
    E ＝ #NORMAL_PRIORITY_CLASS
.如果真结束
.如果真 (进程级别 ＝ 4)
    E ＝ #BELOW_NORMAL_PRIORITY_CLASS
.如果真结束
.如果真 (进程级别 ＝ 5)
    E ＝ #IDLE_PRIORITY_CLASS
.如果真结束
.如果真 (进程标识符 ≠ 0)
    C ＝ OpenProcess (#PROCESS_ALL_ACCESS, 0, 进程标识符)  ' 打开进程获得进程句柄
    B ＝ SetPriorityClass (C, E)  ' 设置进程优先级
    .如果 (B ≠ 0)
        A ＝ 真
    .否则
        A ＝ 假
    .如果结束
    CloseHandle (C)
.如果真结束
返回 (A)

.版本 2
.常量 NORMAL_PRIORITY_CLASS, "32", , 标准
.常量 IDLE_PRIORITY_CLASS, "64", , 低
.常量 HIGH_PRIORITY_CLASS, "128", , 最高
.常量 REALTIME_PRIORITY_CLASS, "256", , 实时
.常量 BELOW_NORMAL_PRIORITY_CLASS, "16384", , 低于标准
.常量 ABOVE_NORMAL_PRIORITY_CLASS, "32768", , 高于标准
.常量 PROCESS_ALL_ACCESS, "2035711", , 最大权限,允许所有权限

.版本 2
.DLL命令 SetPriorityClass, 整数型, "kernel32", "SetPriorityClass", , , 设置进程优先级别
    .参数 hProcess, 整数型, , 进程句柄
    .参数 dwPriorityClass, 整数型, , 优先级别
.DLL命令 OpenProcess, 整数型, "kernel32", "OpenProcess"
    .参数 dwDesiredAccess, 整数型
    .参数 bInheritHandle, 整数型
    .参数 dwProcessId, 整数型
.DLL命令 CloseHandle, 整数型, "kernel32", "CloseHandle", , , 关闭文件或某个对像,非零表示成功
    .参数 hObject, 整数型, , 句柄
.DLL命令 GetCurrentProcess, 整数型, "kernel32", "GetCurrentProcess", , , 获取当前进程的一个伪句柄
.DLL命令 GetCurrentProcessId, 整数型, "kernel32", "GetCurrentProcessId", , , 获取当前进程一个唯一的标识符

[/e]