怎么让编辑框显示返回的数据文本

lucky

side2011

.版本 2

.子程序 取中间的文本, 文本型, 公开, 取中间的文本，和核心支持的不同，好使！
.参数 完整内容, 文本型, , 完整内容
.参数 左边文本, 文本型, , 左边文本
.参数 右边文本, 文本型, , 右边文本
.参数 循环读取, 逻辑型, 可空, 默认为假
.参数 结果数组, 文本型, 可空 数组, 当循环读取为真时返回结果的数组
.参数 返回方式, 逻辑型, 可空, 为真时都有文本返回
.局部变量 临时位置, 整数型
.局部变量 总长度, 整数型
.局部变量 临时文本, 文本型
.局部变量 位置1, 整数型
.局部变量 位置2, 整数型

总长度 ＝ 取文本长度 (完整内容)
.如果 (循环读取 ≠ 真)
    .判断开始 (右边文本 ＝ “”)
        .如果 (寻找文本 (完整内容, 左边文本, , 假) ＞ -1)
            临时位置 ＝ 寻找文本 (完整内容, 左边文本, , 假) ＋ 取文本长度 (左边文本)
            临时文本 ＝ 取文本中间 (完整内容, 临时位置, 总长度)
            返回 (临时文本)
        .否则
            .如果 (返回方式 ＝ 真)
                返回 (完整内容)
            .否则
                返回 (“”)
            .如果结束

        .如果结束

    .判断 (左边文本 ＝ “”)
        .如果 (寻找文本 (完整内容, 右边文本, , 假) ＞ -1)
            临时位置 ＝ 寻找文本 (完整内容, 右边文本, , 假) － 1
            临时文本 ＝ 取文本左边 (完整内容, 临时位置)
            返回 (临时文本)
        .否则
            .如果 (返回方式 ＝ 真)
                返回 (完整内容)
            .否则
                返回 (“”)
            .如果结束

        .如果结束

    .判断 (左边文本 ＝ “” 且 右边文本 ＝ “ ”)
        返回 (“”)
    .默认
        .如果 (寻找文本 (完整内容, 左边文本, , 假) ＞ -1)
            临时位置 ＝ 寻找文本 (完整内容, 左边文本, , 假) ＋ 取文本长度 (左边文本)
            临时文本 ＝ 取文本中间 (完整内容, 临时位置, 总长度)
            总长度 ＝ 取文本长度 (临时文本)
            临时位置 ＝ 寻找文本 (临时文本, 右边文本, , 假) － 1
            临时文本 ＝ 取文本中间 (临时文本, 1, 临时位置)
            返回 (临时文本)
        .否则
            .如果 (返回方式 ＝ 真)
                返回 (完整内容)
            .否则
                返回 (“”)
            .如果结束

        .如果结束

    .判断结束

.否则
    .如果 (左边文本 ＝ “” 或 右边文本 ＝ “”)
        .如果 (返回方式 ＝ 真)
            返回 (完整内容)
        .否则
            返回 (“”)
        .如果结束

    .否则
        重定义数组 (结果数组, 假, 0)
        位置1 ＝ 寻找文本 (完整内容, 左边文本, , 真)
        .判断循环首 (位置1 ≠ -1)
            临时位置 ＝ 位置1 ＋ 1
            位置2 ＝ 寻找文本 (完整内容, 右边文本, 位置1, 假)
            加入成员 (结果数组, 取文本中间 (完整内容, 位置1 ＋ 取文本长度 (左边文本), 位置2 － 位置1 － 取文本长度 (左边文本)))
            位置1 ＝ 寻找文本 (完整内容, 左边文本, 临时位置, 真)
        .判断循环尾 ()
        .如果 (结果数组 [1] ≠ “”)
            返回 (结果数组 [1])
        .否则
            .如果 (返回方式 ＝ 真)
                返回 (完整内容)
            .否则
                返回 (“”)
            .如果结束

        .如果结束

    .如果结束

.如果结束



这个子程序可以解决，编译成模块也行

side2011

编辑框.内容=到文本（返回的数据）
沙发{:3_228:}

lucky

编辑框.内容=到文本（返回的数据）
沙发
side2011 发表于 2011-4-23 14:30

    那要是提取中间一段显示呢？

side2011

回复 3# lucky


    取文本中间，精易模块里有

zichuan

你想返回成功或否吧
直接
如果（寻找文本）
  编辑框1.内容=“成功”

lucky

.版本 2

.子程序 取中间的文本, 文本型, 公开, 取中间的文本，和核心支持的不同，好使！
.参数 完整内容 ...
side2011 发表于 2011-4-23 14:27

    有点头绪了，谢谢！！！！在研究一下，再次感谢！！！