问易语言的 记录集.查找 语句和流程控制方法！！

binghucgb

.版本 2
.支持库 eDB

A
.子程序 _按钮登陆_被单击
.局部变量 文本读, 文本型

.如果真 (记录集.查找 (“姓名=编辑框用户.内容”, #正向搜索) ＝ 真)
    记录集.读文本 (“密码”, 文本读)
    .判断开始 (编辑框密码.内容 ＝ 文本读)
        _启动窗口.可视 ＝ 假
        主窗口.可视 ＝ 真
    .默认
        信息框 (“密码错误”, 0, )
        编辑框密码.内容 ＝ “”
        编辑框密码.获取焦点 ()
    .判断结束     跳至A点
.如果真结束
信息框 (“无此用户”, 0, )
编辑框用户.内容 ＝ “”
编辑框用户.获取焦点 ()
编辑框密码.内容 ＝ “”


1、蓝色字体处要实现   数据库中表的   “姓名”字段  与   编辑框的内容   一致的比较，但这种表述方式是错误的，一直达不到想要的结果，这一点改怎么改动呢？
2、有什么办法能实现红色字体的跳转？？以达到密码错误只需修改密码，而不必连用户名也必须一起修改？？

一棒过克

.版本 2
.支持库 eDB

.子程序 _按钮登录_被单击
.局部变量 文本读, 文本型

数据库连接1.连接Access (取运行目录 () ＋ “\1.mdb”, “”)  ' 这句代码通常放在__启动窗口_创建完毕子程序中
记录集.置连接 (数据库连接1)  ' 同上

记录集.打开 (“表1”, #数据表名)
记录集.到首记录 ()

.如果 (记录集.查找 (“姓名='” ＋ 编辑框用户.内容 ＋ “'”, #正向搜索))
    记录集.读文本 (“密码”, 文本读)
    .如果 (编辑框密码.内容 ＝ 文本读)
        _启动窗口.可视 ＝ 假
        主窗口.可视 ＝ 真
    .否则
        信息框 (“密码错误”, 0, )
        编辑框密码.内容 ＝ “”
        编辑框密码.获取焦点 ()
    .如果结束

.否则
    信息框 (“无此用户”, 0, )
    编辑框用户.内容 ＝ “”
    编辑框用户.获取焦点 ()
    编辑框密码.内容 ＝ “”

xmdd1005

呵呵,学习下,等高手回答,跟着学习!!!

一棒过克

也可以这样，效果一样：
.版本 2
.支持库 eDB

.子程序 _按钮登录_被单击
.局部变量 文本读, 文本型

数据库连接1.连接Access (取运行目录 () ＋ “\1.mdb”, “”)  ' 这句代码通常放在__启动窗口_创建完毕子程序中
记录集.置连接 (数据库连接1)  ' 同上
记录集.打开 (“表1”, #数据表名)
记录集.到首记录 ()
.如果真 (记录集.查找 (“姓名='” ＋ 编辑框用户.内容 ＋ “'”, #正向搜索) ＝ 假)
    信息框 (“无此用户”, 0, )
    编辑框用户.内容 ＝ “”
    编辑框用户.获取焦点 ()
    编辑框密码.内容 ＝ “”
    返回 ()

.如果真结束
记录集.读文本 (“密码”, 文本读)
.如果真 (编辑框密码.内容 ≠ 文本读)
    信息框 (“密码错误”, 0, )
    编辑框密码.内容 ＝ “”
    编辑框密码.获取焦点 ()
    返回 ()
.如果真结束
_启动窗口.可视 ＝ 假
主窗口.可视 ＝ 真

一棒过克

如果数据库内有多个同名用户（密码不同）：
.版本 2
.支持库 eDB

.子程序 _按钮登录_被单击
.局部变量 文本读, 文本型

数据库连接1.连接Access (取运行目录 () ＋ “\1.mdb”, “”)  ' 这句代码通常放在__启动窗口_创建完毕子程序中
记录集.置连接 (数据库连接1)  ' 同上
记录集.打开 (“表1”, #数据表名)
记录集.到首记录 ()
.如果 (记录集.查找 (“姓名='” ＋ 编辑框用户.内容 ＋ “'”, #正向搜索) ＝ 真)
    .判断循环首 (记录集.尾记录后 ＝ 假)  ' 密码只要与其中一个同名用户密码一致，登录成功
        记录集.读文本 (“密码”, 文本读)
        .如果 (编辑框密码.内容 ＝ 文本读)
            _启动窗口.可视 ＝ 假
            主窗口.可视 ＝ 真
            跳出循环 ()
        .否则
            记录集.到下一条 ()
        .如果结束

    .判断循环尾 ()
    .如果真 (编辑框密码.内容 ≠ 文本读)  ' 密码与所有同名用户的密码不一致时，提示密码错误
        信息框 (“密码错误”, 0, )
        编辑框密码.内容 ＝ “”
        编辑框密码.获取焦点 ()
        返回 ()
    .如果真结束


.否则
    信息框 (“无此用户”, 0, )
    编辑框用户.内容 ＝ “”
    编辑框用户.获取焦点 ()
    编辑框密码.内容 ＝ “”
    返回 ()

雨林木风

楼主请参考此帖便可以解决问题：http://www.3600gz.cn/thread-43756-1-1.html

934332

{:3_226:}这么多回答的..差不多都对吧.

雅氏◆¨小轩

学习下！   

雅氏◆¨小轩

{:3_238:}等待高手出现！

binghucgb

大侠们请明示啊