文本程序集增加文本_取全部汉字拼音

zl2017

.版本 2

.子程序 文本_取全部汉字拼音, 文本型, 公开, 支持取出文本中所有国标汉字的拼音，默认不保留非国标汉字字符。
.参数 文本, 文本型, , 欲取拼音的文本
.参数 保留非汉字, 逻辑型, 可空, 默认假，不保留原文本里的符号和数字等非国标汉字字符；真则保留。
.局部变量 b, 字节集
.局部变量 c, 整数型
.局部变量 n, 整数型
.局部变量 z, 整数型
.局部变量 ret, 文本型
.局部变量 p0, 文本型
.局部变量 p1, 文本型

.如果真 (是否为空 (保留非汉字))
    保留非汉字 ＝ 假
.如果真结束
b ＝ 到字节集 (文本)
c ＝ 取字节集长度 (b)
n ＝ 1
.判断循环首 (n ≤ c)
    .如果 (n ＋ 1 ＞ c)
        z ＝ 1
    .否则
        .如果 (b [n] ＞ 128)
            z ＝ 2
            p0 ＝ 到文本 (取字节集中间 (b, n, 2))
            p1 ＝ 取拼音 (p0, 1)
            .判断开始 (取文本长度 (删全部空 (p1)) ≠ 0)
                ret ＝ ret ＋ p1 ＋ “空”
            .默认
                .如果真 (保留非汉字)
                    ret ＝ ret ＋ p0
                .如果真结束

            .判断结束

        .否则
            .如果 (b [n] ≠ 13)
                z ＝ 1
            .否则
                .如果 (b [n ＋ 1] ＝ 10)
                    z ＝ 2
                .否则
                    z ＝ 1

                .如果结束

            .如果结束

            .如果真 (保留非汉字)
                .如果 (取文本长度 (删全部空 (取拼音 (到文本 (取字节集中间 (b, n ＋ 1, 2)), 1))) ≠ 0)  ' ‘判断单字节字符后面是否是双字节字符
                    ret ＝ ret ＋ 到文本 (取字节集中间 (b, n, z)) ＋ “空”
                .否则
                    ret ＝ ret ＋ 到文本 (取字节集中间 (b, n, z))
                .如果结束

            .如果真结束

        .如果结束

    .如果结束
    n ＝ n ＋ z
.判断循环尾 ()
ret ＝ 子文本替换 (ret, “ ”, “”, , , 真)  ' ’删除中间多余的空格
ret ＝ 子文本替换 (ret, “空”, “ ”, , , 真)  ' ’把用作隔开的“空”替换为“ ”

.如果真 (取文本右边 (ret, 1) ＝ “ ”)  ' ’删除尾部多余空格
    ret ＝ 取文本左边 (ret, 取文本长度 (ret) － 1)
.如果真结束
返回 (ret)

借鉴逐字分割的思想，对一段文本的取全部汉字取拼音处理，支持保留非国标拼音的字符。

测试文本
2016年7月至10月,蒋某等人在生产窝点使用江西某公司出品的精制盐为原料,生产假冒zc商标“雪天”牌加碘食用盐,并雇用戴某、李某、李某某对精制盐变更包装,雇用曾某向长沙市开福区、芙蓉区、岳麓区及长沙县等地多家粮油店送货。经鉴定,蒋某等人销售的假冒碘盐中碘含量为零,亚铁氰化钾含量不符合检验标准,为不合格食品。

经查,蒋某等人共销售假冒碘盐34.98吨。案发后,被行政执法机关、公安机关查封扣押了3.7吨,仍有近31.2吨流入市场。经长沙市雨花区法院一审判决,蒋某等人均因犯非法经营罪获刑。其中蒋某被判处有期徒刑一年零六个月,并处罚金人民币5万元。

测试结果
2016 nian 7 yue zhi 10 yue , jiang mou deng ren zai sheng chan wo dian shi yong jiang xi mou gong si chu pin de jing zhi yan wei yuan liao , sheng chan jia mao zhu ce shang biao “xue tian ”pai jia dian shi yong yan , bing gu yong dai mou 、li mou 、li mou mou dui jing zhi yan bian geng bao zhuang , gu yong ceng mou xiang chang sha shi kai fu qu 、fu rong qu 、yue lu qu ji chang sha xian deng di duo jia liang you dian song huo 。jing jian ding , jiang mou deng ren xiao shou de jia mao dian yan zhong dian han liang wei ling , ya tie qing hua jia han liang bu fu he jian yan biao zhun , wei bu he ge shi pin 。

jing cha , jiang mou deng ren gong xiao shou jia mao dian yan 34.98 dun 。an fa hou , bei xing zheng zhi fa ji guan 、gong an ji guan cha feng kou ya le 3.7 dun , reng you jin 31.2 dun liu ru shi chang 。jing chang sha shi yu hua qu fa yuan yi shen pan jue , jiang mou deng ren jun yin fan fei fa jing ying zui huo xing 。qi zhong jiang mou bei pan chu you qi tu xing yi nian ling liu ge yue , bing chu fa jin ren min bi 5 wan yuan 。

项目部002

已收录，下周发布新版本

WANG121

小白一个 看看学习学习