大漠.鼠标移动EX怎么弄

hahaha001

我想在游戏找一个动态人物，由于是动态人物找图是找不到，，，，
就想到鼠标在指定的范围里来回移动，比如在0，0，100，100里来回移动鼠标，只要是鼠标移动到那个动态人物那么就出现他名字，那就可以找字点击，，，
怎么实现呢。。这个鼠标来回移动怎么弄，

大漠.鼠标移动EX。这个是什么意思，弄不懂

ouyanglaile

是对应的某个坐标范围内随机的一个点.对应参数意思是:大漠.鼠标移动EX(10,10,100,100)其中前面2个10,代表这个坐标,后面的两个100对应以10,10这个坐标横纵坐标各偏移100,也就是讲,鼠标点击的位置是在横坐标10-110和纵坐标10-110范围内的随机一点的位置.

chenboss

鼠标移动指定区域.e

还得是我000

.版本 2
.支持库 spec

.子程序 人物_鼠标扫描, 逻辑型
.参数 index, 整数型
.参数 要打怪物名, 文本型
.参数 终止值, 整数型
.参数 步长, 双精度小数型
.参数 起始X, 整数型
.参数 起始Y, 整数型
.局部变量 dm, dmsoft
.局部变量 起始半径, 整数型
.局部变量 每弧度增加的半径, 双精度小数型
.局部变量 等差最大值, 双精度小数型
.局部变量 点数组, 双精度小数型, , "0"
.局部变量 i, 整数型
.局部变量 径向距离, 双精度小数型, , "0"
.局部变量 偏移坐标X, 双精度小数型, , "0"
.局部变量 偏移坐标Y, 双精度小数型, , "0"
.局部变量 结果, 文本型
.局部变量 识别结果, 文本型

dm ＝ 线程信息 [index].dm

' 定义阿基米德螺旋线的参数
等差最大值 ＝ 终止值 × #pi  ' 角度范围
.计次循环首 (终止值 × 3, i)
    加入成员 (点数组, (i － 1) × 终止值 ÷ (终止值 × 3 － 1))
.计次循环尾 ()
重定义数组 (径向距离, 假, 取数组成员数 (点数组))
重定义数组 (偏移坐标X, 假, 取数组成员数 (点数组))
重定义数组 (偏移坐标Y, 假, 取数组成员数 (点数组))
.计次循环首 (取数组成员数 (点数组), i)
    径向距离 [i] ＝ 步长 × 点数组 [i]
    偏移坐标X [i] ＝ 径向距离 [i] × 求余弦 (点数组 [i])
    偏移坐标Y [i] ＝ 径向距离 [i] × 求正弦 (点数组 [i])
    ' 调试输出 (到整数 (起始X ＋ 偏移坐标X [i]), 到整数 (起始Y ＋ 偏移坐标Y [i]))
    dm.MoveTo (到整数 (起始X ＋ 偏移坐标X [i]), 到整数 (起始Y ＋ 偏移坐标Y [i]))
    结果 ＝ dm.Ocr (10, 65, 669, 491, “ff8800-303030|fb8405-202020”, 1)
    .如果真 (结果 ＝ 要打怪物名)
        调试输出 (“当前结果”, 结果)
        dm.delay (100)
        dm.LeftClick ()
        dm.delay (100)
        跳出循环 ()
    .如果真结束

.计次循环尾 ()
.计次循环首 (100, )
    识别结果 ＝ dm.Ocr (21, 165, 370, 215, “f5f5f9-202020|ffffff-505050”, 1)
    .如果真 (识别结果 ≠ “”)
        返回 (真)
    .如果真结束
    脚本延时 (index, 50)
.计次循环尾 ()
返回 (假)


你看看这个是不是你想要的  你自己替换一个颜色

Ben吽

学习一下   这个可以用哦